F#尾递归优化与2个递归调用？

Question

当我编写这个函数时，我知道我不会得到尾部调用优化。我仍然没有想出一个处理这个问题的好方法，希望有人能提供建议。

我有一棵树：

type Heap<'a> =
| E
| T of int * 'a * Heap<'a> * Heap<'a> 

我想要计算其中有多少个节点：

let count h =
    let rec count' h acc =
        match h with 
        | E -> 0 + acc
        | T(_, value, leftChild, rightChild) ->
            let acc = 1 + acc
            (count' leftChild acc) + (count' rightChild acc)

    count' h 0

由于添加了子节点计数，这并不是最优化的。如果树有100万个节点，有什么办法可以使这样的东西工作吗？

谢谢，Derek

---

以下是使用CPS实现计数的代码。但是它仍然会崩溃堆栈。

let count h =
    let rec count' h acc cont =
        match h with
        | E -> cont (1 + acc)
        | T(_,_,left,right) ->
            let f = (fun lc -> count' right lc cont)
            count' left acc f

    count' h 0 (fun (x: int) -> x)

也许我可以想出一种将树划分为足够多的部分的方法，以便我可以在不崩溃堆栈的情况下进行计数？

有人询问生成树的代码。以下是代码：

member this.ParallelHeaps threads =
    let rand = new Random()
    let maxVal = 1000000

    let rec heaper i h =
        if i < 1 then
            h
        else
            let heap = LeftistHeap.insert (rand.Next(100,2 * maxVal)) h
            heaper (i - 1) heap

    let heaps = Array.create threads E
    printfn "Creating heap of %d elements, with %d threads" maxVal threads
    let startTime = DateTime.Now
    seq { for i in 0 .. (threads - 1) ->
          async { Array.set heaps i (heaper (maxVal / threads) E) }}
    |> Async.Parallel
    |> Async.RunSynchronously 
    |> ignore

    printfn "Creating %d sub-heaps took %f milliseconds" threads (DateTime.Now - startTime).TotalMilliseconds
    let startTime = DateTime.Now

    Array.length heaps |> should_ equal threads <| "The size of the heaps array should match the number of threads to process the heaps"

    let rec reMerge i h =
        match i with 
        | -1 -> h
        | _  -> 
            printfn "heap[%d].count = %d" i (LeftistHeap.count heaps.[i])
            LeftistHeap.merge heaps.[i] (reMerge (i-1) h)

    let heap = reMerge (threads-1) E
    printfn "Merging %d heaps took %f milliseconds" threads (DateTime.Now - startTime).TotalMilliseconds
    printfn "heap min: %d" (LeftistHeap.findMin heap)

    LeftistHeap.count heap |> should_ equal maxVal <| "The count of the reMerged heap should equal maxVal"

- Derek Ealy

Answer 1

您可以使用延续传递样式（CPS）来解决该问题。请参阅Matthew Podwysocki的Recursing on Recursion - Continuation Passing。

let tree_size_cont tree = 
  let rec size_acc tree acc cont = 
    match tree with 
    | Leaf _ -> cont (1 + acc) 
    | Node(_, left, right) -> 
         size_acc left acc (fun left_size -> 
         size_acc right left_size cont) 

  size_acc tree 0 (fun x -> x)

请注意，在Debug构建中，尾部调用优化被禁用。如果您不想在Release模式下运行，则可以在Visual Studio项目属性中启用优化。

- Joh

---

延续函数不会增长直到内存最终被耗尽吗？ - Ramon Snir

一般来说，是的，但这被认为是可以接受的。然而，大多数语言（包括我所知道的F#）的堆栈具有静态大小（在加载或编译时设置），因此它会比使用 CPS 更快地创建堆栈溢出，而不是创建内存不足的情况。通常，许多计算问题需要无限制的数据结构来处理任意输入，无论您是通过显式数据结构还是像不断增长的 continuation 这样的“隐式”数据结构来实现都是任意的：数据需要存储在某个地方。 - harms

我之前考虑过尝试这样做，但是因为我认为它仍然会导致堆栈溢出而放弃了。在Joh建议我尝试后，我希望自己错了。但是不，计数函数仍然会导致堆栈溢出。这是我的实现...糟糕，我不能在这里这样做，让我尝试另一个答案。你如何将代码发布到回复中？ - Derek Ealy

` let count h = let rec count' h acc cont = match h with | E -> cont (1 + acc) | T(,,left,right) -> let f = (fun lc -> count' right lc cont) count' left acc f count' h 0 (fun (x: int) -> x)` - Derek Ealy

有人指出，如果代码是在调试模式下构建的，尾调用优化将被禁用。一旦我重新构建为发布模式，我就能够计算具有100万个节点的树了，太棒了！感谢@kvb指出这一点。 - Derek Ealy

很酷 :) ... 知道“调试模式下禁用尾调用”的重要点非常好，因为尾调用对于我们的“递归”神经元非常重要。 - Ankur

Answer 2

CPS是一个很好的通用解决方案，但你也可以考虑显式使用堆栈，因为它会更快，并且可以说更简单：

let count heap =
  let stack = System.Collections.Generic.Stack[heap]
  let mutable n = 0
  while stack.Count > 0 do
    match stack.Pop() with
    | E -> ()
    | T(_, _, heap1, heap2) ->
        n <- n + 1
        stack.Push heap1
        stack.Push heap2
  n

- J D

---

Stack[heap] 是什么意思？ - Joh

从给定序列构造一个Stack集合，这个序列包含单个元素（值为“heap”的列表）。 - J D