要更改ComboBox的DropDown List主题边框颜色,您需要处理List Control的
WM_NCPAINT消息,该消息在需要绘制非客户区域时发送到窗口的句柄:通常在显示DropDown时。
要获取ComboBox的List Control的句柄,您可以使用
GetComboBoxInfo()函数:其List Control和Edit Control的句柄以
COMBOBOXINFO结构返回。
您可以将列表控件句柄分配给
NativeWindow,以便覆盖其WndProc并捕获
WM_NCPAINT
。当收到消息时,使用
GetWindowDc()函数获取列表控件的设备上下文(
HDC
)句柄,并将其传递给
Graphics.FromHdc()方法,创建可用于在此表面上绘制的Graphics对象。
▶ 阅读有关 WM_NCPAINT
消息的文档,您可能会注意到 WPARAM
应引用更新区域句柄:但通常为IntPtr.Zero,这就是为什么我们需要 GetWindowDc()
的原因。
释放设备上下文的句柄后,调用
ReleaseDC()(重要)。
就是这样。
自定义组合框控件公开了一个名为
ListBorderColor
的公共属性,用于在设计时和运行时设置列表控件边框的颜色。
Imports System.ComponentModel
Imports System.Drawing
Imports System.Runtime.InteropServices
Imports System.Windows.Forms
<DesignerCategory("code")>
Public Class ComboBoxExt
Inherits ComboBox
Private listControl As ListNativeWindow = Nothing
Private m_ListBorderColor As Color = Color.Transparent
Public Sub New()
End Sub
<DefaultValue(GetType(Color), "Transparent")>
Public Property ListBorderColor As Color
Get
Return m_ListBorderColor
End Get
Set
m_ListBorderColor = Value
If listControl IsNot Nothing Then
listControl.BorderColor = m_ListBorderColor
End If
End Set
End Property
Protected Overrides Sub OnHandleCreated(e As EventArgs)
MyBase.OnHandleCreated(e)
listControl = New ListNativeWindow(GetComboBoxListInternal(Me.Handle))
listControl.BorderColor = ListBorderColor
End Sub
Protected Overrides Sub OnHandleDestroyed(e As EventArgs)
listControl.ReleaseHandle()
MyBase.OnHandleDestroyed(e)
End Sub
Public Class ListNativeWindow
Inherits NativeWindow
Public Sub New()
Me.New(IntPtr.Zero)
End Sub
Public Sub New(hWnd As IntPtr)
If hWnd <> IntPtr.Zero Then AssignHandle(hWnd)
End Sub
Public Property BorderColor As Color = Color.Transparent
Protected Overrides Sub WndProc(ByRef m As Message)
MyBase.WndProc(m)
Select Case m.Msg
Case WM_NCPAINT
Dim hDC As IntPtr = GetWindowDC(Me.Handle)
Try
Using g = Graphics.FromHdc(hDC),
pen = New Pen(BorderColor)
Dim rect = g.VisibleClipBounds
g.DrawRectangle(pen, 0, 0, rect.Width - 1, rect.Height - 1)
End Using
Finally
ReleaseDC(Me.Handle, hDC)
End Try
m.Result = IntPtr.Zero
End Select
End Sub
End Class
<DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
Friend Shared Function GetComboBoxInfo(hWnd As IntPtr, ByRef pcbi As COMBOBOXINFO) As Boolean
End Function
<DllImport("user32.dll", SetLastError:=True)>
Friend Shared Function GetWindowDC(hWnd As IntPtr) As IntPtr
End Function
<DllImport("user32.dll", SetLastError:=True)>
Friend Shared Function ReleaseDC(hWnd As IntPtr, hDc As IntPtr) As Boolean
End Function
Friend Const WM_NCPAINT As Integer = &H85
<StructLayout(LayoutKind.Sequential)>
Friend Structure COMBOBOXINFO
Public cbSize As Integer
Public rcItem As Rectangle
Public rcButton As Rectangle
Public buttonState As Integer
Public hwndCombo As IntPtr
Public hwndEdit As IntPtr
Public hwndList As IntPtr
Public Sub Init()
cbSize = Marshal.SizeOf(Of COMBOBOXINFO)()
End Sub
End Structure
Friend Function GetComboBoxListInternal(cboHandle As IntPtr) As IntPtr
Dim cbInfo = New COMBOBOXINFO()
cbInfo.Init()
GetComboBoxInfo(cboHandle, cbInfo)
Return cbInfo.hwndList
End Function
End Class