logo标签列表

批量设置命令输出和错误到不同变量

windowsbatch-filecmdwindows-7io-redirection
3
在 Windows 7 的批处理（cmd.exe 命令行）中，我试图将命令的标准输出（stdout）和标准错误（stderr）重定向到不同的变量中（因此第一个变量设置为输出，第二个变量设置为错误（如果有）），而不使用任何临时文件。我已经尝试了很多次，但都没有成功。
那么，有什么可行的方法可以将命令的输出和错误分别设置为不同的变量呢？
3个回答
4

您可以使用两个嵌套的for /F循环，其中内部循环捕获标准输出，外部循环捕获重定向的错误。由于内部循环实例化一个新的cmd进程，因此捕获的文本不能仅分配给一个变量，因为在执行完成后将会丢失。相反，我在每行前都加上了|并将其输出到标准输出。外部循环检测到前导|并相应地分隔行：

@echo off
setlocal EnableExtensions EnableDelayedExpansion
set "STDOUT="
set "STDERR="
(set LF=^
%=empty line=%
)
for /F "delims=" %%E in ('
    2^>^&1 ^(^
        for /F "delims=" %%O in ^('^
            command_line^
        '^) do @^(^
            echo ^^^|%%O^
        ^)^
    ^)
') do (
    set "LINE=%%E"
    if "!LINE:~,1!"=="|" (
        set "STDOUT=!STDOUT!!LINE:~1!!LF!"
    ) else (
        set "STDERR=!STDERR!!LINE!!LF!"
    )
)
echo ** STDOUT **!LF!!STDOUT!
echo ** STDERR **!LF!!STDERR!
endlocal
exit /B

以下是代码的限制：
  • 空行将被忽略；
  • 以分号 ; 开头的行将被忽略；
  • 感叹号 ! 将会丢失，因为启用了延迟环境变量扩展；
  • 以管道符号 | 开头的行可能会被错误地分配；
  • 数据的总大小不能超过8190字节；

所有这些限制都适用于标准输出和标准错误。

编辑：

以下是改进后的代码。已解决有关空行和以分号 ; 开头的行的问题，其他限制仍然存在：

@echo off
setlocal EnableExtensions EnableDelayedExpansion
set "STDOUT="
set "STDERR="
(set LF=^
%=empty line=%
)
for /F "delims=" %%E in ('
    2^>^&1 ^(^
        for /F "delims=" %%O in ^('^
            command_line ^^^^^^^| findstr /N /R "^"^
        '^) do @^(^
            echo ^^^^^^^|%%O^
        ^)^
    ^) ^| findstr /N /R "^"
') do (
    set "LINE=%%E"
    set "LINE=!LINE:*:=!"
    if "!LINE:~,1!"=="|" (
        set "STDOUT=!STDOUT!!LINE:*:=!!LF!"
    ) else (
        set "STDERR=!STDERR!!LINE!!LF!"
    )
)
echo ** STDOUT **!LF!!STDOUT!
echo ** STDERR **!LF!!STDERR!
endlocal
exit /B
findstr命令用于在每一行前加上行号和:，以便for /F不会出现空行；当然，这个前缀后来会被删除。这种改变也隐含地解决了;的问题。
由于将管道嵌套到findstr中，因此需要多次转义来隐藏|字符，只要它的管道函数实际上是必需的。
2
这根本行不通。除了你的每个IN()行必须在结尾使用换行符“^”之外，基本思路是错误的。每个IN()命令都会在一个新的cmd.exe进程中执行。你在进程中定义的任何变量都将在进程终止时消失。因此，你的父脚本无法看到STDOUT变量-它将无法存活。 - dbenham
1
+1 哦，非常聪明！你可以使用“数组”支持每行近8190个字节。使用我的答案中的FINDSTR来避免; EOL问题，并获取数组索引以解决空行问题。您可以通过在stdout和stderr前缀中使用唯一的标志字符来处理任何前导字符。我会使用+表示stdout，-表示stderr。您可以通过仔细切换延迟扩展来保留!。然而，尽管您的解决方案非常有创意，但我认为临时文件解决方案更快，而且实现起来简单得多。 - dbenham
1
此外，您不需要转义 '、( 或 @。 - dbenham
2
非常好。请查看我的编辑答案的结尾，以获取保留!的方法。它很丑陋，但它能用。 - dbenham
2
尤里卡——除了大小限制外，一切都被消除了。请再次查看我的更新答案。 - dbenham
显示剩余4条评论
3
首先，批处理没有像Unix shell脚本那样捕获多行输出的简单方法。您可以使用FOR /F逐行构建多行值，但总长度限制为<8191个字节，并且语法很笨拙。或者，您可以使用FOR /F捕获多行，并模拟变量的数组。
关于您的问题，没有一种方法可以独立地捕获stdout和stderr而不使用至少一个临时文件。编辑: 错误，aschipfl 找到了一种方法。然而，临时文件更快，也更简单。 这是一个简单的演示，使用文件来捕获stderr。我假设您想要捕获最多一行的stdout和/或stderr。
for /f "delims=" %%A in ('yourCommand 2^>err.log`) do set "out=%%A"
<err.log set /p "err="
del err.log

这是一个更复杂的示例，捕获了stdout和stderr的一系列行。在这里，我假设输出的每一行都不以:开头。FINDSTR将每一行前缀加上行号和:，FOR /F解析出行号作为“数组”索引，并解析出:后面的值。
@echo off
setlocal disableDelayedExpansion
set /a out.cnt=err.cnt=0
for /f "delims=: tokens=1*" %%A in ('yourCommand 2^>err.log ^| findstr /n "^"') do (
  set "out.%%A=%%B"
  set "out.cnt=%%A"
)
for /f "delims=: tokens=1*" %%A in ('findstr /n "^" err.log') do (
  set "err.%%A=%%B"
  set "err.cnt=%%A"
)

:: Display the results
setlocal enableDelayedExpansion
echo ** STDOUT **
for /l %%N in (1 1 %out.cnt%) do echo(!out.%%N!
echo ** STDERR **
for /l %%N in (1 1 %err.cnt%) do echo(!err.%%N!


第二次编辑

如果你想正确处理以:开头的输出，需要额外的代码。

@echo off
setlocal disableDelayedExpansion
set /a out.cnt=err.cnt=0
for /f "delims=" %%A in ('yourCommand 2^>err.log ^| findstr /n "^"') do for /f "delims=:" %%N in ("%%A") do (
  set "ln=%%A"
  setlocal enableDelayedExpansion
  for /f "delims=" %%B in (^""!ln:*:=!"^") do (
    endlocal
    set "out.%%N=%%~B"
    set "out.cnt=%%N"
  )
)
for /f "delims=" %%A in ('findstr /n "^" err.log') do for /f "delims=:" %%N in ("%%A") do (
  set "ln=%%A"
  setlocal enableDelayedExpansion
  for /f "delims=" %%B in (^""!ln:*:=!"^") do (
    endlocal
    set "err.%%N=%%~B"
    set "err.cnt=%%N"
  )
)

:: Display the results
setlocal enableDelayedExpansion
echo ** STDOUT **
for /l %%N in (1 1 %out.cnt%) do echo(!out.%%N!
echo ** STDERR **
for /l %%N in (1 1 %err.cnt%) do echo(!err.%%N!

下面是我改进了aschipfl的第二个代码，避免使用临时文件，以便保留!字符。 代码变得越来越丑陋;-)

@echo off
setlocal disableDelayedExpansion
set "STDOUT="
SET "STDERR="
for /f "delims=" %%E in (
   '2^>^&1 (for /f "delims=" %%O in ('^
      yourCommand^
   ^^^^^^^| findstr /n /r "^"'^) do @(echo ^^^^^^^|%%O^)^) ^| findstr /n /r "^"'
) do (
   set "ln=%%E"
   setlocal enableDelayedExpansion
   set "ln=x!ln:*:=!"
   set "ln=!ln:\=\s!"
   if "!ln:~0,2!"=="x|" (
      set "ln=!ln:~0,-1!"
      for /f "delims=" %%A in (^""!STDOUT!"^") do for /f "delims=" %%B in (^""!ln:*:=!"^") do (
        endlocal
        set "STDOUT=%%~A%%~B\n"
      )
   ) else (
      for /f "delims=" %%A in (^""!STDERR!"^") do for /f "delims=" %%B in (^""!ln:~1!"^") do (
        endlocal
        set "STDERR=%%~A%%~B\n"
      )
   )
)
setlocal enableDelayedExpansion
for %%L in (^"^
%= empty line =%
^") do (
  if defined STDOUT (
    set "STDOUT=!STDOUT:\n=%%~L!"
    set "STDOUT=!STDOUT:\s=\!"
    set "STDOUT=!STDOUT:~0,-1!"
  )
  if defined stderr (
    set "STDERR=!STDERR:\n=%%~L!"
    set "STDERR=!STDERR:\s=\!"
    set "STDERR=!STDERR:~0,-1!"
  )
)

echo ** STDOUT **
echo(!STDOUT!
echo ** STDERR **
echo(!STDERR!
exit /b

如果结果存储在数组中而不是一对字符串中，这会变得更加简单。
@echo off
setlocal disableDelayedExpansion
set /a out.cnt=err.cnt=1
for /f "delims=" %%E in (
   '2^>^&1 (for /f "delims=" %%O in ('^
      yourCommand^
   ^^^^^^^| findstr /n /r "^"'^) do @(echo ^^^^^^^|%%O^)^) ^| findstr /n /r "^"'
) do (
   set "ln=%%E"
   setlocal enableDelayedExpansion
   set "ln=x!ln:*:=!"
   if "!ln:~0,2!"=="x|" (
      set "ln=!ln:~0,-1!"
      for %%N in (!out.cnt!) do for /f "delims=" %%A in (^""!ln:*:=!"^") do (
        endlocal
        set "out.%%N=%%~A"
        set /a out.cnt+=1
      )
   ) else (
      for %%N in (!err.cnt!) do for /f "delims=" %%A in (^""!ln:~1!"^") do (
        endlocal
        set "err.%%N=%%~A"
        set /a err.cnt+=1
      )
   )
)
set /a out.cnt-=1, err.cnt-=1
setlocal enableDelayedExpansion

echo ** STDOUT **
for /l %%N in (1 1 %out.cnt%) do echo(!out.%%N!
echo ** STDERR **
for /l %%N in (1 1 %err.cnt%) do echo(!err.%%N!
exit /b

我知道很多人试图避免使用临时文件，但在这种情况下，我认为这是适得其反的。测试表明，当输出非常大时，使用临时文件比使用 FOR /F 循环处理命令结果要快得多。而且临时文件解决方案要简单得多。所以我一定会使用临时文件解决方案。
但是找到一个非临时文件解决方案是一个有趣的挑战。向 aschipfl 致敬，他解决了复杂的转义序列。

第三（最终？）次编辑

最后，这里有一个解决方案，除了每个捕获的输出行必须小于约8180个字节以外，其他所有限制都被消除了。

我本可以将整个代码放在一个大循环中，但是那样转义序列会非常麻烦。将代码分成较小的子例程时，计算转义序列要简单得多。

我在底部的:test例程中为一堆ECHO命令捕获了stdout和stderr。

::
:: Script to demonstrate how to run one or more commands
:: and capture stdout in one array and stderr in another array,
:: without using a temporary file.
::
:: The command(s) to run should be placed in the :test routine at the bottom.
::

@echo off
setlocal disableDelayedExpansion
if "%~1" equ ":out" goto :out
if "%~1" equ ":err" goto :err
if "%~1" equ ":test" goto :test

set /a out.cnt=err.cnt=0

:: Runs :err, which runs :out, which runs :test
:: stdout is captured in out array, and stderr in err array.
for /f "delims=. tokens=1*" %%A in ('^""%~f0" :err^"') do (
  for /f "delims=:" %%N in ("%%B") do (
    set "ln=%%B"
    setlocal enableDelayedExpansion
    for /f "delims=" %%L in (^""!ln:*:=!"^") do (
      endlocal
      set "%%A.%%N=%%~L"
      set "%%A.cnt=%%N"
    )
  )
)

:: Show results
setlocal enableDelayedExpansion
echo ** STDOUT **
for /l %%N in (1 1 %out.cnt%) do echo(!out.%%N!
echo(
echo ** STDERR **
for /l %%N in (1 1 %err.cnt%) do echo(!err.%%N!
exit /b


:err  :: 1) Run the :out code, which swaps stdout with stderr
      :: 2) Prefix stream 1 (stderr) output with err.###:  where ### = line number
      :: 3) Rredirect stream 2 (stdout) to combine with stream 1 (stderr)
2>&1 (for /f "delims=" %%A in ('^""%~f0" :out^|findstr /n "^"^"') do echo err.%%A)
exit /b


:out  :: 1) Run the :test code.
      :: 2) Prefix stream 1 (stdout) output with out.###:  where ### = line number
      :: 3) Swap stream 1 (stdout) with stream 2 (stderr)
3>&2 2>&1 1>&3 (for /f "delims=" %%A in ('^""%~f0" :test^|findstr /n "^"^"') do echo out.%%A)
exit /b


:test :: Place the command(s) to run in this routine
    echo STDOUT line 1 with empty line following
    echo(
>&2 echo STDERR line 1 with empty line following
>&2 echo(
    echo STDOUT line 3 with poison characters "(<^&|!%%>)" (^<^^^&^|!%%^>)
>&2 echo STDERR line 3 with poison characters "(<^&|!%%>)" (^<^^^&^|!%%^>)
    echo err.4:STDOUT line 4 spoofed as stderr - No problem!
>&2 echo out.4:STDERR line 4 spoofed as stdout - No problem!
    echo :STDOUT line 5 leading colon preserved
>&2 echo :STDERR line 5 leading colon preserved
    echo ;STDOUT line 6 default EOL of ; not a problem
>&2 echo ;STDERR line 6 default EOL of ; not a problem
exit /b

-- 输出 --

** STDOUT **
STDOUT line 1 with empty line following

STDOUT line 3 with poison characters "(<^&|!%>)" (<^&|!%>)
err.4:STDOUT line 4 spoofed as stderr - No problem!
:STDOUT line 5 leading colon preserved
;STDOUT line 6 default EOL of ; not a problem

** STDERR **
STDERR line 1 with empty line following

STDERR line 3 with poison characters "(<^&|!%>)" (<^&|!%>)
out.4:STDERR line 4 spoofed as stdout - No problem!
:STDERR line 5 leading colon preserved
;STDERR line 6 default EOL of ; not a problem

我仍然更喜欢临时文件的解决方案 ;-)

1
只要发送到标准输出的行不以冒号分隔的行号本身开头，此解决方案即可正常工作。
@echo off
setlocal EnableDelayedExpansion

set /A out=0, err=1
for /F "tokens=1* delims=:" %%a in ('(theCommand 1^>^&2 2^>^&3 ^| findstr /N "^"^) 2^>^&1') do (
   if "%%a" equ "!err!" (
      set "stderr[!err!]=%%b"
      set /A err+=1
   ) else (
      set /A out+=1
      if "%%b" equ "" (
         set "stdout[!out!]=%%a"
      ) else (
         set "stdout[!out!]=%%a:%%b"
      )
   )
)
set /A err-=1

echo Lines sent to Stdout:
for /L %%i in (1,1,%out%) do echo !stdout[%%i]!
echo/
echo Lines sent to Stderr:
for /L %%i in (1,1,%err%) do echo !stderr[%%i]!

例如，如果theCommand是这个.bat文件：

For example, if theCommand is this .bat file:

@echo off
echo Line one to stdout
echo Line one to stderr >&2
echo Line two to stderr >&2
echo Line two to stdout

"...然后这是输出："
Lines sent to Stdout:
Line one to stdout
Line two to stdout

Lines sent to Stderr:
Line one to stderr
Line two to stderr
1
这是如何工作的？findstr是否处理流3中的数据？如果是，那么这是findstr的另一个“隐藏功能”吗？ - aschipfl
2
@aschipfl - 不，FINDSTR只处理流1。1>&2 2>&3（或2>&3, 1>&2）有效地交换了标准输出和标准错误输出，但前提是流3之前未被定义。如果流3可能已经存在，则必须使用3>&1 1>&2 2>&3（或3>&2 2>&1 1>&3）。有关更多信息，请参见https://dev59.com/x2ct5IYBdhLWcg3wL6qi#12274145。 - dbenham
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接