如何在 XSLT 中将双引号替换为字符串 ' \ " '？

Question

我有一个XML文件，其中的双引号需要替换为字符串\"。

例如：<root><statement1><![CDATA[<u>测试"消息"在这里</u>]]></statement1></root> 因此输出应该是：<root><statement1><![CDATA[<u>测试\"消息\"在这里</u>]]></statement1></root> 请问有人能解释如何完成这个任务吗？

- Tom Cruise

Answer 1

I. XSLT 1.0解决方案：

该转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"
 cdata-section-elements="statement1"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pPattern">"</xsl:param>
 <xsl:param name="pReplacement">\"</xsl:param>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="statement1/text()" name="replace">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pPat" select="$pPattern"/>
  <xsl:param name="pRep" select="$pReplacement"/>

 <xsl:choose>
  <xsl:when test="not(contains($pText, $pPat))">
   <xsl:copy-of select="$pText"/>
  </xsl:when>
  <xsl:otherwise>
   <xsl:copy-of select="substring-before($pText, $pPat)"/>
   <xsl:copy-of select="$pRep"/>
   <xsl:call-template name="replace">
    <xsl:with-param name="pText" select=
         "substring-after($pText, $pPat)"/>
    <xsl:with-param name="pPat" select="$pPat"/>
    <xsl:with-param name="pRep" select="$pRep"/>
   </xsl:call-template>
  </xsl:otherwise>
 </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的 XML 文档时：

<root>
    <statement1><![CDATA[<u>teset "message"here</u>]]></statement1>
</root>

产生期望的，正确的结果:

<root>
   <statement1><![CDATA[<u>teset \"message\"here</u>]]></statement1>
</root>

II. XSLT 2.0 solution:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"
 cdata-section-elements="statement1"/>

 <xsl:param name="pPat">"</xsl:param>
 <xsl:param name="pRep">\\"</xsl:param>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

  <xsl:template match="statement1/text()">
   <xsl:sequence select="replace(.,$pPat, $pRep)"/>
  </xsl:template>
</xsl:stylesheet>

当应用于相同的 XML 文档（如上所示）时，将产生相同的正确结果：

<root>
      <statement1><![CDATA[<u>teset \"message\"here</u>]]></statement1>
</root>

- Dimitre Novatchev

Answer 2

<?xml version='1.0'   ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:fo="http://www.w3.org/1999/XSL/Format"
                version='1.0'>
<xsl:output method="xml"/>

<xsl:template match="/">
  <xsl:for-each select="//p">
    <xsl:value-of select="translate(text(), '&amp;x22;','#')"/>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

这对我有用...

- MikeyKennethR

---

问题在于替换字符串长度为两个字符。 - Daniel Brockman

你所看到的是引号的转义序列 - 然后我使用了井号。这将说明 - 即使混合转义序列和符号，你也可以这样做 :) - MikeyKennethR

就像我说的那样，问题在于替换字符串有两个字符长。它是 \"，而不是 #。 - Daniel Brockman