Delphi TThread.CurrentThread和EAccessViolation - 这是一个错误还是我的无能？

Question

Delphi TThread.CurrentThread和EAccessViolation - 这是一个错误还是我的无能？

delphidelphi-2009tthread

11

在Delphi 2009中，每当我在应用程序中使用TThread.CurrentThread时，当应用程序关闭时会出现以下错误消息:

Exception EAccessViolation in module ntdll.dll at 0003DBBA.
Access violation at address 7799DBBA in module 'ntdll.dll'.  Write of
address 00000014.

除非只是我的电脑有问题，否则你可以在几秒钟内重现这个问题：创建一个新的Delphi表单应用程序，在表单中添加一个按钮，并使用以下代码作为按钮事件处理程序：

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CurrentThread;
end;

在我的Vista机器和XP机器上，如果我不点击按钮，一切都很好，但是如果我点击按钮，当我关闭应用程序时会出现以上错误消息。因此，我在想这是否是一个错误，但同时我认为我可能只是没有理解如何在Delphi中使用TThreads的一些非常基本的东西。我有点像Delphi新手。

如果没有问题，并且您拥有Delphi 2009，则在实现我的简单示例项目时是否会遇到相同的问题？

更新：正如下面的François所指出的那样，实际上这是Delphi 2009目前存在的一个错误-您可以在此处投票支持。

更新：这个错误在Delphi 2010中得到了修复。

- MB

我刚刚花了几个小时来弄清楚我做错了什么。然后我发现了这个问题 :-( - Roddy

QC报告的链接对我无效。我得到一个“要么该页面不存在，要么您没有权限访问它”的错误页面。 - Mason Wheeler

4个回答

12

在CodeGear发布修复程序之前，您可以使用下面的补丁。将其保存到独立单元中，并在程序的任何位置使用它。我还会尝试将其添加到QC中。

此版本适用于D2009（原版）、更新1和更新2。

{ Fix Delphi 2009's invalid finalization order in Classes.pas.
  Written by Primoz Gabrijelcic, http://gp.17slon.com.
  No rights reserved - released to public domain.
}
unit FixD2009Classes;

interface

implementation

uses
  Windows,
  SysUtils,
  Classes;

type
  TCode = array [0..109] of byte;

{$WARN SYMBOL_PLATFORM OFF}

procedure PatchClasses;
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
var
  i         : integer;
  oldProtect: cardinal;
  pCode     : ^TCode;
  tmp       : DWORD;
const
  COffsets_Call: array [1..12] of integer = (0, 15, 24, 34, 49, 59, 69, 79, 89, 94, 99, 109);
  COffset_UnRegisterModuleClasses = 106;
  COffset_DoneThreadSynchronization = 94;
  COffset_FreeExternalThreads = 99;
  CCallDelta = COffset_FreeExternalThreads - COffset_DoneThreadSynchronization;
{$IFEND}
{$ENDIF}
begin
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
  pCode := pointer(cardinal(@TStreamReader.ReadToEnd) + COffset_UnRegisterModuleClasses);
  Win32Check(VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], PAGE_READWRITE, oldProtect));
  try
    for i := Low(COffsets_Call) to High(COffsets_Call) do
      if pCode^[COffsets_Call[i]] <> $E8 then
        raise Exception.Create('Unexpected version of Classes - cannot patch');
    tmp := PDword(@pCode^[COffset_DoneThreadSynchronization+1])^;
    PDword(@pCode^[COffset_DoneThreadSynchronization+1])^ :=
      PDword(@pCode^[COffset_FreeExternalThreads+1])^ + CCallDelta;
    PDword(@pCode^[COffset_FreeExternalThreads+1])^ := tmp - CCallDelta;
  finally VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], oldProtect, oldProtect); end;
{$IFEND}
{$ENDIF}
end;

initialization
  PatchClasses;
end.

- gabr

+1 感谢 gabr！你刚刚为我提供了一个解决方案，我已经追踪了几天的问题！ - jpfollenius

5

Delphi 2009的补丁单元，更新版本为3。

{ Fix Delphi 2009's invalid finalization order in Classes.pas.
  Written by Primoz Gabrijelcic, http://gp.17slon.com.
  No rights reserved - released to public domain.

  D2009 update 3 only.
}
unit FixD2009Classes;

interface

implementation

uses
  Windows,
  SysUtils,
  Classes;

type
  TCode = array [0..144] of byte;

{$WARN SYMBOL_PLATFORM OFF}

procedure PatchClasses;
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
var
  i         : integer;
  oldProtect: cardinal;
  pCode     : ^TCode;
  tmp       : DWORD;
const
  COffsets_Call: array [1..12] of integer = (0, 15, 24, 42, 47, 58, 73, 91, 101, 111, 134, 139);
  COffset_UnRegisterModuleClasses = 107;
  COffset_DoneThreadSynchronization = 134;
  COffset_FreeExternalThreads = 139;
  CCallDelta = COffset_FreeExternalThreads - COffset_DoneThreadSynchronization;
{$IFEND}
{$ENDIF}
begin
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
  pCode := pointer(cardinal(@TStreamReader.ReadToEnd) + COffset_UnRegisterModuleClasses);
  Win32Check(VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], PAGE_READWRITE, oldProtect));
  try
    for i := Low(COffsets_Call) to High(COffsets_Call) do
      if pCode^[COffsets_Call[i]] <> $E8 then
        raise Exception.Create('Unexpected version of Classes - cannot patch');
    tmp := PDword(@pCode^[COffset_DoneThreadSynchronization+1])^;
    PDword(@pCode^[COffset_DoneThreadSynchronization+1])^ :=
      PDword(@pCode^[COffset_FreeExternalThreads+1])^ + CCallDelta;
    PDword(@pCode^[COffset_FreeExternalThreads+1])^ := tmp - CCallDelta;
  finally VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], oldProtect, oldProtect); end;
{$IFEND}
{$ENDIF}
end;

initialization
  PatchClasses;
end.

- gabr

0

我认为CurrentThread是在2009年（或2007年）添加的。我家里有2006年的版本。但你确定它是一个类属性吗？

- Gamecat

是的，非常确定 - 接口声明属性的方式如下：class property CurrentThread: TThread read GetCurrentThread; - MB.

哦，是的，我相信我在另一个帖子中看到Barry Kelly（Delphi编译器专家）提到CurrentThread是Delphi 2009中的新功能。 - MB.

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- François · Accepted Answer

很不幸，这似乎是与 Classes 单元中最终化部分的调用顺序相关的错误：
DoneThreadSynchronization 清除 ThreadLock 结构，接着
FreeExternalThreads 想要销毁 Thread 对象（在调用 CurrentThread 时刚创建），
这需要在调用 TThread.RemoveQueuedEvents 中的 EnterCriticalSection(ThreadLock) 时已经初始化好 ThreadLock...
更新：
现在，在QC 报告中有一个解决补丁。