批处理脚本 - 更改桌面上文件夹的图标（Windows XP）

Question

我该如何通过命令行/批处理脚本在Windows XP中更改桌面文件夹的图标/图片？

我将在我的一个脚本中创建一个事件，当新文件插入文件夹时，将图标更改为感叹号图像以提醒用户。

- Anthony Miller

---

如果您能澄清您正在显示此文件夹图标的上下文，那将会很有帮助。它是桌面应用还是Web应用？使用的操作系统是什么？ - Martin

Windows XP，涉及桌面图标。 - Anthony Miller

Answer 1

将您的image.ico保存到桌面。
以下操作将在桌面上创建一个名为test的文件夹，并创建一个desktop.ini文件，用于将所需的图像文件与之关联。

CD "%userprofile%\desktop"
MKDIR "TEST FOLDER"
ATTRIB +s "TEST FOLDER"
CD "TEST FOLDER"
COPY /Y "%userprofile%\desktop\image.ico" "./image.ico"
ECHO [.ShellClassInfo] >> desktop.txt
ECHO ConfirmFileOp=0 >> desktop.txt
ECHO NoSharing=1 >> desktop.txt
ECHO IconFile=image.ico >> desktop.txt
ECHO IconIndex=0 >> desktop.txt
ECHO InfoTip= >> desktop.txt
CHCP 1252 >NUL
CMD.EXE /D /A /C (SET/P=ÿþ)<NUL > desktop.ini 2>NUL
CMD.EXE /D /U /C TYPE desktop.txt >> desktop.ini
DEL /F /Q desktop.txt
ATTRIB +S +H desktop.ini image.ico

只要是新文件夹（不是已删除并重新创建的），图像会立即显示出来。如果您只是“mkdir”最近删除的文件夹，则需要刷新桌面才能看到更改（缓存？）。

- Anthony Miller

---

那是一些非常高超的技巧。非常有帮助。谢谢！ - dgo

那么，要对现有文件夹执行此操作，您只需键入“mkdir newstuff && rmdir newstuff”，这样会强制刷新桌面吗？ - PsychoData

感谢您的回答。请修复第五行的拼写错误：“%userprofile%”。我试图自己解决，但愚蠢的“编辑必须超过6个字符”的规则妨碍了我。 - Hashim Aziz

这行代码的作用是什么？CMD.EXE /D /A /C (SET/P=ÿþ)<NUL > desktop.ini 2>NUL？ - lalthomas

Answer 2

您应该将desktop.ini文件放在文件夹内，具体请看这里： http://perishablepress.com/press/2006/10/16/folder-background-images-in-winxp/ 更多相关信息请参考： http://msdn.microsoft.com/en-us/library/cc144102(v=vs.85).aspx

- user663896

---

微软链接加一 =D - Anthony Miller

Answer 3

"Mechaflash"的答案在我的系统（Windows XP SP3）上没有起作用...但是这个方法有效：
打开一个工作文件夹，将一个图标放入其中（“Desktop.ini.ico”），并加入这个批处理文件：

@ECHO OFF  
PUSHD "%~dp0"  
MKDIR "NEW CUSTOM FOLDER"  
ATTRIB -R "NEW CUSTOM FOLDER"  
ATTRIB -H -R "NEW CUSTOM FOLDER\Desktop.ini.ico"  
ATTRIB -H -R "NEW CUSTOM FOLDER\Desktop.ini"  
COPY /Y "Desktop.ini.ico" "NEW CUSTOM FOLDER\Desktop.ini.ico"  
ECHO [.ShellClassInfo] > "NEW CUSTOM FOLDER\Desktop.ini"  
ECHO IconFile=Desktop.ini.ico >> "NEW CUSTOM FOLDER\Desktop.ini"  
ECHO IconIndex=0 >> "NEW CUSTOM FOLDER\Desktop.ini"  
ECHO InfoTip=This folder InfoTip text is inside "Desktop.ini" >> "NEW CUSTOM FOLDER\Desktop.ini"  
ATTRIB +H +R "NEW CUSTOM FOLDER\Desktop.ini.ico"  
ATTRIB +H +R "NEW CUSTOM FOLDER\Desktop.ini"  
ATTRIB +R "NEW CUSTOM FOLDER"  
POPD  
EXIT  

双击批处理文件，然后你的“新自定义文件夹”就会出现在你的工作文件夹里。

- derty2