如何使样例运行OpenCV

Question

我正在尝试制作Open CV项目样本，用于模板匹配，如此处所述。 到目前为止我所做的步骤包括：

下载并导入Open CV框架到我的项目中，将.m扩展名文件更改为.mm，在.pch文件中我已经包含了代码

 #ifdef __cplusplus
 #import <opencv2/opencv.hpp>
 #endif

 #ifdef __OBJC__
 #import <UIKit/UIKit.h>
 #import <Foundation/Foundation.h>
 #endif

我还从链接下载并导入了MatchTemplate_Demo.cpp文件。但是在这里出现了库链接问题。

 ld: warning: directory not found for option '-L/Users/G1/Desktop/Xcode'
   ld: warning: directory not found for option '-Lprojects/FirstOpenCv/opencv/lib/debug'
   ld: library not found for -lopencv_calib3d
   clang: error: linker command failed with exit code 1 (use -v to see invocation)

我按照这里给出的步骤来包含库。

2) Add $(SRCROOT)/opencv to header search path and $(SRCROOT)/opencv/lib/debug for library search path for debug configuration and $(SRCROOT)/opencv/lib/release for release build.

3) Add OpenCV libs to linker input by modifying "Other Linker Flags" option with "-lopencv_calib3d -lzlib -lopencv_contrib -lopencv_legacy -lopencv_features2d -lopencv_imgproc -lopencv_video -lopencv_core".

现在请问我应该如何使项目运行。 我已经拿到了源代码和模板图像，并将其导入到项目中。

我现在有ViewController.h和ViewController.mm文件，但不知道这些文件应该编写什么代码才能看到结果。

另外第二步： 我需要使用相机视图实时扫描图像（以便当我将相机放在源图像上时，它应该扫描并找到模板）。

按照此链接：link ，在导入.cppfile时出现链接器错误。

ld: 1 duplicate symbol for architecture i386 clang:
error: linker command failed with exit    code 1 (use -v to see invocation) 

请问有没有人能够建议我如何实现它。

- iOSBee

Answer 1

您有三个相关的问题：

1/ 如何在iOS项目中运行openCV框架
2/ 如何在iOS项目中运行模板匹配c++示例代码
3/ 如何使用相机视图进行实时模板匹配

1/ 如何在iOS项目中运行openCV框架

• 按照您所描述的下载并导入openCV框架。
• 按照您所描述的更改.pch文件。

• 检查您的目标构建设置中是否将c++标准库设置为libc++（这是新项目的默认设置）。

• 不要只是导入demo.cpp而不进行下面所述的更改（它是一个“原始”的c++程序，具有自己的main函数，需要进行修改才能作为iOS / Cocoa项目的一部分工作）。

• 不要搞乱头文件搜索路径、其他链接器标志等，如果您已经从openCV.org导入了预构建的框架，这是不必要的。

• 不要将您的.m文件更改为.mm，除非您知道需要这样做。我的建议是尽可能地将您的c++代码与您的objective-C代码分开，因此大多数文件应该是.m文件（objective-C）或.cpp文件（c++）。只有在您打算在同一文件中混合objective-C和c++时，才需要.mm前缀。

2/ 如何在iOS项目中运行模板匹配c++示例代码

我们将设置这样一个机制，使得您的iOS viewController - 以及大部分iOS代码 - 不需要知道图像是使用openCV / c++处理的，同样的，C++代码也不需要知道它的输入或输出图像数据被路由到哪里。我们通过在两者之间创建一个小型包装器类来实现此目的，该类将objective-C方法调用转换为c++类成员函数并返回。我们还将在UIImage上设置一个类别，以将图像格式从iOS友好的UIImage转换为openCV本地的cv::Mat。

UIImage+OpenCV类别

您需要一些实用程序方法来将UIImage转换为cv::Mat并返回。将它们放置在UIImage类别中是一个好的选择。在XCode中：文件>新建文件>Cocoa Touch>Objective-C类别将为您设置。将该类别命名为OpenCV，并将其设置为UIImage的类别。您需要将此.m文件更改为.mm，因为它需要理解来自openCV框架的c++类型。

头文件应如下所示：

#import <UIKit/UIKit.h>

@interface UIImage (OpenCV)

    //cv::Mat to UIImage
+ (UIImage *)imageWithCVMat:(const cv::Mat&)cvMat;

    //UIImage to cv::Mat
- (cv::Mat)cvMat;

@end

.mm文件应通过紧密遵循此openCV.org代码示例实现这些方法，以作为类别方法进行调整（例如，您不会将UIImage传递到实例方法中，而是使用self引用它）。

您可以像这样使用类别方法，就好像它们是UIImage类和实例方法：

UIImage* image = [UIImage imageWithCVMat:matImage];  //class method

cv::Mat matImage = [image cvMat];  //instance method

openCV包装类

创建一个包装类，将您从viewController调用的Objective-C方法转换为C++函数

头文件应该像这样

//  CVWrapper.h
#import <Foundation/Foundation.h>

@interface CVWrapper : NSObject

+ (NSImage*) templateMatchImage:(UIImage*)image
                          patch:(UIImage*)patch
                         method:(int)method;
@end

我们发送模板图像、路径图像和模板匹配方法，并获得一张显示匹配结果的图像。

实现（.mm文件）

//  CVWrapper.mm
#import "CVWrapper.h"
#import "CVTemplateMatch.h"
#import "UIImage+OpenCV.h"

@implementation CVWrapper


+ (UIImage*) templateMatchImage:(UIImage *)image
                          patch:(UIImage *)patch
                         method:(int)method
{
    cv::Mat imageMat = [image cvMat];
    cv::Mat patchMat = [patch cvMat];

    cv::Mat matchImage = 
           CVTemplateMatch::matchImage(imageMat, 
                                        patchMat,
                                        method);

    UIImage* result =  [UIImage imageWithCVMat:matchImage];
    return result;
}

我们实际上是将标准的Objective-C方法和UIImage类型转换为调用具有C++（openCV框架）类型的成员函数，并将结果转换回UIImage。

C++ TemplateMatch类

头文件：

//  TemplateMatch.h

#ifndef __CVOpenTemplate__CVTemplateMatch__
#define __CVOpenTemplate__CVTemplateMatch__

class CVTemplateMatch
{
public:
    static cv::Mat matchImage (cv::Mat imageMat,
                               cv::Mat patchMat, 
                               int method);
};

#endif /* defined(__CVOpenTemplate__CVTemplateMatch__) */


@end

实现：

这是将模板匹配openCV示例代码重新设计为类实现的代码：

//  TemplateMatch.cpp
/*
 Alterations for use in iOS project
 [1] remove GUI code (iOS supplies the GUI)
 [2] change main{} to static member function 
     with appropriate inputs and return value
 [3] change MatchingMethod{} signature 
     to return Mat value
 */

#include "CVTemplateMatch.h"

    //[1] #include "opencv2/highgui/highgui.hpp"
#include "opencv2/imgproc/imgproc.hpp"
#include <iostream>
#include <stdio.h>

using namespace std;
using namespace cv;

    /// Global Variables
Mat img; Mat templ; Mat result;
    //[1] char* image_window = "Source Image";
    //[1] char* result_window = "Result window";

int match_method; 
    //[1]  int max_Trackbar = 5; 

    /// Function Headers
Mat MatchingMethod( int, void* );  //[3] (added return value to function)

    // [2] /** @function main */
    // [2] int main( int argc, char** argv )

Mat CVTemplateMatch::matchImage (Mat image,Mat patch, int method)
    // [2]
{
        /// Load image and template
        //[2]  img = imread( argv[1], 1 );
        //[2] templ = imread( argv[2], 1 );

    img = image;           //[2]
    templ = patch;         //[2]
    match_method = method; //[2]

        /// Create windows
        //[1] namedWindow( image_window, CV_WINDOW_AUTOSIZE );
        //[1] namedWindow( result_window, CV_WINDOW_AUTOSIZE );

        /// Create Trackbar
        //[1] char* trackbar_label = "Method: \n 0: SQDIFF \n 1: SQDIFF NORMED \n 2: TM CCORR \n 3: TM CCORR NORMED \n 4: TM COEFF \n 5: TM COEFF NORMED";
        //[1] createTrackbar( trackbar_label, image_window, &match_method, max_Trackbar, MatchingMethod );

    Mat result = MatchingMethod( 0, 0 );

        //[1] waitKey(0);
        //[2] return 0;
    return result;  //[2]
}


    //[3] void MatchingMethod( int, void* )
Mat MatchingMethod( int, void* )

{
        /// Source image to display
    Mat img_display;
    img.copyTo( img_display );

        /// Create the result matrix
    int result_cols =  img.cols - templ.cols + 1;
    int result_rows = img.rows - templ.rows + 1;

    result.create( result_cols, result_rows, CV_32FC1 );

        /// Do the Matching and Normalize
    matchTemplate( img, templ, result, match_method );
    normalize( result, result, 0, 1, NORM_MINMAX, -1, Mat() );

        /// Localizing the best match with minMaxLoc
    double minVal; double maxVal; Point minLoc; Point maxLoc;
    Point matchLoc;

    minMaxLoc( result, &minVal, &maxVal, &minLoc, &maxLoc, Mat() );

        /// For SQDIFF and SQDIFF_NORMED, the best matches are lower values. For all the other methods, the higher the better
    if( match_method  == CV_TM_SQDIFF || match_method == CV_TM_SQDIFF_NORMED )
        { matchLoc = minLoc; }
    else
        { matchLoc = maxLoc; }

        /// Show me what you got
    rectangle( img_display, matchLoc, Point( matchLoc.x + templ.cols , matchLoc.y + templ.rows ), Scalar::all(0), 2, 8, 0 );
    rectangle( result, matchLoc, Point( matchLoc.x + templ.cols , matchLoc.y + templ.rows ), Scalar::all(0), 2, 8, 0 );

        //[1]  imshow( image_window, img_display );  
        //[1] imshow( result_window, result );       

    return img_display; //[3] add return value
}

现在在你的viewController中，你只需要调用这个方法：

UIImage* matchedImage = 
       [CVWrapper templateMatchImage:self.imageView.image
                               patch:self.patchView.image
                              method:0];

没有C++，不用担心。

3/ 通过实时摄像头视图进行模板匹配

简单来说：matchTemplate 在实时摄像头的情况下效果不好。该算法在图像中寻找与补丁相同比例和方向的匹配项：它将补丁瓷砖沿其原始方向和大小滑动到图像上，进行最佳匹配比较。如果图像被透视扭曲、大小不同或旋转到不同的方向，则这样做将不能产生很好的结果。

您可以考虑使用OpenCV的特征检测算法，其中一些已经移至非免费版。这里是SIFT的一个很好的描述，可以给您提供思路。对于视频捕获，您可能还需要查看opencv2/highgui中的cap_ios.h：这里有一个教程。

- foundry

Answer 2

实际上，您已经下载了编译好的库，因此无需按照您在问题中提到的步骤进行操作，这是问题所在（即您遵循了错误的步骤），因为那些步骤是将源代码编译成静态库的步骤。

请按照以下步骤操作：

• 解压下载的框架。您可以看到一个名为“opencv2.framework”的文件夹
• 将该文件夹直接拖入项目中（注意：当您将该文件夹拖入Xcode时，Xcode会提示对话框，其中有一个复选框，用于将其实际复制到文件夹中，请勾选该复选框）
• 在.pch文件中像您在问题中提到的那样导入openCV是正确的方式
  现在进行编译。
  还有一件事，无论何时您想要使用openCV的函数，该文件都应具有.mm扩展名（即Objective C++源代码），它将完美运行。 帮助链接:

- Iducool

---

感谢你的回答 @lducool，你给我的帮助链接非常有效，但是当我将模板匹配（http://docs.opencv.org/doc/tutorials/imgproc/histograms/template_matching/template_matching.html）.cpp文件导入项目时，出现了链接错误...我应该如何解决这个问题？ - iOSBee

ld: i386 架构下有 1 个重复符号 clang: 错误: 链接器命令失败，退出码为 1 (使用 -v 选项查看调用) - iOSBee

为什么你要尝试导入那个文件？那个文件可能已经包含在openCV框架中了。试着去检查一下吧。 - Iducool

我刚刚尝试了将那个文件包含进来，并从该文件中删除了不必要或不兼容的语句，现在它可以正常工作了。 - Iducool

@lducool，你能否现在将这些语句包含在你的答案中？ - iOSBee