运行时错误 '1004': 对象 '_Global' 的方法 'Intersect' 失败。

Question

如果我不在脚本运行的同一页上，就会出现运行时错误1004，我想知道为什么...

以下是代码。

Option Explicit

Sub PO_Tracking()

Dim wsPOD As Worksheet
Dim wsPOT As Worksheet
Dim wsPOA As Worksheet
Dim cel As Range
Dim lastrow As Long, i As Long, Er As Long

Set wsPOD = Sheets("PO Data")
Set wsPOT = Sheets("PO Tracking")
Set wsPOA = Sheets("PO Archive")

With Application
    .ScreenUpdating = False
    .DisplayAlerts = False
    .EnableEvents = False
    .Calculation = xlCalculationManual
End With

With wsPOD
    'first bring columns F:G up to match their line
    For Each cel In Intersect(.UsedRange, .UsedRange.Offset(5), .Columns(6))

        If cel = vbNullString And cel.Offset(, -2) <> vbNullString Then
            .Range(cel.Offset(1), cel.Offset(1, 1)).Copy cel
            cel.Offset(1).EntireRow.Delete
        End If

    Next

    'now fil columns A:D to match PO Date and PO#
    For Each cel In Intersect(.UsedRange, .UsedRange.Offset(5), .Columns(1))

        If cel = vbNullString And cel.Offset(, 5) <> vbNullString Then
            .Range(cel.Offset(-1), cel.Offset(-1, 3)).Copy cel
        End If
    Next

'Blow away rows that are useless
    lastrow = wsPOD.Range("A6").End(xlDown).Row
    wsPOD.Range("M5:P5").Copy wsPOD.Range("M6:P" & lastrow)
    Calculate

    With Intersect(wsPOD.UsedRange, ActiveSheet.Columns("N"))
        .AutoFilter 1, "<>Different"
        .SpecialCells(xlCellTypeVisible).EntireRow.Delete
    End With

    With Intersect(wsPOD.UsedRange, ActiveSheet.Columns("P"))
        .AutoFilter 1, "<>Full"
        .SpecialCells(xlCellTypeVisible).EntireRow.Delete
    End With
    wsPOD.UsedRange.Copy Sheets.Add.Range("A1")


'Final Adjustments before transfering over to new sheet.
    With ActiveSheet
        .AutoFilterMode = False
        Intersect(.UsedRange, .Columns("A")).Cut .Range("Q1")
        Intersect(.UsedRange, .Columns("D")).Cut .Range("R1")
        Intersect(.UsedRange, .Columns("C")).Cut .Range("S1")
        Intersect(.UsedRange, .Columns("B")).Cut .Range("T1")
        Intersect(.UsedRange, .Columns("G")).Cut .Range("U1")
        Intersect(.UsedRange, .Columns("F")).Cut .Range("V1")
        Intersect(.UsedRange, .Range("Q:V")).Copy wsPOT.Cells(Rows.Count, "B").End(xlUp).Offset(1)
        .Delete
    End With

    lastrow = wsPOD.Cells(Rows.Count, "B").End(xlUp).Row
    wsPOT.Range("R1:X1").Copy
    wsPOT.Range("B3:H" & lastrow).PasteSpecial xlPasteFormats
    wsPOT.Range("N2:O2").Copy wsPOT.Range("N3:O" & lastrow)
    wsPOT.Range("P1:Q1").Copy wsPOT.Range("I3:J" & lastrow)
    wsPOT.Range("K3:K" & lastrow).Borders.Weight = xlThin
End With



Application.CutCopyMode = False

End Sub

错误在这里：

**With Intersect(wsPOD.UsedRange, ActiveSheet.Columns("N"))**
    .AutoFilter 1, "<>Different"
    .SpecialCells(xlCellTypeVisible).EntireRow.Delete
End With

- Matt Ridge

---

Activesheet 应该是哪个工作表？“PO Data”？ - Siddharth Rout

脚本运行的表格是PO Tracking，脚本旨在从PO Data获取数据，对其进行组织，然后将其输出到PO Tracking上。 - Matt Ridge

将“Activesheet”替换为“wsPOD”。这样它就变成了“With Intersect(wsPOD.UsedRange, wsPOD.Columns("N"))”。现在它将在任何工作表中运行。 - Siddharth Rout

谢谢，我也在考虑这样的想法，但不知道该如何表达 :) - Matt Ridge

Answer 1

如果活动工作表不是wsPOD，则无法在两个工作表上有范围的交叉点，因此： With Intersect(wsPOD.UsedRange, ActiveSheet.Columns("N")) 根据定义必须失败。

编辑...并参见@SiddharthRout的评论以获取修复方法。

- Doug Glancy

---

我甚至会补充说，将所有工作表引用设置为变量并远离ActiveSheet是很好的VBA实践，除非绝对必要。这样你就始终知道和控制着你正在交互的工作表。 - Scott Holtzman

Answer 2

关于“为什么会出现错误”，请参考Doug Glancy的答案。

此外，关于“如何避免此类错误”，可以使用以下方法：

Dim rng1 As Range, rng2 As Range
Set rng1 = wsPOD.UsedRange
Set rng2 = ActiveSheet.Columns("N")
If (rng1.Parent.Name = rng2.Parent.Name) Then
    Dim ints As Range
    Set ints = Intersect(rng1, rng2)
    If (Not (ints Is Nothing)) Then
        With ints
            ' Do your job
        End With
    End If
End If

在使用交集之前，通常最好对其进行验证。

- sancho.s ReinstateMonicaCellio

---

注意: rng1.Parent.Name = rng2.Parent.Name 可能对于不同打开的工作簿中具有相同名称的工作表会导致后续的 Intersect 出现1004错误！最好像我的回答中那样比较父对象/工作表本身：https://dev59.com/xWPVa4cB1Zd3GeqP-fX2#56303096 - Andreas Covidiot

Answer 3

1. 为了避免错误，需要检查工作表（ myRange.Parent ）的相等性，代码如下：

   if rng1.Parent is rng2.Parent then if Not Intersect( rng1, rng2 ) Is Nothing then _
       '... 这里是您的条件代码 ...
   

   • 提示：在此需要注意的重要事项是，不能使用 ... And ... 连接两个条件，因为 VBA 会评估所有条件，即使第一个条件为 False ，它也不会停止评估 :-/

2. 或者确保范围的工作表相同（例如，ws1），即显式指定/创建/交集您的 Range 对象，代码如下：

   if Not Intersect( ws1.Range("A1:A2"), ws1.Range("A2:B2") ) Is Nothing then _
      '... 这里是您的条件代码 ...
   

- Andreas Covidiot