多GPU的基本用法

Question

多GPU的基本用法

24

我如何使用两个设备以改善以下代码（向量求和）的性能？是否可能同时使用更多设备？如果是，如何管理不同设备上全局内存中向量的分配？

#include <stdio.h>
#include <stdlib.h>
#include <math.h>
#include <time.h>
#include <cuda.h>

#define NB 32
#define NT 500
#define N NB*NT

__global__ void add( double *a, double *b, double *c);

//===========================================
__global__ void add( double *a, double *b, double *c){

    int tid = threadIdx.x + blockIdx.x * blockDim.x; 

    while(tid < N){
        c[tid] = a[tid] + b[tid];
        tid += blockDim.x * gridDim.x;
    }

}

//============================================
//BEGIN
//===========================================
int main( void ) {

    double *a, *b, *c;
    double *dev_a, *dev_b, *dev_c;

    // allocate the memory on the CPU
    a=(double *)malloc(N*sizeof(double));
    b=(double *)malloc(N*sizeof(double));
    c=(double *)malloc(N*sizeof(double));

    // allocate the memory on the GPU
    cudaMalloc( (void**)&dev_a, N * sizeof(double) );
    cudaMalloc( (void**)&dev_b, N * sizeof(double) );
    cudaMalloc( (void**)&dev_c, N * sizeof(double) );

    // fill the arrays 'a' and 'b' on the CPU
    for (int i=0; i<N; i++) {
        a[i] = (double)i;
        b[i] = (double)i*2;
    }

    // copy the arrays 'a' and 'b' to the GPU
    cudaMemcpy( dev_a, a, N * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b, b, N * sizeof(double), cudaMemcpyHostToDevice);

    for(int i=0;i<10000;++i)
        add<<<NB,NT>>>( dev_a, dev_b, dev_c );

    // copy the array 'c' back from the GPU to the CPU
    cudaMemcpy( c, dev_c, N * sizeof(double), cudaMemcpyDeviceToHost);

    // display the results
    // for (int i=0; i<N; i++) {
    //      printf( "%g + %g = %g\n", a[i], b[i], c[i] );
    //  }
    printf("\nGPU done\n");

    // free the memory allocated on the GPU
    cudaFree( dev_a );
    cudaFree( dev_b );
    cudaFree( dev_c );
    // free the memory allocated on the CPU
    free( a );
    free( b );
    free( c );

    return 0;
}

提前感谢您。 Michele

- micheletuttafesta

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- talonmies · Accepted Answer

自 CUDA 4.0 发布以来，像你所问的这种多GPU计算相对容易了。在此之前，您需要使用多线程主机应用程序，每个GPU使用一个主机线程，并具有某种线程间通信系统，才能在同一主机应用程序中使用多个GPU。

现在可以像下面这样做您主机代码的内存分配部分：

double *dev_a[2], *dev_b[2], *dev_c[2];
const int Ns[2] = {N/2, N-(N/2)};

// allocate the memory on the GPUs
for(int dev=0; dev<2; dev++) {
    cudaSetDevice(dev);
    cudaMalloc( (void**)&dev_a[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_b[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_c[dev], Ns[dev] * sizeof(double) );
}

(免责声明：代码在浏览器中编写，从未编译，从未测试，请自行承担风险.)

基本思路是使用 cudaSetDevice 在对设备执行操作时选择设备。因此，在上面的片段中，我假设有两个GPU，并在每个GPU上分配内存[(在第一个设备上为N/2个double，在第二个设备上为N-(N/2)个double)].

从主机到设备的数据传输可能就像这样简单：

// copy the arrays 'a' and 'b' to the GPUs
for(int dev=0,pos=0; dev<2; pos+=Ns[dev], dev++) {
    cudaSetDevice(dev);
    cudaMemcpy( dev_a[dev], a+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b[dev], b+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
}

（免责声明：这段代码是在浏览器中编写的，从未编译过，从未测试过，请自行承担风险。）

您的代码中的内核启动部分可能会类似于以下内容：

for(int i=0;i<10000;++i) {
    for(int dev=0; dev<2; dev++) {
        cudaSetDevice(dev);
        add<<<NB,NT>>>( dev_a[dev], dev_b[dev], dev_c[dev], Ns[dev] );
    }
}

（免责声明：在浏览器中编写，从未编译，从未测试，使用需自担风险。）

请注意，我已经向您的内核调用添加了一个额外的参数，因为每个内核实例可能会被调用以处理不同数量的数组元素。我将让您自行计算所需的修改。但是，基本思想是相同的：使用cudaSetDevice选择给定的GPU，然后以正常方式在其上运行内核，每个内核都获得其自己的唯一参数。

您应该能够将这些部分组合起来，制作一个简单的多GPU应用程序。在最近的CUDA版本和硬件中可以使用许多其他功能来协助多GPU应用程序（例如统一寻址、点对点设施等），但这应该足以让您入门。CUDA SDK中还有一个简单的多GPU应用程序，您可以查看以获取更多想法。