将Delphi字符串网格导出到Excel

Question

我正在尝试从Delphi 7中的字符串网格导出数据到Microsoft Excel。我一直在使用以下代码来完成：

  objExcel := TExcelApplication.Create(nil);
  objExcel.Visible[LOCALE_USER_DEFAULT] := true;
  objWB := objExcel.workbooks.add(null,LOCALE_USER_DEFAULT);
  lineNumber := 1;

  for i:=1 to stringgrid1.rowcount-1 do begin
    for j:=0 to stringgrid1.ColCount-1 do begin
      objWB.Worksheets.Application.Cells.Item[i+lineNumber,j+1] := ''''+stringgrid1.Cells[j,i];
    end;
  end;

但是当数据量很大时，导出数据需要很长时间才能完成。有没有其他更快的方法将 Delphi 7 的 StringGrid 数据导出到 Excel？

- dapidmini

---

谢谢你们的快速回复。我认为数组方法现在最适合我的情况，因为我不会使用.csv文件。我该如何将这个问题标记为“已解决”？ - dapidmini

Answer 1

最快的方法是使用 Variant 数组，并将整个数组传递给 Excel：

uses OleAuto;

var
  xls, wb, Range: OLEVariant;
  arrData: Variant;
  RowCount, ColCount, i, j: Integer;
begin
  {create variant array where we'll copy our data}
  RowCount := StringGrid1.RowCount;
  ColCount := StringGrid1.ColCount;
  arrData := VarArrayCreate([1, RowCount, 1, ColCount], varVariant);

  {fill array}
  for i := 1 to RowCount do
    for j := 1 to ColCount do
      arrData[i, j] := StringGrid1.Cells[j-1, i-1];

  {initialize an instance of Excel}
  xls := CreateOLEObject('Excel.Application');

  {create workbook}
  wb := xls.Workbooks.Add;

  {retrieve a range where data must be placed}
  Range := wb.WorkSheets[1].Range[wb.WorkSheets[1].Cells[1, 1],
                                  wb.WorkSheets[1].Cells[RowCount, ColCount]];

  {copy data from allocated variant array}
  Range.Value := arrData;

  {show Excel with our data}
  xls.Visible := True;
end;

- Ken White

---

感谢您的快速回复。对于像我这样的初学者来说，步骤非常清晰。这解决了我的问题。很遗憾我还不能评价答案。 - dapidmini

+1，只是想知道“最快”是指编码所需的时间还是实际“复制”所需的时间？另一种方法是将所有内容以CSV格式放在剪贴板上，然后将剪贴板内容粘贴到Excel中。 - Marjan Venema

@MarjanVenema：剪贴板属于用户，而不是程序员，所以在我看来这不是一个选项。直接从变量数组转换到Excel范围非常快，并且不会干扰用户放进剪贴板的任何东西，他们期望稍后还在那里。 - Ken White

@KenWhite：剪贴板确实属于用户。如果命名得当，用户知道会发生什么（只有这样），那么这是一个选项。例如，我们允许选择范围并在按下Ctrl-C时将其复制到剪贴板中。 - Marjan Venema

Answer 2

问题在于您为每个单元格调用Excel对象；这是一个缓慢的操作，在大量单元格的情况下，将需要很长时间。我不久前遇到过这种情况：4000行，9列大约需要44秒才能传输到Excel。

我的当前解决方案涉及创建一个csv文件，然后将该csv导入Excel。

const
 fn = 'c:\windows\temp\csv.csv';

var
 csv: tstringlist;
 row, col: integer;
 s: string;

begin
 csv:= tstringlist.create;
 for row:= 1 to stringgrid1.rowcount do 
  begin
   s:= '';
   for col:= 0 to stringgrid1.ColCount-1 do 
    s:= s + stringgrid1.Cells[col, row-1] + ',';
   csv.add (s)
  end;

 csv.savetofile (fn);
 csv.free;

 objExcel := TExcelApplication.Create(nil);
 objExcel.workbooks.open (fn);
 deletefile (fn);
end;

另一种方法来自Mike Shkolnik，我将原话引用如下：

var
 xls, wb, Range: OLEVariant;
 arrData: Variant;

begin
{create variant array where we'll copy our data}
 arrData := VarArrayCreate([1, yourStringGrid.RowCount, 1, yourStringGrid.ColCount], varVariant);

 {fill array}
 for i := 1 to yourStringGrid.RowCount do
  for j := 1 to yourStringGrid.ColCount do
   arrData[i, j] := yourStringGrid.Cells[j-1, i-1];

 {initialize an instance of Excel}
 xls := CreateOLEObject('Excel.Application');

 {create workbook}
 wb := xls.Workbooks.Add;

 {retrieve a range where data must be placed}
 Range := wb.WorkSheets[1].Range[wb.WorkSheets[1].Cells[1, 1],
                              wb.WorkSheets[1].Cells[yourStringGrid.RowCount, yourStringGrid.ColCount]];

 {copy data from allocated variant array}
 Range.Value := arrData;

 {show Excel with our data}
 xls.Visible := True;
end;

我建议您尝试两种方法，看看哪一种更适合您的目的。

- No'am Newman

---

感谢快速的回复。由于我认为我不会使用csv文件，所以现在我将仅使用数组解决方案。不幸的是，我还不能评价答案。 - dapidmini

@dapidmini：csv方法的优点在于它可以在事先不知道行数的情况下使用。显然，这在stringgrid中不会发生，但如果您想将查询结果传递给Excel，则会发生这种情况。很遗憾，您标记了未引用其来源的答案。 - No'am Newman

@dapidmini：使用CSV格式，如果需要，您也可以使用剪贴板，而无需先将其写入文件。 - Marjan Venema

@MarjanVenema: 我过去曾经因为在程序中使用剪贴板而受到批评。人们认为剪贴板属于用户，而不是程序，所以在剪贴板中存储某些东西可能会覆盖用户手动存储的内容。(当我写这篇文章时，我没有看到Ken的评论，但他说的与我相同)。 - No'am Newman

我收集了很多Delphi代码片段，这个片段也来自其中之一。我不知道它的来源，因此很难提供参考，你的暗示有些冒犯。 - Ken White

Answer 3

procedure WriteToExcel();
var
  txt : TextFile;
  Str : string;
  i : integer;
begin
  try
    SaveDialog1.FileName := 'excelFile('+FormatDateTime('yyyy-dd-mm hh-nn-ss' ,(Now))+')';
    if SaveDialog1.Execute then
      begin
        AssignFile(txt, SaveDialog1.FileName+'.csv');
        try
          if FileExists(SaveDialog1.FileName) then
            Append(txt)
          else
            ReWrite(txt);
          Str := 'title1, title2, title3, title4, title5';
          WriteLn(txt, Str);
          ShowQuery.First();
          for i:=1 to StringGrid1.RowCount do
            begin
              Str := StringGrid1.Cols[i][1] + ',';
              Str := Str + StringGrid1.Cols[i][2] + ',';
              Str := Str + StringGrid1.Cols[i][3] + ',';
              Str := Str + StringGrid1.Cols[i][4] + ',';
              Str := Str + StringGrid1.Cols[i][5];
              WriteLn(txt,  Str);
            end;
        finally
          CloseFile(txt);
        end;
      end;
  except

  end;
end;

- ali salehi