如何在T-SQL中拆分字符串？

Question

我有一个varchar @a='a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p'变量，其中包含以|分隔的值。我想将这个变量拆分成数组或表格。

请问该如何操作？

- Vaibhav Jain

---

https://dev59.com/XnRC5IYBdhLWcg3wYP-h，https://dev59.com/RXRB5IYBdhLWcg3wLUu3 - Daniel Vassallo

可能是https://dev59.com/GnVD5IYBdhLWcg3wXacd的重复问题。 - Matt Hamilton

Answer 1

像这样使用表值函数：

CREATE FUNCTION Splitfn(@String varchar(8000), @Delimiter char(1))       
returns @temptable TABLE (items varchar(8000))       
as       
begin       
    declare @idx int       
    declare @slice varchar(8000)       

    select @idx = 1       
        if len(@String)<1 or @String is null  return       

    while @idx!= 0       
    begin       
        set @idx = charindex(@Delimiter,@String)       
        if @idx!=0       
            set @slice = left(@String,@idx - 1)       
        else       
            set @slice = @String       

        if(len(@slice)>0)  
            insert into @temptable(Items) values(@slice)       

        set @String = right(@String,len(@String) - @idx)       
        if len(@String) = 0 break       
    end   
return      

end

获取您的变量，并像这样使用此函数：

SELECT i.items FROM dbo.Splitfn(@a,'|') AS i

- ACP

---

@gbn，数字表格比循环执行更快吗？能否详细解释一下？ - ACP

请在我的回答中查看我的链接。 - gbn

有更优雅的解决方案，但是当支持SQL 2005及以下版本的遗留代码库时，这是唯一的选择。 - Manuel Castro

你应该清理从函数返回的临时表吗？ - nulltron

Answer 2

尝试这个：

declare @a varchar(10) 
set @a = 'a|b|c|'
while len(@a) > 1
begin
insert into #temp
select substring(@a,1,patindex('%|%',@a)-1);
set @a = substring(@a,patindex('%|%',@a)+1,len(@a))
end;

- niceApp

---

不错的解决方案，但需要澄清 - 字符串以分隔符号结尾很重要。如果没有 - 你会陷入无限循环。 - Alexey Shcherbak

我的建议是在你的“set @a”行后添加以下语句：IF(patindex('%|%',@a)=0) BEGIN INSERT INTO #temp select @a; BREAK; END; - Alexey Shcherbak

Answer 3

总的来说，这是一个常见的问题。

我会给出常见的答案：Erland Sommarskog的SQL Server 2005和更高版本中的数组和列表。

对于一般用途，我建议使用数字表，而不是循环。请注意保留HTML标签。

- gbn

---

也许您可以通过解释如何将此方法应用于在每个分隔符处拆分文本来改进答案。=) - jumxozizi

Answer 4

这里有一个基于XML的替代方案。它似乎具有与Splitfn()解决方案类似的性能。

这将varchar a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p转换为XML abcdefghijklmnop并从每个XML 节点中提取值。

declare @a      varchar(max);
set @a  =   'a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p';

declare @xml    xml;
set @xml    
    =   '<a>'+replace(replace(replace(@a,'&','&amp;'),'<','&lt;'),'|','</a><a>')+'</a>';

SELECT  x.n.value('.','VARCHAR(1)') AS  singleValue
FROM    @xml.nodes('/a') AS  x(n)
;

- jumxozizi