在VirtualTreeView中编辑根节点单元格文本

Question

我想改变现有虚拟（根）节点的单元格文本。我可以改变数据，但必须刷新整个TreeView，以便再次触发GetText。是否有更简单的方法或可能仅刷新一个根节点而不是整个树的方法？

感谢您的帮助。

- Ben

---

"InvalidateNode"函数总是强制节点重绘，从而触发"OnGetText"事件。你一定做错了什么。如果需要，我可以向您展示证明。 - TLama

Answer 1

在下面的代码中，我尝试模拟您的节点更新事件。这里由按钮单击事件Button1Click表示。如果您单击按钮，则数据记录中的值将增加，并且节点将被强制重新绘制（这将触发OnGetText事件，在该事件中，您将准备好获取该记录中的新增值）。在您的实际代码中，您需要执行以下操作：

• 找到要更新的节点（我找到了TopNode :-)
• 更新该节点的数据记录（在我的情况下，Count值递增）
• 为该节点调用InvalidateNode（这将触发某些事件的虚拟事件链，但其中包括OnGetText）

type
  PTreeData = ^TTreeData;
  TTreeData = record
    Title: string;
    Count: Integer;
  end;

procedure TForm1.FormCreate(Sender: TObject);
var
  TreeData: PTreeData;
  TreeNode: PVirtualNode;
begin
  // this is just for memory leaks report
  ReportMemoryLeaksOnShutdown := True;
  // initialize data size for our data record
  VirtualTree.NodeDataSize := SizeOf(TTreeData);
  // add one node and store it to the TreeNode variable
  TreeNode := VirtualTree.AddChild(nil);
  // get the pointer to just created node data record
  TreeData := VirtualTree.GetNodeData(TreeNode);
  // and assign some values to that data record
  TreeData.Title := 'Count: ';
  TreeData.Count := 0;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  TreeData: PTreeData;
  TreeNode: PVirtualNode;
begin
  // now I take the the top node just as an example
  TreeNode := VirtualTree.TopNode;
  // get the pointer to its data record
  TreeData := VirtualTree.GetNodeData(TreeNode);
  // increase the value in data record for this node
  TreeData.Count := TreeData.Count + 1;
  // and force the node to repaint, what will except
  // other events trigger also the OnGetText one
  VirtualTree.InvalidateNode(TreeNode);
end;

procedure TForm1.VirtualTreeGetText(Sender: TBaseVirtualTree;
  Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
  var CellText: string);
var
  TreeData: PTreeData;
begin
  // here I'll get the pointer to data of the currently refreshed cell's node
  TreeData := VirtualTree.GetNodeData(Node);
  // and return the caption of the cell
  CellText := TreeData.Title + IntToStr(TreeData.Count);
end;

procedure TForm1.VirtualTreeFreeNode(Sender: TBaseVirtualTree;
  Node: PVirtualNode);
var
  TreeData: PTreeData;
begin
  // this is here because of VT memory leaks, so get the pointer to data
  TreeData := Sender.GetNodeData(Node);
  // and finalize them
  Finalize(TreeData^);
end;

- TLama

Answer 2

这段代码可以编辑选定节点的文本，使用编辑框中的文本进行更改。

procedure Form1.btnEditTextClick(Sender: TObject);
var
  Data: PTreeData;
begin
  Data := VST.GetNodeData(VST.FocusedNode);

  Data.Title := Edit2.Text;
  VST.InvalidateNode(VST.FocusedNode);

end;

- Azad