XSLT选择唯一节点

Question

这让我发疯了，对于像我这样的XSLT新手来说。

输入：

<root>
    <a><name>kyle</name></a>
    <b><name>stan</name></b>
    <b><name>wendy</name></b>
    <b><name>cece</name></b>
</root>

预期输出：

<root>
        <a><name>kyle</name></a>
        <b><name>stan</name></b>
</root>

我被要求返回“root”下第一个唯一的节点，应该如何实现？

使用xslt 1.0或2.0均可。

非常感谢！！！

- AlbionKyle

Answer 1

您可以匹配任何具有相同名称的前置兄弟元素，并且不输出任何内容。

XSLT示例：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/*/*[preceding-sibling::*[name() = current()/name()]]"/> 

</xsl:stylesheet>

输出（使用Saxon 9 HE）：

<root>
   <a>
      <name>kyle</name>
   </a>
   <b>
      <name>stan</name>
   </b>
</root>

- Daniel Haley

Answer 2

XSLT 2.0 解决方案：

<?xml version="2.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/">
  <root>
    <xsl:for-each-group select="root/*" group-by="local-name()">
      <xsl:copy-of select="."/>
    </xsl:for-each-group>
    </root>
  </xsl:template>
</xsl:stylesheet>

输出：

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <a>
      <name>kyle</name>
  </a>
   <b>
      <name>stan</name>
  </b>
</root>

- FailedDev