如何在 GLSL 片段着色器中访问纹理的自动 Mipmap 等级？

Question

如何在 GLSL 片段着色器中访问纹理的自动 Mipmap 等级？

opengltexturesglslfragment-shadermipmaps

18

在GLSL片段着色器中，如何确定采样纹理时使用了哪个mipmap级别？

我明白我可以使用textureLod(...)方法手动采样纹理的特定mipmap级别：

uniform sampler2D myTexture;

void main()
{
    float mipmapLevel = 1;
    vec2 textureCoord = vec2(0.5, 0.5);
    gl_FragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

或者我可以使用texture(...)自动选择mipmap级别，例如

uniform sampler2D myTexture;

void main()
{
    vec2 textureCoord = vec2(0.5, 0.5);
    gl_FragColor = texture(myTexture, textureCoord);
}

我更喜欢后者，因为我相信驱动程序对适当的mipmap级别的判断，比我自己做出的更加准确。

但我想知道在自动采样过程中使用了哪个mipmap级别，以帮助我合理地采样附近像素。在GLSL中是否有一种方法可以访问有关自动纹理采样使用了哪个mipmap级别的信息？

- Christopher Bruns

7

你的目标是哪个GLSL版本？GLSL 4.00支持textureQueryLod(...)，可以完全满足你的需求。 - Andon M. Coleman

2个回答

14

以下内容来自这里：

take a look at the OpenGL 4.2 spec chapter 3.9.11 equation 3.21. The mip map level is calculated based on the lengths of the derivative vectors:
float mip_map_level(in vec2 texture_coordinate)
{
    vec2  dx_vtc        = dFdx(texture_coordinate);
    vec2  dy_vtc        = dFdy(texture_coordinate);
    float delta_max_sqr = max(dot(dx_vtc, dx_vtc), dot(dy_vtc, dy_vtc));
    return 0.5 * log2(delta_max_sqr);
}

- genpfault

1

谢谢你找到这个。我看了一下规范，不幸的是它似乎在实际实现中留下了一些余地，所以这种方法可能不是精确使用的方法。此外，它没有考虑GL_TEXTURE_MIN_LOD/GL_TEXTURE_MAX_LOD设置。请注意，您片段中的texture_coordinate应该是未标准化的，即以像素为单位，而不仅仅是（0,1）。这对我来说是一个很好的开始，可以手动指定LOD。但我希望有一种方法可以访问内部自动LOD值。 - Christopher Bruns

@ChristopherBruns：你可以做一些非常俗套的事情：为每个mip级别填充一个虚拟纹理，其中包含不同的纯色/值，对其进行采样，并将颜色/值转换回mip级别 :) - genpfault

2

实际上，如果我们突然谈论GL 4.x，textureQueryLod(...)就是为了这个目的而创建的。像大多数隐式LOD纹理函数一样，它只能在片段着色器中工作，因为它需要屏幕空间梯度（偏导数）来计算适当的mipmap LOD。 - Andon M. Coleman

@AndonM.Coleman 哦，textureQueryLod() 看起来正是我想要的。我一直在使用 GLSL 3.30，但这可能会让我考虑 GLSL 4.0。或者至少让我尝试加载一个扩展。有人应该将其纳入到一个适当的答案中... - Christopher Bruns

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Christopher Bruns · Accepted Answer

以下是三种不同的方法来解决这个问题，具体取决于您可用的OpenGL功能：

正如Andon M. Coleman在评论中指出的那样，在OpenGL 4.00及以上版本中，解决方案很简单；只需使用textureQueryLod函数：

#version 400

uniform sampler2D myTexture;
in vec2 textureCoord; // in normalized units
out vec4 fragColor;

void main()
{
    float mipmapLevel = textureQueryLod(myTexture, textureCoord).x;
    fragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

在早期版本的OpenGL（2.0+？）中，您可能能够加载一个扩展来达到类似的效果。这种方法对我的情况有效。注意：在扩展中，方法调用的大小写与内置的不同（queryTextureLod与queryTextureLOD）。

#version 330

#extension GL_ARB_texture_query_lod : enable

uniform sampler2D myTexture;
in vec2 textureCoord; // in normalized units
out vec4 fragColor;

void main()
{
    float mipmapLevel = 3; // default in case extension is unavailable...
#ifdef GL_ARB_texture_query_lod
    mipmapLevel = textureQueryLOD(myTexture, textureCoord).x; // NOTE CAPITALIZATION
#endif
    fragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

如果加载扩展程序不起作用，您可以使用 genpfault 贡献的方法估计自动详细级别：

#version 330

uniform sampler2D myTexture;
in vec2 textureCoord; // in normalized units
out vec4 fragColor;

// Does not take into account GL_TEXTURE_MIN_LOD/GL_TEXTURE_MAX_LOD/GL_TEXTURE_LOD_BIAS,
// nor implementation-specific flexibility allowed by OpenGL spec
float mip_map_level(in vec2 texture_coordinate) // in texel units
{
    vec2  dx_vtc        = dFdx(texture_coordinate);
    vec2  dy_vtc        = dFdy(texture_coordinate);
    float delta_max_sqr = max(dot(dx_vtc, dx_vtc), dot(dy_vtc, dy_vtc));
    float mml = 0.5 * log2(delta_max_sqr);
    return max( 0, mml ); // Thanks @Nims
}

void main()
{
    // convert normalized texture coordinates to texel units before calling mip_map_level
    float mipmapLevel = mip_map_level(textureCoord * textureSize(myTexture, 0));
    fragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

无论如何，对于我的特定应用程序，我最终只是在主机端计算了mipmap级别，并将其传递给着色器，因为自动的细节级别并不完全符合我的需求。