logo标签列表

Metal - `include` 或 `import` 函数

iosmacosmetal
12

能否将一个metal文件导入或包含到另一个metal文件中？比如我有一个包含所有数学函数的metal文件，只有在我的metal项目中需要时才会导入或包含它。这种做法可行吗？

我尝试过：

#include "sdf.metal"

我遇到了错误：

metallib：_Z4vmaxDv2_f 倍定义符号 命令/Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/usr/bin/metallib 失败，退出代码为1

更新：

这是我的两个着色器文件：

SDF.metal:

#ifndef MYAPP_METAL_CONSTANTS
#define MYAPP_METAL_CONSTANTS


#include <metal_stdlib>

namespace metal {

float kk(float2 v) {
    return max(v.x, v.y);
}

float kkk(float3 v) {
    return max(max(v.x, v.y), v.z);
}

}

#endif

关于 Shaders.metal:

#include <metal_stdlib>
#include "SDF.metal"
using namespace metal;


float fBoxCheap(float3 p, float3 b) { //cheap box
    return kkk(abs(p) - b);
}


float map( float3 p )
{
    float box2 = fBoxCheap(p-float3(0.0,3.0,0.0),float3(4.0,3.0,1.0));



    return box2;
}

float3 getNormal( float3 p )
{
    float3 e = float3( 0.001, 0.00, 0.00 );

    float deltaX = map( p + e.xyy ) - map( p - e.xyy );
    float deltaY = map( p + e.yxy ) - map( p - e.yxy );
    float deltaZ = map( p + e.yyx ) - map( p - e.yyx );

    return normalize( float3( deltaX, deltaY, deltaZ ) );
}

float trace( float3 origin, float3 direction, thread float3 &p )
{
    float totalDistanceTraveled = 0.0;

    for( int i=0; i <64; ++i)
    {
        p = origin + direction * totalDistanceTraveled;

        float distanceFromPointOnRayToClosestObjectInScene = map( p );
        totalDistanceTraveled += distanceFromPointOnRayToClosestObjectInScene;

        if( distanceFromPointOnRayToClosestObjectInScene < 0.0001 )
        {
            break;
        }

        if( totalDistanceTraveled > 10000.0 )
        {
            totalDistanceTraveled = 0.0000;
            break;
        }
    }

    return totalDistanceTraveled;
}

float3 calculateLighting(float3 pointOnSurface, float3 surfaceNormal, float3 lightPosition, float3 cameraPosition)
{
    float3 fromPointToLight = normalize(lightPosition - pointOnSurface);
    float diffuseStrength = clamp( dot( surfaceNormal, fromPointToLight ), 0.0, 1.0 );

    float3 diffuseColor = diffuseStrength * float3( 1.0, 0.0, 0.0 );
    float3 reflectedLightVector = normalize( reflect( -fromPointToLight, surfaceNormal ) );

    float3 fromPointToCamera = normalize( cameraPosition - pointOnSurface );
    float specularStrength = pow( clamp( dot(reflectedLightVector, fromPointToCamera), 0.0, 1.0 ), 10.0 );

    // Ensure that there is no specular lighting when there is no diffuse lighting.
    specularStrength = min( diffuseStrength, specularStrength );
    float3 specularColor = specularStrength * float3( 1.0 );

    float3 finalColor = diffuseColor + specularColor;

    return finalColor;
}

kernel void compute(texture2d<float, access::write> output [[texture(0)]],
                    constant float &timer [[buffer(1)]],
                    constant float &mousex [[buffer(2)]],
                    constant float &mousey [[buffer(3)]],
                    uint2 gid [[thread_position_in_grid]])
{
    int width = output.get_width();
    int height = output.get_height();
    float2 uv = float2(gid) / float2(width, height);
    uv = uv * 2.0 - 1.0;
    // scale proportionately.
    if(width > height) uv.x *= float(width)/float(height);
    if(width < height) uv.y *= float(height)/float(width);


    float posx = mousex * 2.0 - 1.0;
    float posy = mousey * 2.0 - 1.0;

    float3 cameraPosition = float3( posx * 0.01,posy * 0.01, -10.0 );


    float3 cameraDirection = normalize( float3( uv.x, uv.y, 1.0) );

    float3 pointOnSurface;
    float distanceToClosestPointInScene = trace( cameraPosition, cameraDirection, pointOnSurface );

    float3 finalColor = float3(1.0);
    if( distanceToClosestPointInScene > 0.0 )
    {
        float3 lightPosition = float3( 5.0, 2.0, -10.0 );
        float3 surfaceNormal = getNormal( pointOnSurface );
        finalColor = calculateLighting( pointOnSurface, surfaceNormal, lightPosition, cameraPosition );
    }
    output.write(float4(float3(finalColor), 1), gid);

}

更新2：

以及我的MetalView.swift文件：

import MetalKit

public class MetalView: MTKView, NSWindowDelegate {

    var queue: MTLCommandQueue! = nil
    var cps: MTLComputePipelineState! = nil

    var timer: Float = 0
    var timerBuffer: MTLBuffer!

    var mousexBuffer: MTLBuffer!
    var mouseyBuffer: MTLBuffer!
    var pos: NSPoint!
    var floatx: Float!
    var floaty: Float!

    required public init(coder: NSCoder) {
        super.init(coder: coder)
        self.framebufferOnly = false
        device = MTLCreateSystemDefaultDevice()
        registerShaders()
    }


    override public func drawRect(dirtyRect: NSRect) {
        super.drawRect(dirtyRect)
        if let drawable = currentDrawable {
            let command_buffer = queue.commandBuffer()
            let command_encoder = command_buffer.computeCommandEncoder()
            command_encoder.setComputePipelineState(cps)
            command_encoder.setTexture(drawable.texture, atIndex: 0)
            command_encoder.setBuffer(timerBuffer, offset: 0, atIndex: 1)
            command_encoder.setBuffer(mousexBuffer, offset: 0, atIndex: 2)
            command_encoder.setBuffer(mouseyBuffer, offset: 0, atIndex: 3)
            update()
            let threadGroupCount = MTLSizeMake(8, 8, 1)
            let threadGroups = MTLSizeMake(drawable.texture.width / threadGroupCount.width, drawable.texture.height / threadGroupCount.height, 1)
            command_encoder.dispatchThreadgroups(threadGroups, threadsPerThreadgroup: threadGroupCount)
            command_encoder.endEncoding()
            command_buffer.presentDrawable(drawable)
            command_buffer.commit()
        }
    }

    func registerShaders() {
        queue = device!.newCommandQueue()
        do {
            let library = device!.newDefaultLibrary()!
            let kernel = library.newFunctionWithName("compute")!
            timerBuffer = device!.newBufferWithLength(sizeof(Float), options: [])
            mousexBuffer = device!.newBufferWithLength(sizeof(Float), options: [])
            mouseyBuffer = device!.newBufferWithLength(sizeof(Float), options: [])
            cps = try device!.newComputePipelineStateWithFunction(kernel)
        } catch let e {
            Swift.print("\(e)")
        }
    }

    func update() {
        timer += 0.01
        var bufferPointer = timerBuffer.contents()
        memcpy(bufferPointer, &timer, sizeof(Float))
        bufferPointer = mousexBuffer.contents()
        memcpy(bufferPointer, &floatx, sizeof(NSPoint))
        bufferPointer = mouseyBuffer.contents()
        memcpy(bufferPointer, &floaty, sizeof(NSPoint))
    }

    override public func mouseDragged(event: NSEvent) {
        pos = convertPointToLayer(convertPoint(event.locationInWindow, fromView: nil))
        let scale = layer!.contentsScale
        pos.x *= scale
        pos.y *= scale
        floatx = Float(pos.x)
        floaty = Float(pos.y)
        debugPrint("Hello",pos.x,pos.y)
    }
}

更新3

按照KickimusButticus的解决方案实施后，着色器确实编译了。但是我又遇到了另一个错误： 在此输入图片描述

2个回答
21

您的设置不正确（编辑：我的其他答案和以前版本的此答案也是如此）。

您可以像在C++中一样使用头文件（毕竟Metal基于C++11...）。您只需要一个额外的文件，我将其称为SDF.h。该文件包含函数原型声明，没有命名空间声明。并且您需要在其他文件中的using namespace metal;声明之后#include它。确保头文件不是.metal文件，并且它不在您的Build Phases的Compile Sources列表中。如果头文件被视为已编译的源，则很可能会导致CompilerError错误。

SDF.h：

// SDFHeaders.metal
#ifndef SDF_HEADERS
#define SDF_HEADERS

float kk(float2 v);
float kkk(float3 v);

#endif

SDF.metal:

#include <metal_stdlib>

using namespace metal;
#include "SDF.h"

float kk(float2 v) {
    return max(v.x, v.y);
}

float kkk(float3 v) {
    return max(max(v.x, v.y), v.z);
}

Shaders.metal:

这里是在包含SDF.h后使用函数的地方。

// Shaders.metal

#include <metal_stdlib>

using namespace metal;
#include "SDF.h"    

float fBoxCheap(float3 p, float3 b) { //cheap box
    return kkk(abs(p) - b);
}

// ...

当然，在清理之后构建。祝你好运！

我按照你提到的方法进行了操作，程序确实编译通过了。但是，在command_encoder.setComputePipelineState(cps)这一行代码上，我又遇到了另一个运行时错误 - fatal error: unexpectedly found nil while unwrapping an Optional value。我在上方更新了我的MetalView文件。 - sooon
这是进展，你的金属文件已经编译。哪个可选项意外地为 nil？是 cps 吗？你在 registerShaders() 中的 try/catch 块有打印出任何有用的信息吗？ - jperl
1
好的，我认为问题出在你的“编译源”列表中有SDFHeaders.metal。请尝试将其从那里删除。此外，我对我的答案进行了一些其他更改。请查看并进行相应的调整。 - jperl
1
我可以指出Metal 1是基于C++11的，正如你所说，但Metal 2是基于C++14的吗？ - Andreas detests censorship
3
需要翻译的内容：需要注意的一点是，include语句（与代码中的import语句不同）遵循项目目录结构。这意味着，如果您想要包含一个不在与其进行包含的文件相同的文件夹中的文件，您必须给出该文件的路径（即如果它在上级文件夹中，则为 #include "../shared.h"）。 - Ash
显示剩余3条评论
2
如果您在该符号上运行解缠器，您会发现编译器认为您有两个或多个带有签名vmax(float2 v)的函数定义。请检查所包含的文件是否具有多个此类函数定义，或者包含它的文件和包含它的文件都提供了这样的定义。
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接