使用 Delphi 将 PNG 图像转换为灰度图。

Question

你好 这里是我的代码：

procedure TForm4.Button1Click(Sender: TObject);
var
  png: TPNGImage;
  data: PRGBQarray;
  p: ^tagRGBQuad;
  i, o: integer;
begin
  png := TPNGImage.Create;
  try
    png.LoadFromFile('C:\Untitled.png');
    for o := 1 to 100 do
    begin
      data:=png.Scanline[o];
      for I := 1 to 400 do
      begin
        p := @data^[i];
        p.rgbGreen := p.rgbBlue;
        p.rgbRed := p.rgbGreen;
      end;
    end;
    img.picture.Assign(png);
  finally
    png.Free;
  end;
end;

它不起作用，还会使图片混乱，我确定这是rgbReserved引起的。 我该怎么办？

- Javid

---

你能否把你的代码写得更易读一些？ - Andreas Rejbrand

它是如何使图片变得混乱的？你确定它是32位图像而不是24位的吗？我们能看到一个屏幕截图吗？ - Gareth Davidson

@Andreas：这是一个有趣的结构...如果写成@data^[@i^]，会更美观，你觉得呢？ :D - jachguate

@Andreas：它有什么问题？！ - Javid

Answer 1

这是如何将位图变灰的方法。（如果你想将PNG变灰，你需要先从中获取位图数据。我认为VCL会为您完成这个操作。）

type
  PRGB32Array = ^TRGB32Array;
  TRGB32Array = packed array[0..MaxInt div SizeOf(TRGBQuad)-1] of TRGBQuad;

procedure MakeGrey(Bitmap: TBitmap);
var
  w, h: integer;
  y: Integer;
  sl: PRGB32Array;
  x: Integer;
  grey: byte;
begin
  Bitmap.PixelFormat := pf32bit;
  w := Bitmap.Width;
  h := Bitmap.Height;
  for y := 0 to h - 1 do
  begin
    sl := Bitmap.ScanLine[y];
    for x := 0 to w - 1 do
      with sl[x] do
      begin
        grey := (rgbBlue + rgbGreen + rgbRed) div 3;
        rgbBlue := grey;
        rgbGreen := grey;
        rgbRed := grey;
      end;
  end;
end;

示例使用：

procedure TForm4.Button1Click(Sender: TObject);
var
  bm: TBitmap;
begin
  bm := TBitmap.Create;
  try
    bm.LoadFromFile('C:\Users\Andreas Rejbrand\Pictures\Porträtt, litet, kvadratiskt.bmp');
    MakeGrey(bm);
    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;
end;

- Andreas Rejbrand

---

请注意，行grey := (rgbBlue + rgbGreen + rgbRed) div 3;意味着grey在[0,255]之间，符合要求。 - Andreas Rejbrand

所以，这将自动将图像转换为pf32。这有什么缺点吗？ - Gabriel

Answer 2

安德烈亚斯的回答可以给你一个好的、快速的近似值，但是你会失去一些质量，因为红色、绿色和蓝色在人眼中的强度不相等。如果你想要“做对”，而不是使用简单的平均值，请尝试以下代码： grey := round(rgbRed * .3) + round(rgbGreen * .59) + round(rgbBlue * .11); 虽然这样做可能会稍微降低性能，但除非你处理的是非常大的图像，否则不太可能注意到。

- Mason Wheeler

---

值得注意的是，这是NTSC公式，还有其他公式。 - David

Mason，你不觉得用一次舍入运算几乎可以获得完全相同的结果（速度更快），就像这样：“grey := round(rgbRed * .3 + rgbGreen * .59 + rgbBlue * .11);”吗？ - Argalatyr

Answer 3

我知道这个问题已经有答案了，但是我想再补充一些...

下面的代码来自PNGComponents包（PngFunctions.pas），由Thany制作。

//
//The Following code comes from the PNGComponents package from Thany...
//
procedure MakeImageGrayscale(Image: TPNGObject; Amount: Byte = 255);

  procedure GrayscaleRGB(var R, G, B: Byte);
  var
     X: Byte;
  begin
  X := Round(R * 0.30 + G * 0.59 + B * 0.11);
  R := Round(R / 256 * (256 - Amount - 1)) + Round(X / 256 * (Amount + 1));
  G := Round(G / 256 * (256 - Amount - 1)) + Round(X / 256 * (Amount + 1));
  B := Round(B / 256 * (256 - Amount - 1)) + Round(X / 256 * (Amount + 1));
  end;

var
   X, Y, PalCount: Integer;
   Line: Pointer;
   PaletteHandle: HPalette;
   Palette: array[Byte] of TPaletteEntry;
begin
//Don't do anything if the image is already a grayscaled one
if not (Image.Header.ColorType in [COLOR_GRAYSCALE, COLOR_GRAYSCALEALPHA])
then begin
     if Image.Header.ColorType = COLOR_PALETTE
     then begin
          //Grayscale every palette entry
          PaletteHandle := Image.Palette;
          PalCount := GetPaletteEntries(PaletteHandle, 0, 256, Palette);
          for X := 0 to PalCount - 1
          do GrayscaleRGB(Palette[X].peRed, Palette[X].peGreen, Palette[X].peBlue);
          SetPaletteEntries(PaletteHandle, 0, PalCount, Palette);
          Image.Palette := PaletteHandle;
          end
     else begin
          //Grayscale every pixel
          for Y := 0 to Image.Height - 1
          do begin
             Line := Image.Scanline[Y];
             for X := 0 to Image.Width - 1
             do GrayscaleRGB(PRGBLine(Line)^[X].rgbtRed, PRGBLine(Line)^[X].rgbtGreen, PRGBLine(Line)^[X].rgbtBlue);
             end;
          end;
     end;
end;

有一组例程，最初由PNGImage组件的作者发布，可以在Code Central上找到，展示了如何执行其他操作，例如Alpha混合两个图像、旋转、叠加等等。CodeCentral链接

- Vivian Mills

Answer 4

这实际上应该是对@Mason的将RGB转换为灰度的例程的评论，但由于我不知道如何使评论显示代码，所以我将其作为答案。

这是我进行转换的方法：

FUNCTION RGB2GRAY(R,G,B : BYTE) : BYTE; Register; ASSEMBLER;
  ASM
                IMUL    EAX,19595
                IMUL    EDX,38470
                IMUL    ECX,7471
                ADD     EAX,EDX
                ADD     EAX,ECX
                SHR     EAX,16
  END;

FUNCTION GreyScale(C : TColor) : TColor; Register; ASSEMBLER;
  ASM
                MOVZX   EDX,AH
                MOV     ECX,EAX
                SHR     ECX,16
                MOVZX   EAX,AL
                CALL    RGB2GRAY
                MOVZX   EAX,AL
                MOV     AH,AL
                SHL     EAX,8
                MOV     AL,AH
  END;

我不知道它是NTSC公式还是其他什么，但它们似乎在我的程序中起作用 :-).

- HeartWare

---

不，我不是 :-( 作为一个老汇编程序员，如果内联汇编被移除的话，这将是一个重大的缺点。像这样的小例程可能会被调用数千次，通过一些手动优化的汇编代码，它们将获得巨大的性能提升... - HeartWare