Power BI/DAX: 根据添加的列值对SUMMARIZE或GROUPBY进行筛选

Question

由于数据的机密性，我将尝试使用一些随机示例来描述我的困境。

假设我在Power BI中有一个包含发票数据的事实表。我需要计算在过去12个月或者更准确地说，在所选日期之前的12个月内，销售额超过50,000欧元的不同产品ID的数量。同时，我还需要能够将结果缩小到所选的国家、产品组和产品类别。

我开始设置DATESBETWEEN的日期范围，如下所示：

productsCount = 
VAR lastDay = IF(MAX('Calendar table'[Date]) > NOW(); NOW(); MAX('Calendar table'[Date]))
VAR firstDay = EDATE(lastDay; -12)
RETURN

但后来我迷失了：

CALCULATE(
    COUNTROWS('Sales');
    SUMMARIZE(
        'Sales';
        'Sales'[ProductID];
        "prodSales"; SUM('Sales'[EUR])
    );
    DATESBETWEEN('Sales'[Date]; firstDay; lastDay);
    ALLEXCEPT(
        'Sales';
        'Sales'[Product group];
        'Sales'[Product category];
        'Sales'[Country]
    );
    [prodSales] > 50000
)

事情是这样的，我需要能够按销售总额过滤汇总数据，然后再计算行数。

- Uzzy

Answer 1

我还没有测试过，但我认为像这样过滤摘要后的内容可能会起作用：

productsCount =
VAR lastDay =
    IF (
        MAX ( 'Calendar table'[Date] ) > NOW ();
        NOW ();
        MAX ( 'Calendar table'[Date] )
    )
VAR firstDay = EDATE ( lastDay; -12 )
RETURN
    COUNTROWS (
        FILTER (
            CALCULATETABLE (
                SUMMARIZE ( 'Sales';
                   'Sales'[ProductID];
                   "prodSales"; SUM ( 'Sales'[EUR] )
                );
                DATESBETWEEN ( 'Sales'[Date]; firstDay; lastDay );
                ALLEXCEPT (
                    'Sales';
                    'Sales'[Product group];
                    'Sales'[Product category];
                    'Sales'[Country]
                )
            );
            [prodSales] > 50000
        )
    )

- Alexis Olson

---

我只需要在ALLEXCEPT中添加几个过滤器（因为报告页面上有其他视觉效果和交叉过滤功能），然后它就可以正常工作了。谢谢 :) - Uzzy

Answer 2

总之，我们可以在汇总表后进行筛选。

我的输入表格是：

我正在编写查询

App Downlaod Count = 

FILTER(
    SUMMARIZE(events_intraday,
    events_intraday[event_name],
    events_intraday[event_date],
    events_intraday[platform],
    events_intraday[stream_id],
    "Count",CALCULATE(
        COUNT(events_intraday[event_name]),
            FILTER(events_intraday,
                    (events_intraday[platform] = "ANDROID" || 
                    events_intraday[platform] = "IOS")
                )
            )
        ),
        events_intraday[event_name] = "first_open" && 
        (events_intraday[stream_id] = "1415470954" || 
        events_intraday[stream_id] = "1420775080")
    )

输出结果为

- KARTHIKEYAN.A

Answer 3

你可以在Power Query Editor中创建一个总结表，然后在DAX中创建一个度量来过滤结果超过50k的部分。

- user11738502

---

我不知道如何准备这样的表格以便能够做我需要做的事情。 - Uzzy