尝试使用kotlin.plugin.serialization时，Buid.gradle出现错误

Question

我正在尝试跟随Android Dev Codelabs的基础教程。

我按照教程完全操作，但是在尝试同步build.gradle时出现了以下错误：

Cause: org.jetbrains.kotlin.gradle.plugin.KotlinGradleSubplugin: org.jetbrains.kotlinx.serialization.gradle.SerializationGradleSubplugin not a subtype

我的 build.gradle 文件如下：

plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'

    //User plugins
    id "org.jetbrains.kotlin.plugin.serialization" version "1.7.21"
}

android {
    namespace 'com.example.testeworkmanager'
    compileSdk 32

    defaultConfig {
        applicationId "com.example.testeworkmanager"
        minSdk 26
        targetSdk 32
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        vectorDrawables {
            useSupportLibrary true
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }
    buildFeatures {
        compose true
    }
    composeOptions {
        kotlinCompilerExtensionVersion '1.1.1'
    }
    packagingOptions {
        resources {
            excludes += '/META-INF/{AL2.0,LGPL2.1}'
        }
    }
}

dependencies {
    implementation 'androidx.core:core-ktx:1.7.0'
    implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.3.1'
    implementation 'androidx.activity:activity-compose:1.3.1'
    implementation "androidx.compose.ui:ui:$compose_ui_version"
    implementation "androidx.compose.ui:ui-tooling-preview:$compose_ui_version"
    implementation 'androidx.compose.material:material:1.1.1'
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'
    androidTestImplementation "androidx.compose.ui:ui-test-junit4:$compose_ui_version"
    debugImplementation "androidx.compose.ui:ui-tooling:$compose_ui_version"
    debugImplementation "androidx.compose.ui:ui-test-manifest:$compose_ui_version"

    //User dependencies

    implementation 'androidx.work:work-runtime-ktx:2.7.1'
    implementation 'com.squareup.retrofit2:retrofit:2.9.0'
    implementation "com.jakewharton.retrofit:retrofit2-kotlinx-serialization-converter:0.8.0"
    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json:1.4.0"
}

我尝试了一个小时的谷歌搜索和理解，但无法弄清楚我做错了什么。我该怎么办？

- Anderson Linhares

---

可能是重复问题，与 https://dev59.com/rHcPtIcB2Jgan1znKnFt 相同。也许你的构建中有另一个版本的 Kotlin 插件（应该对齐）。 - Joffrey

你是对的。实际上我之前已经读过那篇文章，但是我没找到"kotlin("kjvm") version 1.6.10"在哪里。现在我知道它在项目的build.gradle文件中了。我在那里更新了它，现在一切都正常了。谢谢！ - Anderson Linhares

Answer 1

正如@Joffrey所指出的那样，我项目的build.gradle中有一行代码为'org.jetbrains.kotlin.android' version '1.6.10' apply false。将其更改为1.7.10后，所有问题都已解决。

- Anderson Linhares

Answer 2

请确保在项目 build.gradle 文件中，两个版本号都是相同的，例如此处的 1.6.10：

plugins {
    id 'org.jetbrains.kotlin.android' version '1.6.10' apply false
    id 'org.jetbrains.kotlin.plugin.serialization' version '1.6.10' apply false
}

然后在模块 build.gradle文件中：

plugins {
    id 'org.jetbrains.kotlin.plugin.serialization'
}

- Johan Ordenes Galleguillos