你的.emacs文件里有什么？

Question

最近我换了几次电脑，在这个过程中我丢失了我的.emacs文件。现在我正在尝试重新构建它，但是在此期间，我想学习其他人使用的好的配置。

所以，如果你使用Emacs，你的.emacs文件里有什么呢?

我的.emacs文件现在非常简单，只包含:

1. 全局字体锁定模式!(global-font-lock-mode 1)
2. 我的个人偏好关于缩进，制表符和空格。
3. 使用cperl-mode代替perl-mode。
4. 编译的快捷方式。

你认为哪些设置是有用的呢？

- A. Rex

---

拥有一个只有四行的.emacs文件的人是可疑的。 - Cheeso

@A. Rex：关于不丢失你的*.emacs文件...有几个选项：最近一些人为他们的配置文件设置了DVCS，这样只需一个“push”，就可以免费在线备份。但我觉得这有点牵强，更喜欢一个更简单的方法：我只需将我的（文本）配置文件附加到我的GMail帐户中的电子邮件中（我启用了GMail的POP，这样我也可以获得离线备份我的电子邮件）。有趣的是，昨天我又做了一个“GMAil备份”我的.emacs* :) - SyntaxT3rr0r

Answer 1

使用终极点文件站点。将您的“.emacs”添加到此处。阅读其他人的“.emacs”。

- bortzmeyer

---

接受，从某种意义上讲，它包含了所有其他答案。=) - A. Rex

Answer 2

我最喜欢的代码片段。这是 Emacs 眼睛糖果的终极体现：

;; real lisp hackers use the lambda character
;; courtesy of stefan monnier on c.l.l
(defun sm-lambda-mode-hook ()
  (font-lock-add-keywords
   nil `(("\\<lambda\\>"
   (0 (progn (compose-region (match-beginning 0) (match-end 0)
        ,(make-char 'greek-iso8859-7 107))
      nil))))))
(add-hook 'emacs-lisp-mode-hook 'sm-lambda-mode-hook)
(add-hook 'lisp-interactive-mode-hook 'sm-lamba-mode-hook)
(add-hook 'scheme-mode-hook 'sm-lambda-mode-hook)

当您编辑Lisp/Scheme时，您会看到以下内容：

(global-set-key "^Cr" '(λ () (interactive) (revert-buffer t t nil)))

- Jason Dufair

---

（眼睛翻白，Cheeso倒地，僵硬） - Cheeso

不，眼前最美的是能够为“每一个”模式做那种事情：pretty-mode！（如需更新版本，请参见GitHub） - Francois G

Answer 3

我有一个需求，要将提示框中的"yes"或"no"改为"y"或"n"：

(fset 'yes-or-no-p 'y-or-n-p)

我有以下方法可以启动Emacs而不会出现太多的"炫耀"信息，这些方法来源于这个问题。

(setq inhibit-startup-echo-area-message t)
(setq inhibit-startup-message t)

而Steve Yegge的函数可以重命名您正在编辑的文件以及相应的缓冲区：

(defun rename-file-and-buffer (new-name)
  "Renames both current buffer and file it's visiting to NEW-NAME."
  (interactive "sNew name: ")
  (let ((name (buffer-name))
 (filename (buffer-file-name)))
    (if (not filename)
 (message "Buffer '%s' is not visiting a file!" name)
      (if (get-buffer new-name)
   (message "A buffer named '%s' already exists!" new-name)
 (progn
   (rename-file name new-name 1)
   (rename-buffer new-name)
   (set-visited-file-name new-name)
   (set-buffer-modified-p nil))))))

- Dave Webb

Answer 4

有一个非常有用的方法：在它变得太大之前，尝试将其拆分为多个文件以执行各种任务：我的 .emacs 文件仅设置了我的加载路径并加载了一堆文件 - 所有特定于模式的设置都在 mode-configs.el 文件中，按键绑定在 keys.el 文件中等等。

- jamesnvc

Answer 5

我的.emacs只有127行，以下是最有用的小片段：

;; keep backup files neatly out of the way in .~/
(setq backup-directory-alist '(("." . ".~")))

这会使我发现某些混乱的*~文件进入一个特殊的目录，本例中为.~。

;; uniquify changes conflicting buffer names from file<2> etc
(require 'uniquify)
(setq uniquify-buffer-name-style 'reverse)
(setq uniquify-separator "/")
(setq uniquify-after-kill-buffer-p t) ; rename after killing uniquified
(setq uniquify-ignore-buffers-re "^\\*") ; don't muck with special buffers

这里设置了唯一化（uniquify），可将那些在多个文件名相同时出现的丑陋文件<2>等缓冲区名称转换为更整洁和明确的名称，使用尽可能完整的文件路径。

就是这样...其余部分都是相当标准的内容，我相信每个人都很清楚。

- Borbus

Answer 6

这不是全部的工具包，但这是我收集的一些更有用的片段：

(defadvice show-paren-function (after show-matching-paren-offscreen
                                      activate)
  "If the matching paren is offscreen, show the matching line in the                               
echo area. Has no effect if the character before point is not of                                   
the syntax class ')'."
  (interactive)
  (let ((matching-text nil))
    ;; Only call `blink-matching-open' if the character before point                               
    ;; is a close parentheses type character. Otherwise, there's not                               
    ;; really any point, and `blink-matching-open' would just echo                                 
    ;; "Mismatched parentheses", which gets really annoying.                                       
    (if (char-equal (char-syntax (char-before (point))) ?\))
        (setq matching-text (blink-matching-open)))
    (if (not (null matching-text))
        (message matching-text))))

;;;;;;;;;;;;;;;
;; UTF-8
;;;;;;;;;;;;;;;;;;;;
;; set up unicode
(prefer-coding-system       'utf-8)
(set-default-coding-systems 'utf-8)
(set-terminal-coding-system 'utf-8)
(set-keyboard-coding-system 'utf-8)
;; This from a japanese individual.  I hope it works.
(setq default-buffer-file-coding-system 'utf-8)
;; From Emacs wiki
(setq x-select-request-type '(UTF8_STRING COMPOUND_TEXT TEXT STRING))
;; Wwindows clipboard is UTF-16LE 
(set-clipboard-coding-system 'utf-16le-dos)


(defun jonnay-timestamp ()
  "Spit out the current time"
  (interactive)
  (insert (format-time-string "%Y-%m-%d")))

(defun jonnay-sign ()
  "spit out my name, email and the current time"
  (interactive)
  (insert "-- Jonathan Arkell ([e-mail])")
  (jonnay-timestamp))


;; Cygwin requires some seriosu setting up to work the way i likes it
(message "Setting up Cygwin...")
(let* ((cygwin-root "c:")
       (cygwin-bin (concat cygwin-root "/bin"))
       (gambit-bin "/usr/local/Gambit-C/4.0b22/bin/")
       (snow-bin "/usr/local/snow/current/bin")
       (mysql-bin "/wamp/bin/mysql/mysql5.0.51a/bin/"))
   (setenv "PATH" (concat cygwin-bin ";" ;
                          snow-bin ";" 
                          gambit-bin ";"
                          mysql-bin ";"
                          ".;")  
           (getenv "PATH"))
   (setq exec-path (cons cygwin-bin exec-path)))

(setq shell-file-name "bash")
(setq explicit-shell-file-name "bash")

(require 'cygwin-mount)
(cygwin-mount-activate)
(message "Setting up Cygwin...Done")


; Completion isn't perfect, but close
(defun my-shell-setup ()
   "For Cygwin bash under Emacs 20+"
   (setq comint-scroll-show-maximum-output 'this)
   (setq comint-completion-addsuffix t)
   (setq comint-eol-on-send t)
   (setq w32-quote-process-args ?\")
   (make-variable-buffer-local 'comint-completion-addsuffix))

(setq shell-mode-hook 'my-shell-setup)
(add-hook 'emacs-startup-hook 'cygwin-shell)


; Change how home key works
(global-set-key [home] 'beginning-or-indentation)
(substitute-key-definition 'beginning-of-line 'beginning-or-indentation global-map)


(defun yank-and-down ()
  "Yank the text and go down a line."
  (interactive)
  (yank)
  (exchange-point-and-mark)
  (next-line))

(defun kill-syntax (&optional arg)
  "Kill ARG sets of syntax characters after point."
  (interactive "p")
  (let ((arg (or arg 1))
    (inc (if (and arg (< arg 0)) 1 -1))
    (opoint (point)))
    (while (not (= arg 0))
      (if (> arg 0)
      (skip-syntax-forward (string (char-syntax (char-after))))
    (skip-syntax-backward (string (char-syntax (char-before)))))
      (setq arg (+ arg inc)))
    (kill-region opoint (point))))

(defun kill-syntax-backward (&optional arg)
  "Kill ARG sets of syntax characters preceding point."
  (interactive "p")
  (kill-syntax (- 0 (or arg 1))))

(global-set-key [(control shift y)] 'yank-and-down)
(global-set-key [(shift backspace)] 'kill-syntax-backward)
(global-set-key [(shift delete)] 'kill-syntax)


(defun insert-file-name (arg filename)
  "Insert name of file FILENAME into buffer after point.
  Set mark after the inserted text.

  Prefixed with \\[universal-argument], expand the file name to
  its fully canocalized path.

  See `expand-file-name'."
  ;; Based on insert-file in Emacs -- ashawley 2008-09-26
  (interactive "*P\nfInsert file name: ")
  (if arg
      (insert (expand-file-name filename))
      (insert filename)))

(defun kill-ring-save-filename ()
  "Copy the current filename to the kill ring"
  (interactive)
  (kill-new (buffer-file-name)))

(defun insert-file-name ()
  "Insert the name of the current file."
  (interactive)
  (insert (buffer-file-name)))

(defun insert-directory-name ()
  "Insert the name of the current directory"
  (interactive)
  (insert (file-name-directory (buffer-file-name))))

(defun jonnay-toggle-debug ()
  "Toggle debugging by toggling icicles, and debug on error"
  (interactive)
  (toggle-debug-on-error)
  (icicle-mode))


(defvar programming-modes
  '(emacs-lisp-mode scheme-mode lisp-mode c-mode c++-mode 
    objc-mode latex-mode plain-tex-mode java-mode
    php-mode css-mode js2-mode nxml-mode nxhtml-mode)
  "List of modes related to programming")

; Text-mate style indenting
(defadvice yank (after indent-region activate)
  (if (member major-mode programming-modes)
      (indent-region (region-beginning) (region-end) nil)))

- Jonathan Arkell

---

感谢您帮助我恢复“show-paren-function”，这个函数是我20年前从同事和主管那里复制过来的！ - Yu Shen

Answer 7

我认为以下这些是必不可少的，虽然已经有很多其他人提到了：

(transient-mark-mode 1) ; makes the region visible
(line-number-mode 1)    ; makes the line number show up
(column-number-mode 1)  ; makes the column number show up

- Adam Crume

Answer 8

您可以在这里查看：http://www.dotemacs.de/ 我的.emacs文件太长了，无法在此处展示，这会使答案不易阅读。无论如何，如果您希望，我可以将其发送给您。

此外，我建议您阅读这篇文章：http://steve.yegge.googlepages.com/my-dot-emacs-file

- avp

Answer 9

你可以在我的网站上找到我的配置（包括html页面和打包的tar文件）。其中包含了很多不同模式的设置。

- Alex Ott

Answer 10

以下是我经常使用的一些按键映射:

(global-set-key [(control \,)] 'goto-line)
(global-set-key [(control \.)] 'call-last-kbd-macro)
(global-set-key [(control tab)] 'indent-region)
(global-set-key [(control j)] 'join-line)
(global-set-key [f1] 'man)
(global-set-key [f2] 'igrep-find)
(global-set-key [f3] 'isearch-forward)
(global-set-key [f4] 'next-error)
(global-set-key [f5] 'gdb)
(global-set-key [f6] 'compile)
(global-set-key [f7] 'recompile)
(global-set-key [f8] 'shell)
(global-set-key [f9] 'find-next-matching-tag)
(global-set-key [f11] 'list-buffers)
(global-set-key [f12] 'shell)

其他一些杂项，主要是针对C++开发：

;; Use C++ mode for .h files (instead of plain-old C mode)
(setq auto-mode-alist (cons '("\\.h$" . c++-mode) auto-mode-alist))

;; Use python-mode for SCons files
(setq auto-mode-alist (cons '("SConstruct" . python-mode) auto-mode-alist))
(setq auto-mode-alist (cons '("SConscript" . python-mode) auto-mode-alist))

;; Parse CppUnit failure reports in compilation-mode
(require 'compile)
(setq compilation-error-regexp-alist
      (cons '("\\(!!!FAILURES!!!\nTest Results:\nRun:[^\n]*\n\n\n\\)?\\([0-9]+\\)) test: \\([^(]+\\)(F) line: \\([0-9]+\\) \\([^ \n]+\\)" 5 4)
            compilation-error-regexp-alist))

;; Enable cmake-mode from http://www.cmake.org/Wiki/CMake_Emacs_mode_patch_for_comment_formatting
(require 'cmake-mode)
(setq auto-mode-alist
      (append '(("CMakeLists\\.txt\\'" . cmake-mode)
                ("\\.cmake\\'" . cmake-mode))
              auto-mode-alist))

;; "M-x reload-buffer" will revert-buffer without requiring confirmation
(defun reload-buffer ()
  "revert-buffer without confirmation"
  (interactive)
  (revert-buffer t t))

- Kristopher Johnson