我正在使用CUDA纹理以边缘寻址模式（cudaAddressModeBorder）。我正在使用 tex2D<float>() 读取纹理坐标，当纹理坐标超出纹理范围时，tex2D<float>() 返回 0。
我该如何将返回的边缘值从 0 更改为其他内容？我可以手动检查纹理坐标并设置边缘值。我想知道是否有CUDA API可以设置这样的边缘值。
CUDA纹理的不同寻址模式
13
- Ashwin Nanjappa
2
1硬件支持设置颜色，但在CUDA中没有暴露出来。可能是因为经典寻址模式不需要任何额外的参数。NVIDIA已将其注册为请求的功能。作为一种解决方法，也许您可以在纹理周围绘制所需颜色的1像素边框，并使用夹紧寻址模式以及调整的坐标。 - Roger Dahl
@RogerDahl 我猜这只是一个CUDA API问题。因为对于相同的硬件，DirectX可以设置边框颜色。无论如何，在这种特殊情况下，我不能修改纹理，所以对我来说没有解决方案 :-) - Ashwin Nanjappa
2个回答
23
正如sgarizvi所提到的，CUDA仅支持四种不可定制的地址模式，分别是clamp、border、wrap和mirror，这些在CUDA编程指南的3.2.11.1节中有描述。
前两种工作在非归一化和归一化坐标下，而后两种仅工作在归一化坐标下。
为了描述前两者，让我们考虑非归一化坐标情况和简单起见，考虑1D信号。在这种情况下，输入序列为c[k]，其中k=0,...,M-1。
cudaAddressModeClamp
信号c[k]在k=0,...,M-1之外继续，以使得当k < 0时c[k] = c[0]，当k >= M时c[k] = c[M-1]。
cudaAddressModeBorder
信号c[k]在k=0,...,M-1之外继续，以使得当k < 0和k >= M时c[k] = 0。
现在，为了描述最后两种地址模式，我们被迫考虑归一化坐标，以使得1D输入信号采样被假定为c[k / M]，其中k=0,...,M-1。
cudaAddressModeWrap
信号c[k / M]在k=0,...,M-1之外继续，使其周期等于M。换句话说，对于任何（正数、负数或零）整数p，都有c[(k + p * M) / M] = c[k / M]。
cudaAddressModeMirror
信号c[k / M]在k=0,...,M-1之外继续，使其周期等于2 * M - 2。换句话说，对于任何l和k，使得(l + k)mod(2 * M - 2) = 0，都有c[l / M] = c[k / M]。
下面的代码展示了所有四个可用的地址模式。
#include <stdio.h>
texture<float, 1, cudaReadModeElementType> texture_clamp;
texture<float, 1, cudaReadModeElementType> texture_border;
texture<float, 1, cudaReadModeElementType> texture_wrap;
texture<float, 1, cudaReadModeElementType> texture_mirror;
/********************/
/* CUDA ERROR CHECK */
/********************/
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); }
inline void gpuAssert(cudaError_t code, char *file, int line, bool abort=true)
{
if (code != cudaSuccess)
{
fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line);
if (abort) exit(code);
}
}
/******************************/
/* CUDA ADDRESS MODE CLAMPING */
/******************************/
__global__ void Test_texture_clamping(const int M) {
printf("Texture clamping - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_clamp, -(float)threadIdx.x));
printf("Texture clamping - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_clamp, (float)(M + threadIdx.x)));
}
/****************************/
/* CUDA ADDRESS MODE BORDER */
/****************************/
__global__ void Test_texture_border(const int M) {
printf("Texture border - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_border, -(float)threadIdx.x));
printf("Texture border - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_border, (float)(M + threadIdx.x)));
}
/**************************/
/* CUDA ADDRESS MODE WRAP */
/**************************/
__global__ void Test_texture_wrap(const int M) {
printf("Texture wrap - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_wrap, -(float)threadIdx.x/(float)M));
printf("Texture wrap - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_wrap, (float)(M + threadIdx.x)/(float)M));
}
/****************************/
/* CUDA ADDRESS MODE MIRROR */
/****************************/
__global__ void Test_texture_mirror(const int M) {
printf("Texture mirror - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_mirror, -(float)threadIdx.x/(float)M));
printf("Texture mirror - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_mirror, (float)(M + threadIdx.x)/(float)M));
}
/********/
/* MAIN */
/********/
void main(){
const int M = 4;
// --- Host side memory allocation and initialization
float *h_data = (float*)malloc(M * sizeof(float));
for (int i=0; i<M; i++) h_data[i] = (float)i;
// --- Texture clamping
cudaArray* d_data_clamping = NULL; gpuErrchk(cudaMallocArray(&d_data_clamping, &texture_clamp.channelDesc, M, 1));
gpuErrchk(cudaMemcpyToArray(d_data_clamping, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice));
cudaBindTextureToArray(texture_clamp, d_data_clamping);
texture_clamp.normalized = false;
texture_clamp.addressMode[0] = cudaAddressModeClamp;
dim3 dimBlock(2 * M, 1); dim3 dimGrid(1, 1);
Test_texture_clamping<<<dimGrid,dimBlock>>>(M);
printf("\n\n\n");
// --- Texture border
cudaArray* d_data_border = NULL; gpuErrchk(cudaMallocArray(&d_data_border, &texture_border.channelDesc, M, 1));
gpuErrchk(cudaMemcpyToArray(d_data_border, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice));
cudaBindTextureToArray(texture_border, d_data_border);
texture_border.normalized = false;
texture_border.addressMode[0] = cudaAddressModeBorder;
Test_texture_border<<<dimGrid,dimBlock>>>(M);
printf("\n\n\n");
// --- Texture wrap
cudaArray* d_data_wrap = NULL; gpuErrchk(cudaMallocArray(&d_data_wrap, &texture_wrap.channelDesc, M, 1));
gpuErrchk(cudaMemcpyToArray(d_data_wrap, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice));
cudaBindTextureToArray(texture_wrap, d_data_wrap);
texture_wrap.normalized = true;
texture_wrap.addressMode[0] = cudaAddressModeWrap;
Test_texture_wrap<<<dimGrid,dimBlock>>>(M);
printf("\n\n\n");
// --- Texture mirror
cudaArray* d_data_mirror = NULL; gpuErrchk(cudaMallocArray(&d_data_mirror, &texture_mirror.channelDesc, M, 1));
gpuErrchk(cudaMemcpyToArray(d_data_mirror, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice));
cudaBindTextureToArray(texture_mirror, d_data_mirror);
texture_mirror.normalized = true ;
texture_mirror.addressMode[0] = cudaAddressModeMirror;
Test_texture_mirror<<<dimGrid,dimBlock>>>(M);
printf("\n\n\n");
}
这些是输出结果。
index -7 -6 -5 -4 -3 -2 -1 0 1 2 3 4 5 6 7 8 9 10 11
clamp 0 0 0 0 0 0 0 0 1 2 3 3 3 3 3 3 3 3 3
border 0 0 0 0 0 0 0 0 1 2 3 0 0 0 0 0 0 0 0
wrap 1 2 3 0 1 2 3 0 1 2 3 0 1 2 3 0 1 2 3
mirror 1 2 3 3 2 1 0 0 1 2 3 3 2 1 0 0 1 2 3
- Vitality
2
7我希望这是CUDA文档，而不是
cudaTextureDesc::addressMode specifies the addressing mode！感谢Nvidia... - Ander Biguri谢谢，非常有用。 - Michael
4
截至目前（CUDA 5.5），CUDA纹理获取行为不可自定义。只能利用4种自动内置模式中的1种（即边框，夹紧，环绕和镜像）来进行超出范围的纹理获取。
- sgarizvi
网页内容由stack overflow 提供, 点击上面的可以查看英文原文，
原文链接
原文链接