logo标签列表

用XSLT生成另一个XSLT脚本

xmlxslt
10

在这个帖子中，我参考了我的上一个帖子：使用XSLT将XML转换为CSV - 动态列。

在引用的帖子中，XSLT脚本工作正常，但对于大型XML文档，性能不佳。现在我想编写一个XSLT脚本，用于输出另一个XSLT脚本，该脚本将输出最终的CSV文件。

问题：

如何编写第一个XSLT脚本？输出应如下所示：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/*">
    <xsl:text>Name;</xsl:text>
    <xsl:text>Brother;</xsl:text>
    <xsl:text>Sister</xsl:text>
    <-- this part is dynamic -->
    <xsl:apply-templates select="Person" />
</xsl:template>

<xsl:template match="Person">
    <xsl:value-of select="Name" />
    <xsl:value-of select="Brother" />
    <xsl:value-of select="Sister" />
    <-- this part is dynamic too -->
    <xsl:text>&#10;</xsl:text>
</xsl:template>
</xsl:stylesheet>

输入的 XML 文件与参考线程中的文件相同:

<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>

对于每种不同类型的元素，在生成的 XSLT 脚本中应该有像以下这样的一行：

<xsl:text>Type;</xsl:text>
其实你不需要一个双外部阶段的解决方案。你所需要做的就是提高Tim的解决方案的大规模效率。你真正应该问的问题是如何在大规模上进行优化。 - Sean B. Durkin
3个回答
18
要编写一个输出另一个XSLT的XSLT，您需要使用生成输出元素，例如。
<xsl:element name="xsl:text">

如果你想要使用字面结果元素，请使用<xsl:namespace-alias>。 XSLT规范中有一个示例：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fo="http://www.w3.org/1999/XSL/Format"
  xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias">

<xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>

<xsl:template match="/">
  <axsl:stylesheet>
    <xsl:apply-templates/>
  </axsl:stylesheet>
</xsl:template>

样式表中的任何 <axsl:...> 元素都会在输出中变成 <xsl:...>。

您的解决方案最适合我的问题。使用axsl是我现在的方法。我稍后会测试Sean的解决方案。 - Andre
1
与其使用双外部阶段解决方案（即编写一个样式表来执行另一个样式表），我认为您最好采用Tim的解决方案版本，以便在大规模情况下更好地提高性能。请使用您的“大型XML文档”作为输入来测量此解决方案的性能。 这个XSLT 1.0样式表... 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />

<xsl:key name="kTypes" match="Type" use="." />  
<xsl:variable name="distinct-types"
  select="/*/Person/FamilyMembers/FamilyMember/Type[
  generate-id()=generate-id(key('kTypes',.)[1])]" />

<xsl:template match="/">
  <xsl:value-of select="'Name;'" />
  <xsl:for-each select="$distinct-types">
    <xsl:value-of select="." />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
  <xsl:apply-templates select="*/Person" />
</xsl:template>

<xsl:template match="Person">
  <xsl:value-of select="concat(Name,';')" />
  <xsl:variable name="family" select="FamilyMembers/FamilyMember" />
  <xsl:for-each select="$distinct-types">
    <xsl:variable name="type" select="string(.)" />
    <xsl:value-of select="$family/self::*[Type=$type]/Name" />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
</xsl:template>

</xsl:stylesheet>

...将高效地转换此输入（或其他输入）...

<t>
<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
</t>

...并产生文本...

Name;Sister;Brother;Father
John;Lisa;Tom;
Daniel;;;Peter
我会测试并给出反馈。可能需要一些时间。 - Andre
0
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接