匿名方法作为函数结果

Question

我想做的是将得到的匿名方法作为函数结果分配给同类型的变量。Delphi抱怨无法进行赋值。显然，Delphi认为我要分配“GetListener”函数而不是该函数的结果。非常感谢您的任何帮助。

type
      TPropertyChangedListener = reference to procedure (Sender: TStimulus);

      TMyClass = class
        function GetListener:TPropertyChangedListener
      end;


    ....

    var MyClass: TMyClass;
        Listener: TPropertyChangedListener;
    begin
      MyClass:= TMyClass.create;
      Listener:= MyClass.GetListener;   //  Delphi compile error: E2010 Incompatible types:  TPropertyChangedListener' and 'Procedure of object' 

    end; 

- iamjoosy

Answer 1

使用以下语法：

  Listener:= MyClass.GetListener();

我写了以下示例，以明确 MyClass.GetListener() 和 MyClass.GetListener 赋值之间的区别：

type
  TProcRef = reference to procedure(Sender: TObject);
  TFunc = function: TProcRef of object;

  TMyClass = class
    function GetListener: TProcRef;
  end;

function TMyClass.GetListener: TProcRef;
begin
  Result:= procedure(Sender: TObject)
  begin
    Sender.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  MyClass: TMyClass;
  ProcRef: TProcRef;
  Func: TFunc;

begin
  MyClass:= TMyClass.Create;
// standard syntax
  ProcRef:= MyClass.GetListener();

// also possible syntax
//  Func:= MyClass.GetListener;
//  ProcRef:= Func();

  ProcRef(MyClass);
end;

- kludg

---

谢谢Serg。这正是我在寻找的两个()。有时候事情就是那么简单...只要你知道它们。 - iamjoosy

这就是为什么我总是使用C的调用语法（也称为()括号）来明确它是一个调用。 - alex

Answer 2

我发现解决这个问题的唯一方法是这样声明你的GetListener：

procedure GetListener(var a: TPropertyChangedListener);

可能有一些语法可以强制编译器考虑函数的结果而不是函数本身，但我找不到任何方法。

- Ken Bourassa

---

嗯，是的，我自己也考虑过那个解决方案。缺点是会让代码变得有点混乱 - 特别是因为在我的实际代码中，我想将 GetListener 的结果添加到 TList<TPropertyChangedListener> 中。在这种情况下，我需要声明一个额外的变量，按照你建议的方法获取 Listener，并将变量添加到列表中，而不是使用 MyList.Add(GetListener)。 - iamjoosy