XSLT：提取唯一属性值

Question

请帮忙，我是XSLT新手，正在尝试将一个XML格式转换为另一个。

我需要提取唯一的属性值，并将这些值转换为新的格式。下面的示例XML显示了原始和新/目标格式。

我已经花费了很长时间，但没有任何收获。有人能帮忙或给我一些指导吗？

原始格式：

<base>
  <level>
    <level2 Name ="AA" value="1"/>
  </level>
  <level>
    <level2 Name ="BB" value="2"/>
  </level>
  <level>
    <level2 Name ="BB" value="3"/>
  </level>
  <level>
    <level2 Name ="CC" value="4"/>
  </level>
  <level>
    <level2 Name ="AA" value="5"/>
  </level>
</base>

新格式：

<base>
  <levelNames>
    <level level2Name ="AA"/>
    <level level2Name ="BB"/>
    <level level2Name ="CC"/>
  </levelNames>
</base>

非常感谢。

- SuperSuperDev1234

---

请发布您已经尝试过的XSLT，我们会提出建议。 - skaffman

Answer 1

XSLT 解决方案：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:key name="LevelDistint" match="level2" use="@Name"/>
    <xsl:template match="base">
        <base>
            <levelNames>
                <xsl:for-each select="level/level2[generate-id() = generate-id(key('LevelDistint', @Name)[1])]">
                    <level>
                        <xsl:attribute name="level2Name"><xsl:value-of select="normalize-space(@Name)"/></xsl:attribute>
                    </level>
                </xsl:for-each>
            </levelNames>
        </base>
    </xsl:template>
</xsl:stylesheet>

XSLT 输出：

<?xml version="1.0" encoding="UTF-8"?>
<base>
    <levelNames>
        <level level2Name="AA"/>
        <level level2Name="BB"/>
        <level level2Name="CC"/>
    </levelNames>
</base>

- Rashmi Pandit

Answer 2

再一次，Muenchian分组技术似乎是缺失的关键。

对于IT技术来说，这是一个比较简单的问题，所以我会让您自己去学习并掌握Muench。

- annakata

---

我在投票支持和继续前进、发布解决方案和感到内疚之间犹豫不决。该死的你。:-D 但你可能是对的，怀疑这是作业，所以我克制了自己。 - Tomalak

如果你做过一次，你就会发现它真的很容易。你只需要理解这个想法。对于大多数常见的XSLT问题，我真的建议先在这里查看：http://www.dpawson.co.uk/xsl/sect2/sect21.html - Boldewyn

@Boldewyn - 是的，对于初学者来说这是一份极好的资源，尽管它外观不太美观 :) - annakata

叹气 有人能解释一下为什么要踩我吗？是因为我没有替楼主完成他的工作吗？ - annakata

Answer 3

请先创建 xsl:key，然后您就可以轻松使用下面的代码。

xsl:key 名称="levelName" 匹配="level2" 使用="@Name"

<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="base">
    <xsl:element name="{local-name(.)}">
        <xsl:element name="levelNames">
           <xsl:apply-templates/>
        </xsl:element>
    </xsl:element>
</xsl:template>

    <xsl:template match="level">
        <xsl:for-each select="level2[count(.|key('levelName', @Name)[1]) = 1]">
            <xsl:sort order="ascending" data-type="text" select="@Name"/>
            <xsl:element name="{local-name(..)}">
                <xsl:attribute name="level2Name">
                    <xsl:value-of select="@Name"/>
                </xsl:attribute>
            </xsl:element>
        </xsl:for-each>
    </xsl:template>

-