在elisp中确定节日的函数

Question

有没有一种函数可以在elisp中确定当前系统日期是否是节假日，类似这样的功能。

(is-holiday (current-time))

- luozengbin

Answer 1

答案要求用户设置预定义假日的日历，例如此示例。我已经为5月9日包含了一个测试假期 - 如果用户希望在5月9日之外的任何一天测试此功能，则可能希望将 任意测试假期 更改为测试正在执行的任何一天 - 测试完成后，测试条目可以删除。

有关如何格式化假期的示例，请参阅变量calendar-holidays的文档字符串，在库holidays.el中 - 例如，holiday-fixed； holiday-float； holiday-sexp； （月相）； （太阳赤道线和冬至）； holiday-hebrew； holiday-islamic； holiday-bahai； holiday-julian； holiday-chinese；等等。 您如何尝试此示例？：块/复制/粘贴代码到您的* scratch *缓冲区中;并键入M-x eval-buffer RET ;然后输入M-x is-holiday RET 。它是一个完全功能的工作草稿。如果您在尝试后决定不喜欢它，只需重新启动Emacs，您将回到尝试之前的状态。

执行测试是使用最新的Emacs公共版本进行的： GNU Emacs 24.4.1（x86_64-apple-darwin10.8.0，NS apple-appkit-1038.36）于2014年10月20日在builder10-6.porkrind.org上 。

(require 'holidays)

(defcustom my-custom-holiday-list (mapcar 'purecopy '(
  (holiday-fixed 1 1 "New Year's Day")
  (holiday-float 1 1 3 "Martin Luther King Day")
  (holiday-float 2 1 3 "President's Day")
  (holiday-float 5 1 -1 "Memorial Day")
  ;; ARBITRARY TEST HOLIDAY -- MAY 9
  (holiday-fixed 5 9 "Arbitrary Test Holiday -- May 9")
  (holiday-fixed 7 4 "Independence Day")
  (holiday-float 9 1 1 "Labor Day")
  (holiday-float 10 1 2 "Columbus Day")
  (holiday-fixed 11 11 "Veteran's Day")
  (holiday-float 11 4 4 "Thanksgiving")
  (holiday-fixed 12 25 "Christmas")
  (solar-equinoxes-solstices)
  (holiday-sexp calendar-daylight-savings-starts
    (format "Daylight Saving Time Begins %s"
      (solar-time-string
        (/ calendar-daylight-savings-starts-time (float 60))
        calendar-standard-time-zone-name)))
  (holiday-sexp calendar-daylight-savings-ends
      (format "Daylight Saving Time Ends %s"
       (solar-time-string
         (/ calendar-daylight-savings-ends-time (float 60))
         calendar-daylight-time-zone-name))) ))
  "Custom holidays defined by the user."
  :type 'sexp
  :group 'holidays)

(defun is-holiday ()
  "Is today a holiday?"
(interactive)
  (let* (
      (d1 (time-to-days (current-time)))
      (date (calendar-gregorian-from-absolute d1))
      ee
      res-holidays
      (displayed-month (nth 0 date))
      (displayed-year (nth 2 date))
      (holiday-list
        (dolist (p my-custom-holiday-list res-holidays)
          (let* (h)
           (when (setq h (eval p))
             (setq res-holidays (append h res-holidays)))))) )
    (mapcar
      (lambda (x)
        (let ((txt (format "%s -- %s" (car x) (car (cdr x)))))
          (when (eq d1 (calendar-absolute-from-gregorian (car x)))
            (push txt ee))))
      holiday-list)
    (if ee
      (message "The following holiday(s) is/are today:  %s" (nreverse ee))
      (message "Today is not a holiday."))))

- lawlist