单子 Writer m 和 Either e 在范畴论上是对偶的吗？

Question

我注意到Writer m和Either e单子之间存在双重关系。如果m是一个幺半群，那么

unit :: () -> m
join :: (m,m) -> m

可以被用来构建一个单子：

return is composition: a -> ((),a) -> (m,a)
join is composition: (m,(m,a)) -> ((m,m),a) -> (m,a)

空类型的对偶是Void（空类型），积类型的对偶是余积类型。每个类型e都可以被赋予“余单子”结构：

unit :: Void -> e
join :: Either e e -> e

以明显的方式进行。现在，

return is composition: a -> Either Void a -> Either e a
join is composition: Either e (Either e a) -> Either (Either e e) a -> Either e a

这是 Either e 函子。箭头遵循完全相同的模式。

问题：是否可能编写一种通用代码，根据给定的幺半群，能够同时作为 Either e 和 Writer m 运行？

- sdcvvc

Answer 1

我不会说这些单子是绝对的双重，而是它们都是由以下构造所产生的：给定一个单子范畴(C, ⊗, 1)和一个在C中的代数A，考虑将X发送到A ⊗ X的单子。在第一种情况下，C是Hask，⊗是×，代数是幺半群；在第二种情况下，C是Hask，⊗是∐（Either），代数只是一种类型（每种类型都是关于∐唯一的一种代数方式 - 这就是您所指的“余幺半群”，尽管通常意义不同，请参见下文）。按照惯例，我正在一个假想的世界中工作，其中⊥不存在，因此×实际上是一个乘积等等。可能可以使用适当的单子范畴类型类捕捉这个常见的概括（我现在太累了，无法理解category-extras在这方面试图做什么），从而同时定义Writer和Either作为单子（模新类型，可能）。

关于 Writer m 的范畴对偶，取决于你想要考虑什么固定条件，但最有可能的候选者似乎是在没有任何 m 条件的情况下对 (,) m 进行共单子结构。

instance Comonad ((,) m) where
    coreturn (m, a) = a
    cojoin (m, a) = (m, (m, a))

（请注意，这里是我们使用m作为共同体的地方，即我们有映射m →（），m → m × m。）

- Reid Barton

Answer 2

这里是代码：

{-# LANGUAGE FlexibleInstances, EmptyDataDecls, MultiParamTypeClasses,
FunctionalDependencies, GeneralizedNewtypeDeriving, UndecidableInstances #-}

import Control.Arrow (first, second, left, right)
import Data.Monoid

data Void
data Iso a b = Iso { from :: a -> b, to :: b -> a}

-- monoidal category (Hask, m, unit)
class MonoidalCategory m unit | m -> unit where
  iso1 :: Iso (m (m x y) z) (m x (m y z))
  iso2 :: Iso x (m x unit)
  iso3 :: Iso x (m unit x)

  map1 :: (a -> b) -> (m a c -> m b c)
  map2 :: (a -> b) -> (m c a -> m c b)

instance MonoidalCategory (,) () where
  iso1 = Iso (\((x,y),z) -> (x,(y,z))) (\(x,(y,z)) -> ((x,y),z))
  iso2 = Iso (\x -> (x,())) (\(x,()) -> x)
  iso3 = Iso (\x -> ((),x)) (\((),x) -> x)
  map1 = first
  map2 = second

instance MonoidalCategory Either Void where
  iso1 = Iso f g
         where f (Left (Left x)) = Left x
               f (Left (Right x)) = Right (Left x)
               f (Right x) = Right (Right x)

               g (Left x) = Left (Left x)
               g (Right (Left x)) = Left (Right x)
               g (Right (Right x)) = Right x
  iso2 = Iso Left (\(Left x) -> x)
  iso3 = Iso Right (\(Right x) -> x)
  map1 = left
  map2 = right

-- monoid in monoidal category (Hask, c, u)
class MonoidM m c u | m -> c u where
  mult :: c m m -> m
  unit :: u -> m

-- object of monoidal category (Hask, Either, Void)
newtype Eith a = Eith { getEith :: a } deriving (Show)

-- object of monoidal category (Hask, (,), ())
newtype Monoid m => Mult m = Mult { getMult :: m } deriving (Monoid, Show)

instance MonoidM (Eith a) Either Void where
  mult (Left x) = x
  mult (Right x) = x
  unit _ = undefined

instance Monoid m => MonoidM (Mult m) (,) () where
  mult = uncurry mappend
  unit = const mempty

instance (MonoidalCategory c u, MonoidM m c u) => Monad (c m) where
  return = map1 unit . from iso3
  x >>= f = (map1 mult . to iso1) (map2 f x)

使用方法：

a = (Mult "hello", 5) >>= (\x -> (Mult " world", x+1))
                                 -- (Mult {getMult = "hello world"}, 6)
inv 0 = Left (Eith "error")
inv x = Right (1/x)
b = Right 5 >>= inv              -- Right 0.2
c = Right 0 >>= inv              -- Left (Eith {getEith="error"})
d = Left (Eith "a") >>= inv      -- Left (Eith {getEith="a"})

- sdcvvc

Answer 3

严格来说，()和Void并不是对偶的—— ⊥ 的存在意味着所有类型都有实例，因此 ⊥ 是 Void 的唯一实例，使其成为终端对象，正如您所期望的那样。 () 由两个值组成，因此不相关。如果您忽略 ⊥，那么 () 就是终端的，而 Void 则是初始的，就像您希望的那样。

我认为您的示例也不是一个共单子结构——共单子的签名应该是这样的：

class Comonoid a
    coempty :: a -> ()
    coappend :: a -> (a, a)

如果你考虑等价的共单子定律，那么它最终会变得相当无用，我认为。

我想知道你是否更接近于自然数上的标准和/积单子，如何应用于代数数据类型？ Void 和 Either 是 0/+，而 () 和 (,) 是 1/*。但我不确定如何证明其余部分。

- C. A. McCann