如何在XSLT中将单引号替换为双引号加单引号

Question

如何替换XML值，例如：

<name>Linda O'Connel</name>

to:

<name>Linda O''Connel</name>

通过XSLT实现？

我需要这个功能，因为我需要将这个值传递给PowerShell命令行和其他平台，由于需要用"两个单引号"来转义撇号/单引号。

- EdgyIT

---

你应该意识到 PowerShell 可以直接读取 XML 内容，然后直接处理它，而不是试图将其转换为字符串，再对字符串进行转义。 - TheMadTechnician

我肯定可以做到，但是我需要将“双单引号”传递到其他平台，因为这是它们转义单引号的方式。所以，如果有任何通过XSLT完成此操作的方法，那就太好了。谢谢。 - EdgyIT

Answer 1

假设你使用的是XSLT 1.0处理器，你需要使用一个递归命名模板来实现这个功能，例如：

<xsl:template name="replace">
    <xsl:param name="text"/>
    <xsl:param name="searchString">'</xsl:param>
    <xsl:param name="replaceString">''</xsl:param>
    <xsl:choose>
        <xsl:when test="contains($text,$searchString)">
            <xsl:value-of select="substring-before($text,$searchString)"/>
            <xsl:value-of select="$replaceString"/>
           <!--  recursive call -->
            <xsl:call-template name="replace">
                <xsl:with-param name="text" select="substring-after($text,$searchString)"/>
                <xsl:with-param name="searchString" select="$searchString"/>
                <xsl:with-param name="replaceString" select="$replaceString"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

调用示例：

<xsl:template match="name">
    <xsl:copy>
        <xsl:call-template name="replace">
            <xsl:with-param name="text" select="."/>
        </xsl:call-template>
    </xsl:copy>
</xsl:template>

- michael.hor257k

Answer 2

您也可以尝试以下方法。

  <xsl:variable name="temp">'</xsl:variable>
  <name>
    <xsl:value-of select="concat(substring-before(name,$temp),$temp,$temp,substring-after(name,$temp))"/>
  </name>

- Saurav

---

你假设只有一个撇号。 - michael.hor257k

是的，但它正确地执行了第一个实例，而且只需要一个实例。 - xerostomus