如何在gnuplot中分组箱线图的异常值

Question

如何在gnuplot中分组箱线图的异常值

3

我有一组大量的数据点。我尝试用箱线图绘制它们，但其中一些异常值具有相同的值，并在一条线上表示。我找到了一个链接How to set the horizontal distance between outliers in gnuplot boxplot，但并没有太大帮助，因为显然不可能实现。

是否有可能将异常值分组，仅打印一个点，然后在其旁边打印一个数字括号以指示有多少个点？我认为这将使图表更易读。

作为参考，对于一个x值，我有三个箱线图，在一个图中重复六次。我正在使用gnuplot 5，并已经调整了点大小，但不能再缩小距离。希望你能帮忙！

编辑：

set terminal pdf
set output 'dat.pdf'
file0 = 'dat1.dat'
file1 = 'dat2.dat'
file2 = 'dat3.dat'
set pointsize 0.2
set notitle
set xlabel 'X'
set ylabel 'Y'
header = system('head -1 '.file0);
N = words(header)

set xtics ('' 1)
set for [i=1:N] xtics add (word(header, i) i)

set style data boxplot
plot file0 using (1-0.25):1:(0.2) with boxplot lw 2 lc rgb '#8B0000' fs pattern 16 title 'A'
plot file1 using (1):1:(0.2) with boxplot lw 2 lc rgb '#00008B' fs pattern 4 title 'B'
plot file2 using (1+0.25):1:(0.2) with boxplot lw 2 lc rgb '#006400' fs pattern 5 title 'C'
for [i=2:N] plot file0 using (i-0.25):i:(0.2) with boxplot lw 2 lc rgb '#8B0000' fs pattern 16 notitle
for [i=2:N] plot file1 using (i):i:(0.2) with boxplot lw 2 lc rgb '#00008B' fs pattern 4 notitle
for [i=2:N] plot file2 using (i+0.25):i:(0.2) with boxplot lw 2 lc rgb '#006400' fs pattern 5 notitle

这段代码已经存在，如何最好地实现它？

- Patrick

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Christoph · Accepted Answer

目前还没有自动完成此操作的选项。手动在gnuplot中完成所需步骤如下:

(在以下步骤中，我假设数据文件data.dat只有一列.)

Analyze your data with stats to determine the boundaries for the outliers:

stats 'data.dat' using 1
range = 1.5 # (this is the default value of the `set style boxplot range` value)
lower_limit = STATS_lo_quartile - range*(STATS_up_quartile - STATS_lo_quartile)
upper_limit = STATS_up_quartile + range*(STATS_up_quartile - STATS_lo_quartile)

Count only the outliers and write them to a temporary file

set table 'tmp.dat'
plot 'data.dat' using 1:($1 > upper_limit || $1 < lower_limit ? 1 : 0) smooth frequency
unset table

Plot the boxplot without the outliers, and the outliers with the labels plotting style:

set style boxplot nooutliers
plot 'data.dat' using (1):1 with boxplot,\
     'tmp.dat' using (1):($2 > 0 ? $1 : 1/0):(sprintf('(%d)', int($2))) with labels offset 1,0 left point pt 7

需要为每个箱线图执行此操作。

免责声明：这个步骤应该基本可行，但是由于没有示例数据，我无法测试它。