在Processing中如何使用矩阵旋转向量？

Question

我正在尝试使用矩阵旋转向量，但感到困惑。

我认为我所需要做的就是创建一个旋转矩阵并将其乘以向量以获得旋转后的向量。 这里您可以看到我使用Processing进行的简单测试：

使用a来增加旋转角度，x/y/z用于改变轴。

以下是源代码：

PVector[] clone,face = {new PVector(50,0,50),new PVector(-50,0,50),new PVector(-50, 0, -50),new PVector(50, 0, -50)};
color faceC = color(255,0,0),cloneC = color(0,255,0);
float angle = 90;
PVector x = new PVector(1,0,0),y = new PVector(0,1,0),z = new PVector(0,0,1), axis = x;
PFont ocr;

void setup(){
  size(400,400,P3D);
  strokeWeight(1.1610855);smooth();
  clone = rotateVerts(face,angle,axis);
  ocr = loadFont("ocr.vlw");
}
void draw(){
  background(255);
  fill(0);textFont(ocr,10);text("a = increment rotation\nx/y/z = change axis\nrotation: " + angle + "\naxis: " + axis,10,10,200,200);fill(255);
  translate(width*.5,height*.5);
  rotateX(map(mouseY,height*.5,-height*.5,0,TWO_PI));
  rotateY(map(mouseX,0,width,0,TWO_PI));
    drawQuad(face,faceC);
    drawQuad(clone,cloneC);
  stroke(128,0,0);line(0,0,0,100,0,0);stroke(0,128,0);line(0,0,0,0,-100,0);stroke(0,0,128);line(0,0,0,0,0,100);
}
void keyPressed(){
  if(key == 'a') angle += 15;
  if(angle > 360) angle -= 360;
  if(key == 'x') axis = x;
  if(key == 'y') axis = y;
  if(key == 'z') axis = z;
  clone = rotateVerts(face,angle,axis);
}
PVector[] rotateVerts(PVector[] verts,float angle,PVector axis){
  int vl = verts.length;
  PVector[] clone = new PVector[vl];
  for(int i = 0; i<vl;i++) clone[i] = PVector.add(verts[i],new PVector());
  //rotate using a matrix
  PMatrix3D rMat = new PMatrix3D();
  rMat.rotate(radians(angle),axis.x,axis.y,axis.z);
  for(int i = 0; i<vl;i++) rMat.mult(clone[i],clone[i]);
  return clone;
}
void drawQuad(PVector[] verts,color c){
  stroke(c);
  beginShape(QUADS);
    for(int i = 0 ; i < 4; i++) vertex(verts[i].x,verts[i].y,verts[i].z);
  endShape();
}

Processing附带了PVector和PMatrix3D，我已经使用过了。

我是不是没有按照应该使用的方式使用PMatrix，还是这是一个bug？有什么提示吗？

- George Profenza

Answer 1

这就是罪魁祸首：

rMat.mult(clone[i],clone[i]);

这样做是不安全的，因为与C或JAVA不同，源代码在操作进行过程中会发生变化。

将函数末尾更改为：

PVector[] dst = new PVector[vl];
for(int i = 0; i<vl;i++) dst[i] = new PVector();
for(int i = 0; i<vl;i++) rMat.mult(clone[i],dst[i]);
return dst;

将解决此问题。

- Knyphe

Answer 2

你可以使用toxiclibs几何类代替PVector，这将帮助简化整个语法：

import toxi.geom.*;

Vec3D[] rotateVerts(Vec3D[] verts, float angle, Vec3D axis){
  Vec3D[] clone = new Vec3D[verts.length];
  for(int i = 0; i<verts.length;i++)
    clone[i] = verts[i].getRotatedAroundAxis(axis,angle);
  return clone;
}

或者使用矩阵进行转换：

Vec3D[] rotateVerts(Vec3D[] verts, float angle, Vec3D axis){
  Matrix4x4 mat=new Matrix4x4();
  mat.rotateAroundAxis(axis,angle);
  Vec3D[] clone = new Vec3D[verts.length];
  for(int i = 0; i<verts.length;i++) clone[i] = mat.applyTo(verts[i]);
  return clone;
}

后者在只进行简单轴旋转时会稍微慢一些，但如果您同时进行其他转换（例如平移等），这种方法更为合理。此外，在两种情况下，假定angle以弧度为单位..。

希望能有所帮助！

- toxi

---

非常好！谢谢！我正在查看文档（https://dev.postspectacular.com/docs/core/toxi/geom/Vec3D.html#headingXY()），发现headingXY、XZ、YZ非常方便。如果我有4个顶点和一个法线，如何获得Z轴上的旋转？如果我在法线上使用heading方法，Z始终会相同，因为我只处理1个顶点。有什么提示吗？ - George Profenza