Mathematica：将矩阵数据写入XML；从XML读取矩阵数据

Question

Mathematica：将矩阵数据写入XML；从XML读取矩阵数据

4

我所处理的对象的矩阵表示的一部分如下：

 {
 {1, A,{100,  20, 30},10},
 {2, B,{100}, 0},
 {3, X,{120,20},0},
 {4, C,{},11}
 }

我希望将此数据以XML格式存储在外部，如下所示： 1002030 100 12020 我正在寻找一个例子来:

- 将矩阵转换为XML(使用哪些Mathematica命令?)。 - 导入XML文件后将XML字符串解析回矩阵格式。

- nilo de roock

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Leonid Shifrin · Accepted Answer

在这里，我们将您的数据作为符号XML导入：

In[50]:= xml = Import["C:\\Temp\\matrixData.xml"]

Out[50]= XMLObject["Document"][{}, 
 XMLElement["data", {}, 
 {XMLElement["row", {"key" -> "1", "val1" -> "A", "val2" -> "10"}, 
      {XMLElement["occ", {}, {"100"}], XMLElement["occ", {}, {"20"}], 
        XMLElement["occ", {}, {"30"}]}], 
  XMLElement["row", {"key" -> "2", "val1" -> "B", "val2" -> "0"},
      {XMLElement["occ", {}, {"100"}]}],
  XMLElement[ "row", {"key" -> "3", "val1" -> "X","val2" -> "0"}, 
      {XMLElement["occ", {}, {"120"}], XMLElement["occ", {}, {"20"}]}], 
  XMLElement["row", {"key" -> "4", "val1" -> "C", "val2" -> "11"}, {}]}], {}]

在这里，我们将其解析为矩阵：

In[51]:= matr = 
 xml /. XMLObject["Document"][{}, data_, _] :> data /. 
     XMLElement["data", _, children_] :> children /. 
         XMLElement["row", attrs_, vals_] :> {"key" /. attrs, 
             "val1" /. attrs, vals /. XMLElement["occ", _, {val_}] :> val, 
             "val2" /. attrs} /. s_String :> ToExpression[s]

 Out[51]= {{1, A, {100, 20, 30}, 10}, {2, B, {100}, 0}, {3,X, {120, 20}, 0}, {4, C, {}, 11}}

由于使用了规则嵌套技术，这段代码变得简短而经济。我在这里讨论它：here。这种技术的一个很好的应用可以在这里找到：here。

这是反向的：

XMLObject["Document"][{}, XMLElement["data", {},
  Replace[matr, {key_, val1_, vals_List, val2_} :>
      XMLElement[ "row", {"key" -> ToString[key], "val1" -> ToString[val1], 
          "val2" -> ToString[val2]},
             XMLElement["occ", {}, {ToString[#]}] & /@ vals], {1}]], {}]

虽然我没有展示结果，但这与导入的符号 XML 相同。您可以使用此符号 XML 调用 Export，它将知道如何处理它。