为什么在Grails控制器中通过params从视图中提取日期很困难？
我不想像这样手动提取日期：
instance.dateX = parseDate(params["dateX_value"])//parseDate is from my helper class
我只想使用 instance.properties = params。
模型中的类型是 java.util.Date，在参数中包含所有信息：[dateX_month: 'value', dateX_day: 'value', ...]
我在网上搜索了一下，但没有找到相关信息。我希望 Grails 1.3.0 能够帮助，但仍然是同样的问题。
我不能也不愿意相信需要手动提取日期！
Config.groovy中的一个设置定义了绑定参数到Date时应用程序范围内使用的日期格式
grails.databinding.dateFormats = [
'MMddyyyy', 'yyyy-MM-dd HH:mm:ss.S', "yyyy-MM-dd'T'hh:mm:ss'Z'"
]
grails.databinding.dateFormats 中指定的格式将按照列表中包含它们的顺序进行尝试。
您可以使用 @BindingFormat 覆盖这些应用程序范围内的格式，以适用于单个命令对象。
import org.grails.databinding.BindingFormat
class Person {
@BindingFormat('MMddyyyy')
Date birthDate
}
我不相信需要手动提取日期！
你的固执得到了回报，早在Grails 1.3之前就可以直接绑定日期了。步骤如下：
(1)创建一个类为您的日期格式注册编辑器
import org.springframework.beans.PropertyEditorRegistrar
import org.springframework.beans.PropertyEditorRegistry
import org.springframework.beans.propertyeditors.CustomDateEditor
import java.text.SimpleDateFormat
public class CustomDateEditorRegistrar implements PropertyEditorRegistrar {
public void registerCustomEditors(PropertyEditorRegistry registry) {
String dateFormat = 'yyyy/MM/dd'
registry.registerCustomEditor(Date, new CustomDateEditor(new SimpleDateFormat(dateFormat), true))
}
}
(2) 在grails-app/conf/spring/resources.groovy中注册以下bean，使Grails能够识别该日期编辑器：
beans = {
customPropertyEditorRegistrar(CustomDateEditorRegistrar)
}
(3) 现在，当你以 yyyy/MM/dd 格式在一个名为 foo 的参数中发送日期时，它将自动绑定到一个名为 foo 的属性，使用以下任一方法:
myDomainObject.properties = params
new MyDomainClass(params)
project/src/java/CustomEditorRegistrar.java使用或覆盖了已弃用的API。有没有一种“新”的方法来做这件事？ - zoran119Grails 2.1.1中的params有了新方法，可轻松进行空值安全解析。
def val = params.date('myDate', 'dd-MM-yyyy')
// or a list for formats
def val = params.date('myDate', ['yyyy-MM-dd', 'yyyyMMdd', 'yyMMdd'])
// or the format read from messages.properties via the key 'date.myDate.format'
def val = params.date('myDate')
在文档这里找到它。
您可以在application.yml中设置日期格式，遵循以下语法：
grails:
databinding:
dateFormats:
- 'dd/MM/yyyy'
- 'dd/MM/yyyy HH:mm:ss'
- 'yyyy-MM-dd HH:mm:ss.S'
- "yyyy-MM-dd'T'hh:mm:ss'Z'"
- "yyyy-MM-dd HH:mm:ss.S z"
- "yyyy-MM-dd'T'HH:mm:ssX"
@Don 感谢您上面的回答。
这里有一个替代自定义编辑器的方法，它首先检查日期时间，然后检查日期格式。
Groovy很好用，只需要为Java添加分号即可。
import java.text.DateFormat
import java.text.ParseException
import org.springframework.util.StringUtils
import java.beans.PropertyEditorSupport
class CustomDateTimeEditor extends PropertyEditorSupport {
private final java.text.DateFormat dateTimeFormat
private final java.text.DateFormat dateFormat
private final boolean allowEmpty
public CustomDateTimeEditor(DateFormat dateTimeFormat, DateFormat dateFormat, boolean allowEmpty) {
this.dateTimeFormat = dateTimeFormat
this.dateFormat = dateFormat
this.allowEmpty = allowEmpty
}
/**
* Parse the Date from the given text, using the specified DateFormat.
*/
public void setAsText(String text) throws IllegalArgumentException {
if (this.allowEmpty && !StringUtils.hasText(text)) {
// Treat empty String as null value.
setValue(null)
}
else {
try {
setValue(this.dateTimeFormat.parse(text))
}
catch (ParseException dtex) {
try {
setValue(this.dateFormat.parse(text))
}
catch ( ParseException dex ) {
throw new IllegalArgumentException ("Could not parse date: " + dex.getMessage() + " " + dtex.getMessage() )
}
}
}
}
/**
* Format the Date as String, using the specified DateFormat.
*/
public String getAsText() {
Date value = (Date) getValue()
return (value != null ? this.dateFormat.format(value) : "")
}
}
您是否尝试使用过任何Grails日期选择器插件？
我使用过日历插件，并且有良好的使用体验。
（当使用日历插件时）当您提交日期选择请求时，可以自动将查询参数绑定到要用请求填充的领域对象。
例如：
new DomainObject(params)
new Date().parse("yyyy/MM/dd", "2010/03/18")
new Date.parse() 正是他想避免的。据我所知，如果您直接绑定参数，仍然需要注册自定义日期编辑器（如我的回复中所述）。否则，数据绑定器怎么可能知道哪个字段是月份，哪个是年份（例如）？我同意日历插件是可用的日期选择器插件中最好的。 - DónalGrails版本 >= 2.3
一种支持本地化的版本，用于将字符串转换为日期
在src/groovy中：
package test
import org.codehaus.groovy.grails.web.servlet.mvc.GrailsWebRequest
import org.grails.databinding.converters.ValueConverter
import org.springframework.context.MessageSource
import org.springframework.web.servlet.LocaleResolver
import javax.servlet.http.HttpServletRequest
import java.text.SimpleDateFormat
class StringToDateConverter implements ValueConverter {
MessageSource messageSource
LocaleResolver localeResolver
@Override
boolean canConvert(Object value) {
return value instanceof String
}
@Override
Object convert(Object value) {
String format = messageSource.getMessage('default.date.format', null, "dd/MM/yyyy", getLocale())
SimpleDateFormat simpleDateFormat = new SimpleDateFormat(format)
return simpleDateFormat.parse(value)
}
@Override
Class<?> getTargetType() {
return Date.class
}
protected Locale getLocale() {
def locale
def request = GrailsWebRequest.lookup()?.currentRequest
if(request instanceof HttpServletRequest) {
locale = localeResolver?.resolveLocale(request)
}
if(locale == null) {
locale = Locale.default
}
return locale
}
}
beans = {
defaultDateConverter(StringToDateConverter){
messageSource = ref('messageSource')
localeResolver = ref('localeResolver')
}
}