Haskell QuickCheck 生成和测试玫瑰树？

Question

Haskell QuickCheck 生成和测试玫瑰树？

7

我正在尝试一个简单的玫瑰树代码。

data RoseT a = Leaf a | Node a [RoseT a] deriving (Show)

instance Eq (RoseT a) where
 (==) (Leaf a) (Leaf b) = a == b
 (==) (Node a rs1) (Node b rs2) = and ((a==b): (zipWith (==) rs1 rs2))
 (==) _ _ = False

我能使用QuickCheck来测试Eq实例的实现吗？如果可以，如何使用？如果不行，有什么更好的替代方案吗？

我还有一个函数，它执行以下操作：

appendPath :: (RoseT a) -> (RoseT (a,[a]))
appendPath rst = appendPath' [] rst 

appendPath :: [a] -> (RoseT a) -> (RoseT (a,[a]))
appendPath' p (Leaf a) = Leaf (a,p)
appendPath' p (Node a rs) = Node (a,p) (map (appendPath' (a:p)) rs)

函数 appendPath 接受一个玫瑰树作为输入，并返回一棵带有从节点到根的路径信息的玫瑰树。我会在另一个函数中使用这些信息。

我如何使用 quickcheck 在大型玫瑰树上检查此实现？

编辑： 如 mhwombat 建议的那样，似乎不可能编写一个以类型参数为参数的生成器。所以这是我的类型参数。我想构建一个表示有效随机算术表达式的字符串的 RoseT，其中算术表达式本身遵循以下结构：

data Expr = Var String | AddExpr [Expr] | MulExpr [Expr] deriving Show

因此，是否有一种方法可以仅使用 quickcheck 生成随机的 RoseT Expr，其中 Expr 自身是随机生成的？

再次感谢 mhwombat，耐心引导我做出进展。

- Tem Pora

你想测试什么？使用QuickCheck测试关于你的树的属性肯定是可行的，但你有什么想法呢？ - daniel gratzer

你的 RoseT 定义似乎不正确。玫瑰树在其 ADT 中不应该有 Leaf 模式，因为使用该定义会导致叶节点的书写方式不明确，即是 Leaf 42 还是 Node 42 []。这是不明确的，因为这两个表达式应该是相等的，但它们并不相等。 - Daniel Dinnyes

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- mhwombat · Accepted Answer

除非我漏掉了什么，你对 RoseT 的 Eq 实现与默认派生实现相同。因此，你可以直接这样说：

data RoseT a = Leaf a | Node a [RoseT a] deriving (Show, Eq)

并且忘记 instance Eq (RoseT a) where 的内容。

下一个问题是这是否能满足您的测试需求。如果您正在使用浮点类型参数进行测试，例如 RoseT Double，那么您需要考虑由于舍入而产生的差异。在这种情况下，您需要一个比较两个树的函数，并查看值是否“足够接近”。

但是，我怀疑您的 RoseT 实现不会以任何方式依赖于类型参数。在这种情况下，您可以使用简单的类型（如 Char 或 Int）对其进行测试，并使用 == 进行任何所需的比较。

您有两个 appendPath 的类型签名。我认为第二个应该是 appendPath'：

appendPath' :: [a] -> (RoseT a) -> (RoseT (a,[a]))

现在来讲如何进行测试。最好你/QuickCheck能够对被测试的树的复杂度进行一定的控制。这样做有助于你，因为最简单的树将首先进行测试，因此你可以“早期”发现错误（即使用更简单的测试用例进行调试）。你可以通过实现一个适用于你的类的“大小”生成器来实现这一点。以下是一种方法。 "size" 参数的值越高，树具有的层数就越多。

type TestRoseT = RoseT Char

sizedArbTestRoseT :: Int -> Gen TestRoseT
sizedArbTestRoseT 0 = do
  c <- arbitrary
  return $ Leaf c
sizedArbTestRoseT n = do
  c <- arbitrary
  subtreeCount <- choose (0,n-1)
  subtrees <- vectorOf subtreeCount (sizedArbTestRoseT (n-1))
  return $ Node c subtrees

instance Arbitrary TestRoseT where
  arbitrary = sized sizedArbTestRoseT

prop_appendPath_does_something :: TestRoseT -> Property
prop_appendPath_does_something t = undefined -- stub

我们可以这样对生成的测试数据进行抽样：

λ> sample (sizedArbTestRoseT 2)
Node '\a' [Node '\RS' []]
Node '?' []
Node '\158' []
Node 'o' [Node 'E' []]
Node '\196' []
Node '4' [Node 'G' []]
Node ';' [Node 'f' []]
Node 'A' [Node '\CAN' []]
Node '!' []
Node 'q' [Node '\t' []]
Node '\'' [Node '\212' []]

编辑：

对于您的Expr类型，我们可以编写以下生成器：

sizedArbExpr :: Int -> Gen Expr
sizedArbExpr 0 = do
  s <- arbitrary
  return $ Var s
sizedArbExpr n = do
  es <- vectorOf 2 (sizedArbExpr (n-1))
  elements [AddExpr es, MulExpr es]

instance Arbitrary Expr where
  arbitrary = sized sizedArbExpr

我们需要修改TestRoseT及其生成器，以使树的复杂度与“size”参数一致。

type TestRoseT = RoseT Expr

sizedArbTestRoseT :: Int -> Gen TestRoseT
sizedArbTestRoseT 0 = do
  c <- sizedArbExpr 0 -- changed this to keep complexity in bounds
  return $ Leaf c
sizedArbTestRoseT n = do
  c <- sizedArbExpr (n-1) -- changed this to keep complexity in bounds
  subtreeCount <- choose (0,n-1)
  subtrees <- vectorOf subtreeCount (sizedArbTestRoseT (n-1))
  return $ Node c subtrees

测试这些修改后，会得到类似以下的结果：

λ> sample (sizedArbTestRoseT 3)
Node (MulExpr [MulExpr [Var "",Var ""],AddExpr [Var "",Var ""]]) [Node (MulExpr [Var "",Var ""]) [Node (Var "") []]]
Node (MulExpr [AddExpr [Var "",Var ""],AddExpr [Var "",Var ""]]) [Node (AddExpr [Var "",Var ""]) []]
Node (MulExpr [AddExpr [Var "\164D",Var "\151\246\FS"],MulExpr [Var ":\149j\EM",Var "h\253\255"]]) [Node (MulExpr [Var "\CAN\a\ACK",Var "\184"]) [Node (Var "t\154]\\") []],Node (MulExpr [Var "\135",Var "\f\DEL\\"]) [Node (Var "\SOH\DEL") []]]
Node (AddExpr [AddExpr [Var "",Var ""],MulExpr [Var "Kj\STXV",Var "D\141<s\187"]]) []
Node (AddExpr [MulExpr [Var "\252",Var "`"],MulExpr [Var "\167`t\196",Var ":\135\NULdr\237\167"]]) []
Node (AddExpr [MulExpr [Var "]\173\&28D\SOCom",Var "^\196\ETB2\216\&2\GS\ENQ\ENQ"],AddExpr [Var "$bB\212\SOH\146\234",Var "\DC3\213\&3\SUB\\}^\246(\200"]]) [Node (MulExpr [Var "l;\133\EM\147#\SUBN\\\t",Var "\235\151U\129m3|"]) [Node (Var "\NULb\133") []],Node (AddExpr [Var "\187\EOT\165S\207\r\"\RS",Var "4"]) []]
Node (MulExpr [MulExpr [Var "%0eK",Var "`N**k\FS6\NAK"],MulExpr [Var "'lUL\NAKRPc\ENQR",Var "j\232+`\FS@n"]]) [Node (AddExpr [Var "H\DC1C%\DC48<\t\ETX.L",Var "\235+\v\STXX,\NAK\SUBQc="]) [Node (Var "f\254oX?w\224\195~/") []]]
Node (AddExpr [AddExpr [Var "P",Var "\148G\STX\DEL*\136(\161\159\&7"],AddExpr [Var "\218\136-",Var "9?\128\159\b\b%3t}\131qe"]]) [Node (MulExpr [Var "\198\249\&4\176\193/}\DC28",Var ")Gl0ym\GS"]) [Node (Var ")\204\226qA\175") []]]
Node (MulExpr [MulExpr [Var "\t\186r.",Var "j\ENQ\183\NUL\NAK\129:rg[\170o\157g\238"],AddExpr [Var "\218F\226\248\156\225\&1",Var "vu\SOH\138+CKW\EM\167\&1n"]]) [Node (MulExpr [Var ",\241\158={o\182\"5\t\STX\ETX\DC2\218\162",Var "\197\&1"]) [Node (Var "u?a};\238") []]]
Node (MulExpr [MulExpr [Var "*",Var "R"],AddExpr [Var "\CAN8C",Var "\232V.\172ILy\162a"]]) []
Node (MulExpr [MulExpr [Var "\SI\240NF\249-\v$",Var "K`\STX\231w{"],MulExpr [Var "\DC1\255\209",Var "/\227\146\236\STX\185T3r\f"]]) [Node (MulExpr [Var "\229,\DLE\NAKwf[7P\160\DEL",Var "\134#\RS\SI0KCg\195\NAK\"\191\&6\243\193\SI"]) [Node (Var "\226\&7b8\f\EOTgF\171\GS}\189c\SUBc\ETX") []]]

顺便说一下，你说“看起来不可能编写一个以类型参数作为参数的生成器”。实际上是可以做到的，但我认为这并不是你真正想要的。另外，有点不寻常的是你想创建一棵树(RoseT)，其中叶子包含二叉树(Expr)。换句话说，你正在创建树的树。当然，我不知道你的应用场景。