我尝试使用参数m和n重现显示横向电磁(TEM)模式强度分布的图像。我使用了一个4x4的表面绘图矩阵。对于我来说,结果令人满意。为了完整起见:
- 如何添加轴而不是为每个单独的图形添加一个标题?
- 是否有一种方法可以仅在一个方向上显示表面上的等值线,就像原始图像中一样?
- 原作者省略了多图的下部以强调对称性。我不确定这是否真正使观点清晰。我应该只显示完整的矩阵还是您能想到更好的方法?
解决方案
谢谢大家。根据您的建议,我现在拥有以下图片:
这是从Qt终端输出的以下代码:
m=n=3 # max. 3
THETA=2.5
set hidden3d trianglepattern 2
set isosamples 50
set xrange [-THETA:THETA]
set yrange [-THETA:THETA]
set view 70,55,,.5
unset border
unset key
unset tics
H0(x)=1
H1(x)=2*x
H2(x)=4*x**2-2
H3(x)=8*x**3-12*x
set multiplot layout n+1,m+1 upwards margins .14,.9,.14,.9 spacing .05 \
title 'Intensitätsverteilungen der Laguerre-Gauß-Moden' font ",16"
do for [i=0:n] for [j=0:m] {
eval sprintf("splot (H%d(sqrt(2)*y)*exp(-y**2))**2\
* (H%d(sqrt(2)*x)*exp(-x**2))**2\
with lines lc %d", i, j, abs(i-j)+1)
}
set origin 0,0
set size 1,1
unset margins
set title ' '
set arrow from 0,-.5 to graph 1,0
set arrow from -.5,0 to graph 0,1
set label at .5, .5 "dreh-\nsymmetrisch" center rotate by -37
set arrow from .7,0 to .1,.6
set tics out nomirror
set xtics 0, 1, n
set ytics 0, 1, m
set xrange [-.5:n+.5]
set yrange [-.5:m+.5]
set xlabel offset graph .5,0 "n"
set ylabel offset graph 0,.5 "m" norotate
plot NaN
unset multiplot
- 我没有手动添加坐标轴,而是在上面绘制了一个适当缩放的2D图。因此,除了参数m和n为3之外,坐标轴的比例也支持其他参数。要支持更高阶数,需要添加相应的Hermite多项式Hn(x); n=1, 2, 3, ...并可能需要调整多个图的边距。
- 提供
set hidden3d trianglepattern 2
被证明是使等值线仅以一个方向显示的最简单方法。 - 颜色应该有助于区分成对的旋转对称图形。有人可能会对美学进行争论,但希望传达的信息能够得到传递。
set hidden3d trianglepattern 2
和set isosamples 50
。 - grsousajunior