gnuplot - 绘制椭球内的随机点

Question

gnuplot - 绘制椭球内的随机点

mathrandomgeometrygnuplotellipse

4

我想使用gnuplot创建和绘制一组随机点，这些点在椭球体的边界内。是否可以直接在gnuplot中完成此操作，还是需要在外部程序中生成随机数据点？

最终，我想生成类似于此椭圆图形的椭球体图形。

有一些关于rand和柱面/球面坐标使用的示例，但我不确定如何在椭球体边界内生成随机点。

- tommy.carstensen

2个回答

2

我没有找到一种方法可以在参数绘图示例中重复使用你展示的rand(0)，但是通过内部调用命令行工具，你可以进行一些修改来实现这个功能：

unset key
a=3
b=2

set xrange [-a:a]
set yrange [-b:b]
set style function dots
plot "<seq 1000 | awk '{print rand(), rand()}'" using (a*(2*$1-1)):(b*(sqrt(1-((2*$1-1))**2))*(2*$2-1))

将此转换为3D留给读者作为练习（只需继续这些表达式）。

- Bernhard

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Christoph · Accepted Answer

基于@Bernhard的回答，以下是如何仅使用gnuplot来实现。要重用随机数，可以将两个rand调用和变量赋值放在using语句的第一个参数中，用逗号分隔。 using语句从左到右评估，因此您可以在所有后续的using参数中访问这些变量。

为了演示这一点，请参见以下示例：

set samples 1000
plot '+' using (x=rand(0), y=rand(0), x):(y)

应用于椭球体，这是该脚本的内容：

a=3
b=2
phi=30*pi/180

max(x,y) = (x > y ? x : y)
set xrange[-max(a,b):max(a,b)]
set yrange[-max(a,b):max(a,b)]

set offset 0.1,0.1,0.1,0.1
set samples 2000

ex(x, y) = a*(2*x-1)
ey(x, y) = b*(sqrt(1-((2*x-1))**2))*(2*y-1)

unset key    
plot '+' using (x=rand(0), y=rand(0), ex(x,y)*cos(phi)-ey(x,y)*sin(phi)):\
               (ey(x,y)*cos(phi)+ex(x,y)*sin(phi)) pt 7 ps 0.5

结果如下:

enter image description here

然而，这会导致点的分布似乎不均匀(请看椭圆两端的凝聚点，参见@andyras的评论)。为了避免这种情况，以下是如何筛选等分布的随机点以使其位于椭球内:

a=3
b=2
set angles degree
phi=30

max(x,y) = (x > y ? x : y)
set xrange[-max(a,b):max(a,b)]
set yrange[-max(a,b):max(a,b)]

set offset 0.1,0.1,0.1,0.1
set samples 2000
set size ratio 1

check(x, y) = (((x/a)**2 + (y/b)**2) <= 1)
unset key
plot '+' using (x=2*a*(rand(0)-0.5), y=2*b*(rand(0)-0.5), \
     check(x,y) ? x*cos(phi)-y*sin(phi) : 1/0):\
     (x*sin(phi)+y*cos(phi)) pt 7 ps 0.5

这样会得到更好的结果：

enter image description here

将其扩展到三维：

a=3
b=1
c=1
set angles degree
phi=30

mx(x,y) = (x > y ? x : y)
max(x,y,z) = mx(mx(x,y), mx(x,z))
set xrange[-max(a,b,c):max(a,b,c)]
set yrange[-max(a,b,c):max(a,b,c)]
set zrange[-max(a,b,c):max(a,b,c)]

set offset 0.1,0.1,0.1,0.1
set samples 2000
set size ratio 1

set ticslevel 0
set view 60, 330

check(x, y, z) = (((x/a)**2 + (y/b)**2 + (z/c)**2) <= 1)
unset key
splot '+' using (x = 2*a*(rand(0)-0.5), \
                 y = 2*b*(rand(0)-0.5), \
                 z=2*c*(rand(0)-0.5), \
                 check(x,y,z) ? x*cos(phi)-y*sin(phi) : 1/0):\
                 (x*sin(phi)+y*cos(phi)):(z) pt 7 ps 0.5

带着以下结果：

在此输入图片描述