如何使Unity3D自定义着色器透明？

Question

我有一个自定义着色器，可以在对象内部（例如：球体）渲染纹理。但是我无法使其透明，因为Unity说该着色器中没有添加_Color属性。

我不是Unity Shader的专家，所以需要一些帮助来修改我的现有着色器。以下是我的着色器代码。

Shader "InsideVisible" 
{
    Properties 
    {
        _MainTex ("Base (RGB)", 2D) = "white" {}
    }

    SubShader 
    {
        Tags { "RenderType"="Opaque" }
        Cull front
        LOD 100

        Pass 
        {  
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata_t {
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f {
                float4 vertex : SV_POSITION;
                half2 texcoord : TEXCOORD0;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata_t v)
            {
                v2f o;

                o.vertex     = mul(UNITY_MATRIX_MVP, v.vertex);
                v.texcoord.x = 1 - v.texcoord.x;                
                o.texcoord   = TRANSFORM_TEX(v.texcoord, _MainTex);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.texcoord);
                return col;
            }

            ENDCG
        }
    }
}

- XpressGeek

---

当在Unity中应用该着色器时，它似乎能够正常工作。你是不是尝试从脚本或其他地方访问“_Color”属性？ - Jephron

是的，我正在尝试通过脚本使其透明化。普通标准着色器很容易变得透明，但这个自定义着色器不行。否则，这个着色器完美地工作着。 - XpressGeek

Answer 1

你的脚本可能尝试访问名为_Color的属性并设置其透明度值，但是此着色器上没有_Color属性，因此脚本失败。

而且着色器没有设置透明度，所以我们需要修复它。

着色器属性有点像在C#类上公开的公共属性：外部世界可以操纵它们以改变着色器渲染的方式。

在片段中，我们将图像颜色乘以_Color属性，以便它可以控制着色和透明度。

要使您的着色器呈现透明度，您还需要向SubShader和Pragma添加几行代码。

Shader "InsideVisible" 
{
    Properties 
    {
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _Color ("Color (RGBA)", Color) = (1, 1, 1, 1) // add _Color property
    }

    SubShader 
    {
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha
        Cull front 
        LOD 100

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert alpha
            #pragma fragment frag alpha

            #include "UnityCG.cginc"

            struct appdata_t 
            {
                float4 vertex   : POSITION;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f 
            {
                float4 vertex  : SV_POSITION;
                half2 texcoord : TEXCOORD0;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _Color;

            v2f vert (appdata_t v)
            {
                v2f o;

                o.vertex     = mul(UNITY_MATRIX_MVP, v.vertex);
                v.texcoord.x = 1 - v.texcoord.x;
                o.texcoord   = TRANSFORM_TEX(v.texcoord, _MainTex);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.texcoord) * _Color; // multiply by _Color
                return col;
            }

            ENDCG
        }
    }
}

- Jephron

---

现在那个可行了。非常感谢！这正是我寻找了10天之久的正确解决方案！ - XpressGeek

谢谢。我发现在我的情况下我不需要使用“Cull front”，因为这会移除实际的阴影。 - Ash