理解F#尾递归

Question

最近，我正在学习F#。 我尝试用不同的方法解决问题。 就像这样：

(*

[0;1;2;3;4;5;6;7;8] -> [(0,1,2);(3,4,5);(6,7,8)]

*)

//head-recursive
let rec toTriplet_v1 list=
    match list with
    | a::b::c::t -> (a,b,c)::(toTriplet_v1 t) 
    | _ -> []

//tail-recursive
let toTriplet_v2 list=
    let rec loop lst acc=
        match lst with
        | a::b::c::t -> loop t ((a,b,c)::acc)
        | _ -> acc
    loop list []

//tail-recursive(???)
let toTriplet_v3 list=
    let rec loop lst accfun=
        match lst with
        | a::b::c::t -> loop t (fun ls -> accfun ((a,b,c)::ls))
        | _ -> accfun []
    loop list (fun x -> x)

let funs = [toTriplet_v1; toTriplet_v2; toTriplet_v3];
funs |> List.map (fun x -> x [0..8]) |> List.iteri (fun i x -> printfn "V%d : %A" (i+1) x)

我认为V2和V3的结果应该是相同的。 但是，我得到了以下结果：

V1 : [(0, 1, 2); (3, 4, 5); (6, 7, 8)]
V2 : [(6, 7, 8); (3, 4, 5); (0, 1, 2)]
V3 : [(0, 1, 2); (3, 4, 5); (6, 7, 8)]

为什么V2和V3的结果不同？

- kev

Answer 1

V2使用标准的累加变量来完成尾递归：

loop ([0;1;2;3;4;5;6;7;8], []) ->
  loop ([3;4;5;6;7;8], [(0,1,2)]) ->
    loop ([6;7;8], [(3,4,5), (0,1,2)]) ->
      loop ([], [(6,7,8), (3,4,5), (0,1,2)]) ->
        [(6,7,8), (3,4,5), (0,1,2)]

V3使用continuation，或者通俗易懂的说，是一个累积函数：

loop ([0;1;2;3;4;5;6;7;8], x->x) ->
  loop ([3;4;5;6;7;8], x->(0;1;2)::x) ->
    loop ([6;7;8], x->(3;4;5)::x) ->
      loop ([], x->(6,7,8)::x) ->
        [(6,7,8)]  // x->(6,7,8)::x applies to []
    ->
      [(3,4,5);(6,7,8)] // x->(3,4,5)::x applies to [(6,7,8)]
  ->
    [(0,1,2);(3,4,5);(6,7,8)] // x->(0,1,2)::x applies to [(3,4,5);(6,7,8)]

你可以看到累积变量和累积函数之间的区别：

使用累积变量停在最后一次调用，因为累积变量存储了答案。然而，累积函数在最后一次调用后仍然会进行一些回溯工作。需要注意的是，使用累积函数确实是尾递归的，因为递归调用 loop t (fun ls -> accfun ((a,b,c)::ls)) 实际上是该函数的 最后一条语句。

顺便说一下，你提供的代码是展示概念尾递归函数的好例子。理解这些样例代码的一种方法是像我在上面的两个示例中所做的那样，处理小的情况。处理一些小的情况后，你将更深入地理解这个概念。

- Yin Zhu