SQL Server分割和表插入

Question

我希望能够使用SQL Server 2005来完成以下操作：

1. 创建一个存储过程，它接受一个以逗号“,”分隔的varchar()参数。 2. 分离/拆分varchar()参数，并将这些值插入到一个临时表中。

需要实现以下功能：

INSERT INTO #temp_table SPLIT('john,peter,sally',',');

SELECT * FROM #temp_table;

是否有一个函数或存储过程可以执行拆分操作？

如果有，它是如何工作的？

谢谢

- Koekiebox

---

可能是SQL中字符串拆分的重复问题。 - Jacob

Answer 1

SQL Server本身没有字符串分割函数，但是你可以创建一个类似这个的函数来进行字符串分割。

CREATE FUNCTION dbo.Split(@String varchar(8000), @Delimiter char(1))       
returns @temptable TABLE (items varchar(8000))       
as       
begin       
    declare @idx int       
    declare @slice varchar(8000)       

    select @idx = 1       
        if len(@String)<1 or @String is null  return       

    while @idx!= 0       
    begin       
        set @idx = charindex(@Delimiter,@String)       
        if @idx!=0       
            set @slice = left(@String,@idx - 1)       
        else       
            set @slice = @String       

        if(len(@slice)>0)  
            insert into @temptable(Items) values(@slice)       

        set @String = right(@String,len(@String) - @idx)       
        if len(@String) = 0 break       
    end   
return       
end

- Clayton