获取Vista Ultimate 64位系统上硬盘（而非分区）序列号

Question

获取Vista Ultimate 64位系统上硬盘（而非分区）序列号

10

我曾试图在不使用WMI的情况下获取硬盘序列号，最终找到了在StackOverflow.com上发表的代码。这个代码在32位的Windows系统（XP和Vista）上运行非常好。但是当我尝试在64位操作系统（特别是Vista Ultimate 64）上获取序列号时，代码总是返回String.Empty或空格。

有人有想法如何解决这个问题吗？

编辑：

我使用了Dave Cluderay建议的工具，并得到了有趣的结果：

以下是在Windows XP SP2 32位上运行DiskId32的输出：

To get all details use "diskid32 /d"
Trying to read the drive IDs using physical access with admin rights
Drive 0 - Primary Controller -  - Master drive
Drive Model Number________________: [MAXTOR STM3160215AS]
Drive Serial Number_______________: [            6RA26XK3]
Drive Controller Revision Number__: [3.AAD]
Controller Buffer Size on Drive___: 2097152 bytes
Drive Type________________________: Fixed
Drive Size________________________: 160041885696 bytes

Trying to read the drive IDs using the SCSI back door

Drive 4 - Tertiary Controller -  - Master drive
Drive Model Number________________: [MAXTOR STM3160215AS]
Drive Serial Number_______________: [            6RA26XK3]
Drive Controller Revision Number__: [3.AAD]
Controller Buffer Size on Drive___: 2097152 bytes
Drive Type________________________: Fixed
Drive Size________________________: 160041885696 bytes

Trying to read the drive IDs using physical access with zero rights

**** STORAGE_DEVICE_DESCRIPTOR for drive 0 ****
Vendor Id = []
Product Id = [MAXTOR STM3160215AS]
Product Revision = [3.AAD]
Serial Number = []

**** DISK_GEOMETRY_EX for drive 0 ****
Disk is fixed
DiskSize = 160041885696

Trying to read the drive IDs using Smart

Drive 0 - Primary Controller -  - Master drive

Drive Model Number________________: [MAXTOR STM3160215AS]
Drive Serial Number_______________: [            6RA26XK3]
Drive Controller Revision Number__: [3.AAD]
Controller Buffer Size on Drive___: 2097152 bytes
Drive Type________________________: Fixed
Drive Size________________________: 160041885696 bytes

Hard Drive Serial Number__________:             6RA26XK3

Hard Drive Model Number___________: MAXTOR STM3160215AS

而且DiskId32可以在Windows Vista Ultimate 64位上运行：

To get all details use "diskid32 /d"

Trying to read the drive IDs using physical access with admin rights

Trying to read the drive IDs using the SCSI back door

Trying to read the drive IDs using physical access with zero rights

**** STORAGE_DEVICE_DESCRIPTOR for drive 0 ****
Vendor Id = [MAXTOR S]
Product Id = [TM3160215AS]
Product Revision = [3.AA]
Serial Number = []

**** DISK_GEOMETRY_EX for drive 0 ****
Disk is fixed
DiskSize = 160041885696

Trying to read the drive IDs using Smart

Hard Drive Serial Number__________:

Hard Drive Model Number___________:

注意Vista系统返回的信息较少，而且没有返回序列号。另外，EnumDisk工具在Vista上将我的硬盘称为“SCSI”，而在Windows XP上为“ATA”。

有什么想法吗？

编辑2：

我发布了来自EnumDisks的结果：

在Windows XP SP2 32位系统上：

Properties for Device 1

Device ID: IDE\DiskMAXTOR_STM3160215AS_____________________3.AAD___

Adapter Properties
------------------
Bus Type       : ATA
Max. Tr. Length: 0x20000
Max. Phy. Pages: 0xffffffff
Alignment Mask : 0x1

Device Properties
-----------------
Device Type     : Direct Access Device (0x0)
Removable Media : No
Product ID      : MAXTOR STM3160215AS
Product Revision: 3.AAD

Inquiry Data from Pass Through
------------------------------
Device Type: Direct Access Device (0x0)
Vendor ID  : MAXTOR S
Product ID : TM3160215AS
Product Rev: 3.AA
Vendor Str :



***  End of Device List  ***

同时，在Vista 64位旗舰版上：

Properties for Device 1

Device ID: SCSI\DiskMAXTOR_STM3160215AS_____3.AA

Adapter Properties
------------------
Bus Type       : FIBRE
Max. Tr. Length: 0x20000
Max. Phy. Pages: 0x11
Alignment Mask : 0x0

Device Properties
-----------------
Device Type     : Direct Access Device (0x0)
Removable Media : No
Vendor ID       : MAXTOR S
Product ID      : TM3160215AS
Product Revision: 3.AA

Inquiry Data from Pass Through
------------------------------
Device Type: Direct Access Device (0x0)
Vendor ID  : MAXTOR S
Product ID : TM3160215AS
Product Rev: 3.AA
Vendor Str :



***  End of Device List  ***

- TheAgent

还有一些可能相关的信息 - 两个操作系统是否在同一台物理机器上（即双重启动）或分开的机器？其中一个是虚拟机吗？磁盘方面有什么值得注意的地方，例如RAID等？ - Dave Cluderay

两个操作系统都在同一台物理机器上，没有使用虚拟机。我的硬盘也没有什么特别之处，只是一个典型的ATA MAXTOR 160 GB硬盘。 - TheAgent

你好。据推测，在Vista 64上，EnumDisk1也无法获取序列号？ - Dave Cluderay

（另外，EnumDisk1 输出了任何错误信息吗？） - Dave Cluderay

据我所记，没有错误。我在此处粘贴了EnumDisk1的整个输出。 - TheAgent

这个应该移动到超级用户吧？ - Randell

7个回答

3

使用 IOCTL_STORAGE_GET_MEDIA_SERIAL_NUMBER 进行 DeviceIoControl 操作。

或者检查 IOCTL_CHANGER_GET_PRODUCT_DATA。

- CiNN

2

IOCTL_STORAGE_GET_MEDIA_SERIAL_NUMBER 用于 USB 设备。 - joshperry

2

您需要确保您的P/Invoke定义是64位友好的。或者，尝试将解决方案中的项目的目标CPU设置为32位。有关P/Invoke和64位的更多信息，请单击此处。 编辑： 下面重新编写的代码可能对您更加有效-基本上我整理了P/Invoke定义并添加了更好的错误处理。该代码尝试两次获取序列号。第一次使用IOCTL_STORAGE_QUERY_PROPERTY，第二次使用SMART_RCV_DRIVE_DATA。

' PhysicalDrive.vb

Option Strict On
Option Explicit On

Imports System.Runtime.InteropServices
Imports System.Text
Imports System.ComponentModel
Imports Microsoft.Win32.SafeHandles

Public Class PhysicalDrive

#Region "Win32 Definitions"
    <StructLayout(LayoutKind.Sequential)> _
    Private Structure IDEREGS
        Public bFeaturesReg As Byte
        Public bSectorCountReg As Byte
        Public bSectorNumberReg As Byte
        Public bCylLowReg As Byte
        Public bCylHighReg As Byte
        Public bDriveHeadReg As Byte
        Public bCommandReg As Byte
        Public bReserved As Byte
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure SENDCMDINPARAMS
        Public cBufferSize As Int32
        Public irDriveRegs As IDEREGS
        Public bDriveNumber As Byte
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=3)> _
        Public bReserved As Byte()
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=4)> _
        Public dwReserved As Int32()
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=1)> _
        Public bBuffer As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure DRIVERSTATUS
        Public bDriverError As Byte
        Public bIDEError As Byte
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=2)> _
        Public bReserved As Byte()
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=2)> _
        Public dwReserved As Int32()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure SENDCMDOUTPARAMS
        Public cBufferSize As Int32
        Public DriverStatus As DRIVERSTATUS
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=IDENTIFY_BUFFER_SIZE)> _
        Public bBuffer As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure GETVERSIONOUTPARAMS
        Public bVersion As Byte
        Public bRevision As Byte
        Public bReserved As Byte
        Public bIDEDeviceMap As Byte
        Public fCapabilities As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=4)> _
        Public dwReserved As Int32()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure STORAGE_PROPERTY_QUERY
        Public PropertyId As Int32
        Public QueryType As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=1)> _
        Public AdditionalParameters As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure STORAGE_DEVICE_DESCRIPTOR
        Public Version As Int32
        Public Size As Int32
        Public DeviceType As Byte
        Public DeviceTypeModifier As Byte
        Public RemovableMedia As Byte
        Public CommandQueueing As Byte
        Public VendorIdOffset As Int32
        Public ProductIdOffset As Int32
        Public ProductRevisionOffset As Int32
        Public SerialNumberOffset As Int32
        Public BusType As Byte
        Public RawPropertiesLength As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=10240)> _
        Public RawDeviceProperties As Byte()
    End Structure

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function CreateFile(ByVal lpFileName As String, ByVal dwDesiredAccess As Int32, ByVal dwShareMode As Int32, ByVal lpSecurityAttributes As IntPtr, ByVal dwCreationDisposition As Int32, ByVal dwFlagsAndAttributes As Int32, ByVal hTemplateFile As IntPtr) As SafeFileHandle
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, <[In](), Out()> ByRef lpInBuffer As SENDCMDINPARAMS, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As SENDCMDOUTPARAMS, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, ByVal lpInBuffer As IntPtr, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As GETVERSIONOUTPARAMS, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, <[In](), Out()> ByRef lpInBuffer As STORAGE_PROPERTY_QUERY, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As STORAGE_DEVICE_DESCRIPTOR, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    Private Const OPEN_EXISTING As Int32 = 3
    Private Const GENERIC_READ As Int32 = &H80000000
    Private Const GENERIC_WRITE As Int32 = &H40000000
    Private Const FILE_SHARE_READ As Int32 = &H1
    Private Const FILE_SHARE_WRITE As Int32 = &H2
    Private Const FILE_SHARE_DELETE As Int32 = &H4
    Private Const SMART_GET_VERSION As Int32 = &H74080
    Private Const SMART_RCV_DRIVE_DATA As Int32 = &H7C088
    Private Const ID_CMD As Int32 = &HEC
    Private Const IDENTIFY_BUFFER_SIZE As Int32 = 512
    Private Const CAP_SMART_CMD As Int32 = &H4
    Private Const IOCTL_STORAGE_QUERY_PROPERTY As Int32 = &H2D1400
    Private Const PropertyStandardQuery As Int32 = 0
    Private Const StorageDeviceProperty As Int32 = 0
#End Region

    Public Shared Function GetSerialNumber(ByVal diskNumber As Integer) As String
        Dim result As String = GetSerialNumberUsingStorageQuery(diskNumber)
        If String.IsNullOrEmpty(result) Then
            result = GetSerialNumberUsingSmart(diskNumber)
        End If
        Return result
    End Function

    Public Shared Function GetSerialNumberUsingStorageQuery(ByVal diskNumber As Integer) As String
        Using hDisk As SafeFileHandle = OpenDisk(diskNumber)
            Dim iBytesReturned As Int32
            Dim spq As New STORAGE_PROPERTY_QUERY()
            Dim sdd As New STORAGE_DEVICE_DESCRIPTOR()
            spq.PropertyId = StorageDeviceProperty
            spq.QueryType = PropertyStandardQuery

            If DeviceIoControl(hDisk, IOCTL_STORAGE_QUERY_PROPERTY, spq, Marshal.SizeOf(spq), sdd, Marshal.SizeOf(sdd), iBytesReturned, 0) = 0 Then
                Throw CreateWin32Exception(Marshal.GetLastWin32Error(), "DeviceIoControl(IOCTL_STORAGE_QUERY_PROPERTY)")
            End If

            Dim result As New StringBuilder()
            If sdd.SerialNumberOffset > 0 Then
                Dim rawDevicePropertiesOffset As Integer = Marshal.SizeOf(sdd) - sdd.RawDeviceProperties.Length
                Dim pos As Integer = sdd.SerialNumberOffset - rawDevicePropertiesOffset
                While pos < iBytesReturned And sdd.RawDeviceProperties(pos) <> 0
                    result.Append(Encoding.ASCII.GetString(sdd.RawDeviceProperties, pos, 1))
                    pos += 1
                End While
            End If
            Return result.ToString()
        End Using
    End Function

    Public Shared Function GetSerialNumberUsingSmart(ByVal diskNumber As Integer) As String
        Using hDisk As SafeFileHandle = OpenDisk(diskNumber)
            If IsSmartSupported(hDisk) Then
                Dim iBytesReturned As Int32
                Dim sci As New SENDCMDINPARAMS
                Dim sco As New SENDCMDOUTPARAMS
                sci.irDriveRegs.bCommandReg = ID_CMD
                sci.bDriveNumber = CByte(diskNumber)
                sci.cBufferSize = IDENTIFY_BUFFER_SIZE
                If DeviceIoControl(hDisk, SMART_RCV_DRIVE_DATA, sci, Marshal.SizeOf(sci), sco, Marshal.SizeOf(sco), iBytesReturned, 0) = 0 Then
                    Throw CreateWin32Exception(Marshal.GetLastWin32Error(), "DeviceIoControl(SMART_RCV_DRIVE_DATA)")
                End If
                Dim result As New StringBuilder()
                For index As Integer = 20 To 39 Step 2
                    result.Append(Encoding.ASCII.GetString(sco.bBuffer, index + 1, 1))
                    result.Append(Encoding.ASCII.GetString(sco.bBuffer, index, 1))
                Next
                Return result.ToString()
            Else
                Return String.Empty
            End If
        End Using
    End Function

    Private Shared Function CreateWin32Exception(ByVal errorCode As Int32, ByVal context As String) As Win32Exception
        Dim win32Exception As New Win32Exception(errorCode)
        win32Exception.Data("Context") = context
        Return win32Exception
    End Function

    Private Shared Function OpenDisk(ByVal diskNumber As Integer) As SafeFileHandle
        Dim hDevice As SafeFileHandle = CreateFile(String.Format("\\.\PhysicalDrive{0}", diskNumber), GENERIC_READ Or GENERIC_WRITE, FILE_SHARE_READ Or FILE_SHARE_WRITE Or FILE_SHARE_DELETE, IntPtr.Zero, OPEN_EXISTING, 0, IntPtr.Zero)
        If (Not hDevice.IsInvalid) Then
            Return hDevice
        Else
            Throw CreateWin32Exception(Marshal.GetLastWin32Error(), "CreateFile")
        End If
    End Function

    Private Shared Function IsSmartSupported(ByVal hDisk As SafeFileHandle) As Boolean
        Dim iBytesReturned As Int32
        Dim gvo As New GETVERSIONOUTPARAMS
        If DeviceIoControl(hDisk, SMART_GET_VERSION, IntPtr.Zero, 0, gvo, Marshal.SizeOf(gvo), iBytesReturned, 0) = 0 Then
            Return False
        End If
        Return (gvo.fCapabilities And CAP_SMART_CMD) > 0
    End Function

End Class

这是调用它的代码：

' MainModule.vb

Module MainModule

    Sub Main()
        Console.WriteLine("{0}-bit runtime.", IntPtr.Size * 8)
        For drive As Integer = 0 To 4
            Try
                Console.WriteLine("Drive {0} - serial number: [{1}]", drive, PhysicalDrive.GetSerialNumber(drive))
            Catch ex As Exception
                If ex.Data("Context") IsNot Nothing Then Console.Error.Write("{0} failed: ", ex.Data("Context"))
                Console.Error.WriteLine(ex.Message)
            End Try
        Next
    End Sub

End Module

我只有一台64位的机器进行测试，但这段代码在上面可以正常运行。

- Dave Cluderay

64位的Vista？因为我在我的64位Vista Ultimate上测试了这段代码，它仍然返回一个空字符串。（由于32位操作系统返回实际序列号之前还有额外的空格字符，所以我在结果上使用String.Trim）似乎没有任何.NET代码能够返回SN。我如何联系微软的程序员讨论这个问题？ - TheAgent

我在一个Windows 7 RC x64 HP ML-115服务器上测试了这段代码。有一些C++的样例可供下载，可以以可执行文件的形式获取。我特别想到的样例是diskid32 (http://www.winsim.com/diskid32/diskid32.html) 和 EnumDisk1 (http://support.microsoft.com/kb/264203)。我建议你在64位机器上尝试运行这些可执行文件。如果它们能够获取序列号，也许我或其他人可以帮助你在自己的VB.net代码中实现相同的技术。 - Dave Cluderay

1

在 Windows 7 64 上工作正常：

        ManagementObjectSearcher mos = new ManagementObjectSearcher("SELECT * FROM Win32_DiskDrive");

        foreach (ManagementObject obj in mos.Get()) {
            Trace.TraceInformation("Information about disk drive {0}:", obj["Name"]);
            Trace.Indent();
            foreach (PropertyData pd in obj.Properties)
                Trace.TraceInformation("Name \"{0}\": \"{1}\"", pd.Name, pd.Value);
            Trace.Unindent();

            obj.Properties["SerialNumber"]
        }

很可能Win32_PhysicalMedia类在64位平台上无法使用。

即使是Disk32，在此时也可以工作（除了翻转序列号字节时的错误），因为它基于相同的概念。

- Luca

我刚在我的机器上（XP，使用.NET 4.0）尝试了这段代码，并且访问obj.Properties["SerialiNumber"]时抛出了“未找到”异常。 - newman

我刚在我的机器上尝试了这段代码（XP，使用.NET 4.0），访问obj.Properties ["SerialiNumber"]抛出“未找到”异常。 - newman

在Windows XP上，您应该查询Win32_PhysicalMedia。这段代码可以在Windows 7上运行。 - Luca

1

这些代码应该可以给你硬盘序列号，它与你链接的代码类似（ReadPhysicalDriveInNTWithAdminRights），但有几个额外函数。

- binarybob

0

从这里的代码进行修改：

using System;
using System.Collections.Generic;
using System.Linq;
using System.Management;
using System.Text;

namespace Console_DiskDrive
{
    class Program
    {
        static void Main(string[] args)
        {
            String query = "SELECT * FROM Win32_DiskDrive";

            foreach (ManagementObject item in new ManagementObjectSearcher(query).Get())
            {
                string serialNumber = Convert.ToString(item["SerialNumber"]);

                Console.WriteLine(serialNumber);
            }

            Console.ReadLine();
        }
    }
}

在我的运行Vista Home Premium x64的系统上，给了我一个40个字符的十六进制字符串，我假设它是我的序列号。稍后我会打开盒子进行确认，但你可以试试看这是否是你要找的东西。

- Chris Doggett

我以前测试过了。获取硬盘序列号的WMI存在一些问题，包括在某些Windows版本上无法工作和间歇性故障，因此那不是答案。 - TheAgent

在我的笔记本电脑上（DELL Latitude E6400 运行 XP），访问“SerialNumber”属性会抛出“未找到”的异常。 - newman

-1

你可能想要使用Windows非托管API来完成这个任务：

使用适当的结构调用GetVolumeInformation API，并查找VolumeSerialNumber整数字段。

这个API已经存在很久了，自从Windows 98以来一直在为我工作。不幸的是，无法在x64上进行检查。

你能否使用其他Windows工具查看正确的序列号？顺便说一句：'0'是一个有效的序列号！如果磁盘映像是从备份中恢复的或类似情况，可能会出现这种情况。

- Alexander Kosenkov

谢谢您的回复，但我不是在寻找卷序列号，而是硬盘的序列号、型号等。 - TheAgent

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Dave Cluderay · Accepted Answer

这段代码尝试获取序列号的方法有三种：

使用 IOCTL_STORAGE_QUERY_PROPERTY。
使用 SMART_RCV_DRIVE_DATA。
使用 IOCTL_SCSI_PASS_THROUGH。

这段代码在64位系统上可用：

' PhysicalDrive.vb

Option Strict On
Option Explicit On

Imports System.Runtime.InteropServices
Imports System.Text
Imports System.ComponentModel
Imports Microsoft.Win32.SafeHandles

Public Class PhysicalDrive

#Region "Win32 Definitions"
    <StructLayout(LayoutKind.Sequential)> _
    Private Structure IDEREGS
        Public bFeaturesReg As Byte
        Public bSectorCountReg As Byte
        Public bSectorNumberReg As Byte
        Public bCylLowReg As Byte
        Public bCylHighReg As Byte
        Public bDriveHeadReg As Byte
        Public bCommandReg As Byte
        Public bReserved As Byte
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure SENDCMDINPARAMS
        Public cBufferSize As Int32
        Public irDriveRegs As IDEREGS
        Public bDriveNumber As Byte
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=3)> _
        Public bReserved As Byte()
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=4)> _
        Public dwReserved As Int32()
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=1)> _
        Public bBuffer As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure DRIVERSTATUS
        Public bDriverError As Byte
        Public bIDEError As Byte
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=2)> _
        Public bReserved As Byte()
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=2)> _
        Public dwReserved As Int32()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure SENDCMDOUTPARAMS
        Public cBufferSize As Int32
        Public DriverStatus As DRIVERSTATUS
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=IDENTIFY_BUFFER_SIZE)> _
        Public bBuffer As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure GETVERSIONINPARAMS
        Public bVersion As Byte
        Public bRevision As Byte
        Public bReserved As Byte
        Public bIDEDeviceMap As Byte
        Public fCapabilities As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=4)> _
        Public dwReserved As Int32()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure STORAGE_PROPERTY_QUERY
        Public PropertyId As Int32
        Public QueryType As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=1)> _
        Public AdditionalParameters As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure STORAGE_DEVICE_DESCRIPTOR
        Public Version As Int32
        Public Size As Int32
        Public DeviceType As Byte
        Public DeviceTypeModifier As Byte
        Public RemovableMedia As Byte
        Public CommandQueueing As Byte
        Public VendorIdOffset As Int32
        Public ProductIdOffset As Int32
        Public ProductRevisionOffset As Int32
        Public SerialNumberOffset As Int32
        Public BusType As Byte
        Public RawPropertiesLength As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=10240)> _
        Public RawDeviceProperties As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure SCSI_PASS_THROUGH
        Public Length As Int16
        Public ScsiStatus As Byte
        Public PathId As Byte
        Public TargetId As Byte
        Public Lun As Byte
        Public CdbLength As Byte
        Public SenseInfoLength As Byte
        Public DataIn As Byte
        Public DataTransferLength As Int32
        Public TimeOutValue As Int32
        Public DataBufferOffset As IntPtr
        Public SenseInfoOffset As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=16)> _
        Public Cdb As Byte()
    End Structure

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure SCSI_PASS_THROUGH_WITH_BUFFER
        Public Spt As SCSI_PASS_THROUGH
        Public Filler As Int32
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=64)> _
        Public Buffer As Byte()
    End Structure

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function CreateFile(ByVal lpFileName As String, ByVal dwDesiredAccess As Int32, ByVal dwShareMode As Int32, ByVal lpSecurityAttributes As IntPtr, ByVal dwCreationDisposition As Int32, ByVal dwFlagsAndAttributes As Int32, ByVal hTemplateFile As IntPtr) As SafeFileHandle
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, <[In]()> ByRef lpInBuffer As SENDCMDINPARAMS, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As SENDCMDOUTPARAMS, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, ByVal lpInBuffer As IntPtr, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As GETVERSIONINPARAMS, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, <[In]()> ByRef lpInBuffer As STORAGE_PROPERTY_QUERY, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As STORAGE_DEVICE_DESCRIPTOR, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)> _
    Private Shared Function DeviceIoControl(ByVal hDevice As SafeFileHandle, ByVal dwIoControlCode As Int32, <[In]()> ByRef lpInBuffer As SCSI_PASS_THROUGH_WITH_BUFFER, ByVal nInBufferSize As Int32, <[In](), Out()> ByRef lpOutBuffer As SCSI_PASS_THROUGH_WITH_BUFFER, ByVal nOutBufferSize As Int32, ByRef lpBytesReturned As Int32, ByVal lpOverlapped As Int32) As Int32
    End Function

    Private Const OPEN_EXISTING As Int32 = 3
    Private Const GENERIC_READ As Int32 = &H80000000
    Private Const GENERIC_WRITE As Int32 = &H40000000
    Private Const FILE_SHARE_READ As Int32 = &H1
    Private Const FILE_SHARE_WRITE As Int32 = &H2
    Private Const FILE_SHARE_DELETE As Int32 = &H4
    Private Const SMART_GET_VERSION As Int32 = &H74080
    Private Const SMART_RCV_DRIVE_DATA As Int32 = &H7C088
    Private Const ID_CMD As Int32 = &HEC
    Private Const IDENTIFY_BUFFER_SIZE As Int32 = 512
    Private Const CAP_SMART_CMD As Int32 = &H4
    Private Const IOCTL_STORAGE_QUERY_PROPERTY As Int32 = &H2D1400
    Private Const IOCTL_SCSI_PASS_THROUGH As Int32 = &H4D004
    Private Const SCSI_IOCTL_DATA_IN As Int32 = &H1
    Private Const PropertyStandardQuery As Int32 = 0
    Private Const StorageDeviceProperty As Int32 = 0
    Private Const ERROR_INVALID_FUNCTION As Int32 = &H1
#End Region

    Public Shared Function GetSerialNumberUsingStorageQuery(ByVal diskNumber As Integer) As String
        Using hDisk As SafeFileHandle = OpenDisk(diskNumber)
            Dim iBytesReturned As Int32
            Dim spq As New STORAGE_PROPERTY_QUERY()
            Dim sdd As New STORAGE_DEVICE_DESCRIPTOR()
            spq.PropertyId = StorageDeviceProperty
            spq.QueryType = PropertyStandardQuery

            If DeviceIoControl(hDisk, IOCTL_STORAGE_QUERY_PROPERTY, spq, Marshal.SizeOf(spq), sdd, Marshal.SizeOf(sdd), iBytesReturned, 0) = 0 Then
                Throw CreateWin32Exception(Marshal.GetLastWin32Error(), "DeviceIoControl(IOCTL_STORAGE_QUERY_PROPERTY)")
            End If

            Dim result As New StringBuilder()
            If sdd.SerialNumberOffset > 0 Then
                Dim rawDevicePropertiesOffset As Integer = Marshal.SizeOf(sdd) - sdd.RawDeviceProperties.Length
                Dim pos As Integer = sdd.SerialNumberOffset - rawDevicePropertiesOffset
                While pos < iBytesReturned And sdd.RawDeviceProperties(pos) <> 0
                    result.Append(Encoding.ASCII.GetString(sdd.RawDeviceProperties, pos, 1))
                    pos += 1
                End While
            End If
            Return result.ToString().Trim()
        End Using
    End Function

    Public Shared Function GetSerialNumberUsingSmart(ByVal diskNumber As Integer) As String
        Using hDisk As SafeFileHandle = OpenDisk(diskNumber)
            If IsSmartSupported(hDisk) Then
                Dim iBytesReturned As Int32
                Dim sci As New SENDCMDINPARAMS
                Dim sco As New SENDCMDOUTPARAMS
                sci.irDriveRegs.bCommandReg = ID_CMD
                sci.bDriveNumber = CByte(diskNumber)
                sci.cBufferSize = IDENTIFY_BUFFER_SIZE
                If DeviceIoControl(hDisk, SMART_RCV_DRIVE_DATA, sci, Marshal.SizeOf(sci), sco, Marshal.SizeOf(sco), iBytesReturned, 0) = 0 Then
                    Throw CreateWin32Exception(Marshal.GetLastWin32Error(), "DeviceIoControl(SMART_RCV_DRIVE_DATA)")
                End If
                Dim result As New StringBuilder()
                For index As Integer = 20 To 39 Step 2
                    result.Append(Encoding.ASCII.GetString(sco.bBuffer, index + 1, 1))
                    result.Append(Encoding.ASCII.GetString(sco.bBuffer, index, 1))
                Next
                Return result.ToString().Trim()
            Else
                Return String.Empty
            End If
        End Using
    End Function

    Public Shared Function GetSerialNumberUsingScsiPassThrough(ByVal diskNumber As Integer) As String
        Using hDisk As SafeFileHandle = OpenDisk(diskNumber)
            Dim iBytesReturned As Int32
            Dim spt As New SCSI_PASS_THROUGH_WITH_BUFFER
            spt.Spt.Length = CShort(Marshal.SizeOf(spt.Spt))
            spt.Spt.CdbLength = 16
            spt.Spt.DataIn = SCSI_IOCTL_DATA_IN
            spt.Spt.DataTransferLength = 64
            spt.Spt.DataBufferOffset = New IntPtr(Marshal.SizeOf(spt) - 64)
            spt.Spt.TimeOutValue = 60
            Dim cdb(15) As Byte
            cdb(0) = &H12 ' INQUIRY
            cdb(1) = &H1 ' EVPD bit
            cdb(2) = &H80 ' Page code (indicates Serial Number)
            cdb(4) = 64 ' Allocation length
            spt.Spt.Cdb = cdb
            If DeviceIoControl(hDisk, IOCTL_SCSI_PASS_THROUGH, spt, Marshal.SizeOf(spt), spt, Marshal.SizeOf(spt), iBytesReturned, 0) = 0 Then
                Dim iErrorCode As Int32 = Marshal.GetLastWin32Error()
                If iErrorCode <> ERROR_INVALID_FUNCTION Then
                    Throw CreateWin32Exception(iErrorCode, "DeviceIoControl(IOCTL_SCSI_PASS_THROUGH)")
                End If
            End If
            Dim result As New StringBuilder()
            Dim pos As Integer = IntPtr.Size
            While pos < spt.Spt.DataTransferLength And spt.Buffer(pos) <> 0
                result.Append(Encoding.ASCII.GetString(spt.Buffer, pos, 1))
                pos += 1
            End While
            Return result.ToString().Trim()
        End Using
    End Function

    Private Shared Function CreateWin32Exception(ByVal errorCode As Int32, ByVal context As String) As Win32Exception
        Dim win32Exception As New Win32Exception(errorCode)
        win32Exception.Data("Context") = context
        Return win32Exception
    End Function

    Private Shared Function OpenDisk(ByVal diskNumber As Integer) As SafeFileHandle
        Dim hDevice As SafeFileHandle = CreateFile(String.Format("\\.\PhysicalDrive{0}", diskNumber), GENERIC_READ Or GENERIC_WRITE, FILE_SHARE_READ Or FILE_SHARE_WRITE Or FILE_SHARE_DELETE, IntPtr.Zero, OPEN_EXISTING, 0, IntPtr.Zero)
        If (Not hDevice.IsInvalid) Then
            Return hDevice
        Else
            Throw CreateWin32Exception(Marshal.GetLastWin32Error(), "CreateFile")
        End If
    End Function

    Private Shared Function IsSmartSupported(ByVal hDisk As SafeFileHandle) As Boolean
        Dim iBytesReturned As Int32
        Dim gvi As New GETVERSIONINPARAMS
        If DeviceIoControl(hDisk, SMART_GET_VERSION, IntPtr.Zero, 0, gvi, Marshal.SizeOf(gvi), iBytesReturned, 0) = 0 Then
            Return False
        End If
        Return (gvi.fCapabilities And CAP_SMART_CMD) > 0
    End Function

End Class

以下是调用它的代码：

' MainModule.vb

Module MainModule

    Sub Main()
        Console.WriteLine("{0}-bit runtime.", IntPtr.Size * 8)
        For drive As Integer = 0 To 4
            Try
                Console.WriteLine("Drive {0}, SMART:             [{1}]", drive, PhysicalDrive.GetSerialNumberUsingSmart(drive))
                Console.WriteLine("Drive {0}, Storage Query:     [{1}]", drive, PhysicalDrive.GetSerialNumberUsingStorageQuery(drive))
                Console.WriteLine("Drive {0}, SCSI Pass Through: [{1}]", drive, PhysicalDrive.GetSerialNumberUsingScsiPassThrough(drive))
            Catch ex As Exception
                If ex.Data("Context") IsNot Nothing Then Console.Error.Write("{0} failed: ", ex.Data("Context"))
                Console.Error.WriteLine(ex.Message)
            End Try
        Next
    End Sub

End Module

编辑 - 我已将主要方法更改为显示每次尝试的结果以进行比较。这将有助于说明这些技术的命中和失误情况。