错误：无法解析以下类的超类型。请确保您在类路径中具有所需的依赖项。

Question

我的Android项目（Kotlin）无法编译。

Gradle日志：

以下类的超类型无法解析。请确保在类路径中具有所需的依赖项：class.com.google.firebase.auth.FirebaseAuth，未解决的超类型com.google.android.gms.internal.zzeku。

这是我的应用程序Gradle：

apply plugin: 'com.android.application'

apply plugin: 'kotlin-android'

apply plugin: 'kotlin-android-extensions'

android {
    compileSdkVersion 27
    defaultConfig {
        applicationId "com.example.arturpoplawski.bandmanager"
        minSdkVersion 24
        targetSdkVersion 27
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    //kotlin
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jre7:$kotlin_version"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"

    //android
    implementation 'com.android.support:appcompat-v7:27.1.1'
    implementation 'com.android.support:design:27.1.1'
    implementation 'com.android.support.constraint:constraint-layout:1.1.2'
    implementation 'com.android.support:design:27.1.1'
    implementation 'com.android.support:support-v4:27.1.1'

    //firebase
    implementation 'com.google.firebase:firebase-firestore:11.8.0'
    implementation 'com.google.firebase:firebase-core:16.0.1'
    implementation 'com.firebaseui:firebase-ui-auth:3.1.0'
    implementation 'com.google.firebase:firebase-auth:11.2.2'

    //picasso
    implementation 'com.squareup.picasso:picasso:2.71828'


    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.2'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
}

apply plugin: 'com.google.gms.google-

以下是 Build Gradle 项目：

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext.kotlin_version = '1.2.30'
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.4'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
        classpath 'com.google.gms:google-services:4.0.2'
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

- aru96

Answer 1

为解决此问题，请更改以下代码行：

implementation 'com.google.firebase:firebase-firestore:11.8.0'
implementation 'com.firebaseui:firebase-ui-auth:3.1.0'
implementation 'com.google.firebase:firebase-auth:11.2.2'

为了

implementation 'com.google.firebase:firebase-firestore:17.0.4'
implementation 'com.firebaseui:firebase-ui-auth:4.1.0'
implementation 'com.google.firebase:firebase-auth:16.0.2'

另外，我认为这行代码只是部分的：

apply plugin: 'com.google.gms.google-

整个正确的行应该是：

apply plugin: 'com.google.gms.google-services'

- Alex Mamo

---

谢谢，Firebase依赖项版本的增加解决了问题。 :)关于这个“部分代码” - 我只是在复制我的代码时错过了它。 - aru96

非常感谢。在我的情况下，我只是错过了这一行 implementation 'com.google.firebase:firebase-auth:16.0.2'。 - Igor Konyukhov