Delphi中将数据包添加到TBytes，进行验证和读取

Question

我有一张PCB印刷电路板，其中有一个ATMEL微控制器通过Lantronix Xport进行TCP通信。它以ASCII字符串格式发送一些继电器和传感器的状态报告，长度为30个字节，格式如下：

400000000000000000414243303031303030303030303030303030303339
|                 | | |
| byte[0] = $40   | | |
                  | | |- byte[11] = $43 // 'C' Always 
                  | |--- byte[10] = $42 // 'B' Always
                  |----- byte[9]  = $41 // 'A' Always

byte[1..8] = boolean values := Bool(byte[x]);
byte[12..29] = 6 different numbers as string, 3 chars long each, range 0..999

我已经对数据包的加载状态进行了简单的验证：

procedure Load(iData: TBytes);
const vsp = 9;  //Validation String Postition
   buflen = 30;
begin
  If (Length(iData) = buflen) And (iData[0] = $40) And (iData[vsp] = $41) And (iData[vsp + 1] = $42) And (iData[vsp + 2] = $43) Then
    SetStatus(iData)  //Function for loading validated packet
  Else Begin
    DoError(1, 'Invalid packet. Length = ' + IntToStr(Length(iData)) + #13#10 +
               'iData[0]       = ' + String(ByteToHex(iData[0])) + #13#10 +
               'iData[vsp]     = ' + String(ByteToHex(iData[vsp])) + #13#10 +
               'iData[vsp + 1] = ' + String(ByteToHex(iData[vsp + 1])) + #13#10 +
               'iData[vsp + 2] = ' + String(ByteToHex(iData[vsp + 2]))
               );
  End;
End;

问题在于有时候 ASCII 字符串会被分成多个数据包或者拼接成一个数据包（第一个数字是时间戳）：

4239483 4000  // Could be missing in case of disconnect-reconnect.
4239514 00000000000000414243303030303030303030303030303030303338400000000000000000414243
4239545 303031303030303030303030303030303339
4239576 400000000000000000414243303031303030303030303030303030303339400000000000000000414243303031303030303030303030303030303338
4239670 40000000000000000041424330303130
4239701 3030303030303030303030303339

在断开重新连接的情况下，状态信息的部分内容将丢失。

我该如何利用TMemoryStream或Move来读取每个接收到的数据包而不丢失任何信息？

编辑： SetStatus看起来像这样，所以我想避免将状态报告移植到字符串中：

Procedure TTractor.SetStatus(AData: TBytes);
begin
  StatusStream := AData;
  pStatus.HighSpeed             := Bool(AData[1]);
  pStatus.RevDir                := Bool(AData[2]);
  pStatus.FwdDir                := Bool(AData[3]);
  pStatus.FrontExpanded         := Bool(AData[4]);
  pStatus.RearExpanded          := Bool(AData[5]);
  pStatus.AntiSpin              := Bool(AData[6]);
  pStatus.Unknown1              := DecodePCBNumber(AData[12], AData[13], AData[14]);
  pStatus.PumpPressureVoltage   := DecodePCBNumber(AData[15], AData[16], AData[17]);
  pStatus.Unknown2              := DecodePCBNumber(AData[18], AData[19], AData[20]);
  pStatus.WheelPressureVoltage  := DecodePCBNumber(AData[21], AData[22], AData[23]);
  pStatus.OilTemperatureVoltage := DecodePCBNumber(AData[24], AData[25], AData[26]);
  pStatus.PCBTemperatureVoltage := DecodePCBNumber(AData[27], AData[28], AData[29]);
End;

阅读代码：

procedure TForm1.FormCreate(Sender: TObject);
begin
  If Traktor = nil Then Traktor := TTractor.Create(500);
  //...
End;

// TidConnectionIntercept
procedure TForm1.trCItcReceive(ASender: TIdConnectionIntercept; var ABuffer: TArray<System.Byte>);
Var
  tmpList: TList;
  i: Integer;
Begin
  If Traktor <> nil Then Traktor.StatusTBytes := ABuffer;
  AppendConLog(TraktorReceive, False, False, BytesToHexStr(ABuffer) );
End;

procedure TForm1.AppendConLog(LogTyp: TLogType; ShowInConsole, PlainText: Boolean; Text: String);
begin
  If ShowInConsole Or (PlainText And DebugMode) Then Begin
    MemoConsole.Lines.Add(FormatDateTime('[hh:nn:ss] ', Now) + Text);
    Text := String2Hex(AnsiString(Text));
  End;
  LogFile.Add(IntToHex(DateTimeToUNIXTimeFAST(Now()), 8) + ' ' + IntToHex(GetTickCount, 8) + ' ' +
              IntToHex(Word(ShowInConsole), 1) + IntToHex(Word(PlainText), 1) + ' ' +
              IntToHex( Ord(LogTyp), 2) + ' ' + Text);
end;

Type TTractor = class
    constructor Create(LoadInterval: Cardinal; SyncInterval: Cardinal = 25);
    //....
  public
    property StatusTBytes: TBytes read StatusStream write Load;    
  //...
End;    

- wittrup

---

这个问题几乎与http://stackoverflow.com/questions/22436319/comport-readstr相同。 - Sir Rufo

那是个不错的东西。但是除非必要，我想避免将它转换为字符串。 - wittrup

你使用什么来读取TCP数据？例如，如果你使用Indy，你只需在需要时调用ReadBytes（30），并让它处理数据包的拆分/合并。 - Remy Lebeau

你不需要将它转换为字符串，只需从中获取思路，并使用Byte代替Char和TBytes代替string进行操作。 - Sir Rufo

@wittrup：Intercept 的作用是用于处理数据（压缩、加密等），而不是用于检测何时读取数据。相反，应该使用 IOHandler 方法，如 ReadBytes()。TIdIOHandler 有自己的内部缓冲区来处理拆分/合并的数据包。这样，您就可以专注于更高级别的逻辑（读取 30 字节消息），而 Indy 处理低级别的细节（在循环中读取直到有 30 字节可用，缓存未使用的数据以供后续读取等）。如果您展示您当前的读取代码，我可以帮您重写以正确使用 Indy 的 IOHandler。 - Remy Lebeau

Answer 1

一个Intercept.OnReceive事件本身不会触发，它是在另一个读取操作的上下文中触发的。你展示的代码中没有任何读取操作，因此永远不会触发OnReceive事件。 Intercept用于操作数据（压缩、加密等），而不是用于检测何时读取数据。使用IOHandler方法，例如ReadBytes()。 TIdIOHandler具有自己的内部缓冲区，可以为您处理拆分/合并的数据包。这使您可以专注于更高级别的逻辑（读取30字节的消息），而Indy则处理较低级别的细节（循环读取直到有30个可用字节，缓存未使用的数据以进行后续读取等）。

完全摆脱Intercept，然后在需要时调用TIdTCPClient.IOHandler.ReadBytes()，例如：

在定时器中：

procedure TForm1.IdTCPClient1Connected(Sender: TObject);
begin
  ReadTimer.Enabled := True;
end;

procedure TForm1.IdTCPClient1Disconnected(Sender: TObject);
begin
  ReadTimer.Enabled := False;
end;

procedure TForm1.ReadTimerElapsed(ASender: TObject);
var
  Buffer: TIdBytes;
Begin
  try
    if IdTCPClient1.IOHandler.InputBufferIsEmpty then
    begin
      IdTCPClient1.IOHandler.CheckForDataOnSource(10);
      IdTCPClient1.IOHandler.CheckForDisconnect;
      if IdTCPClient1.IOHandler.InputBufferIsEmpty then Exit;
    end;
    IdTCPClient1.IOHandler.ReadBytes(Buffer, 30);
  except
    IdTCPClient1.Disconnect;
    Exit;
  end;
  If Traktor <> nil Then Traktor.StatusTBytes := Buffer;
  AppendConLog(TraktorReceive, False, False, BytesToHexStr(Buffer) );
End;

或者在工作线程中：

type
  TDataEvent = procedure(const Data: TIdBytes) of object;

  TReadingThread = class(TThread)
  private
    FBuffer: TIdBytes;
    FClient: TIdTCPClient;
    FOnData: TDataEvent;
    procedure DoData;
  protected
    procedure Execute; override;
  public
    constructor Create(AClient: TIdTCPClient; AOnData: TDataEvent); reintroduce;
  end;

constructor TReadingThread.Create(AClient: TIdTCPClient; AOnData: TDataEvent);
begin
  inherited Create(False);
  FClient := AClient;
  FOnData := AOnData;
end;

procedure TReadingThread.Execute;
begin
  while not Terminated do
  begin
    FClient.IOHandler.ReadBytes(FBuffer, 30);
    Synchronize(DoData);
  end;
end;

procedure TReadingThread.DoData;
begin
  if Assigned(FOnData) then FOnData(FBuffer);
end;

var
  ReadThread: TReadingThread = nil;

procedure TForm1.IdTCPClient1Connected(Sender: TObject);
begin
  ReadThread := TReadingThread.Create(IdTCPClient1, DataAvailable);
end;

procedure TForm1.IdTCPClient1Disconnected(Sender: TObject);
begin
  if Assigned(ReadThread) then
  begin
    ReadThread.Terminate;
    ReadThread.WaitFor;
    FreeAndNil(ReadThread);
  end;
end;

procedure TForm1.DataAvailable(const Data: TIdBytes);
begin
  If Traktor <> nil Then Traktor.StatusTBytes := Data;
  AppendConLog(TraktorReceive, False, False, BytesToHexStr(Data) );
end;

- Remy Lebeau

Answer 2

将来自端口的每个数据部分添加到全局缓冲区：ansistring 检查缓冲区在位置1是否包含所需的标头（否则删除标头字节之前的所有内容），并检查缓冲区长度是否>= buflen。如果是，则处理数据并从缓冲区中删除。

- MBo

---

在处理数据之前，我会添加一个检查可能的标头以应对断开连接的情况。 - Sertac Akyuz