背景：.NET Framework 3.5
我知道如何使用XSLT执行单个XML转换，但没有找到关于链接XML转换的好例子。
输入： - XPathDocument格式的XML文档。 - 多个XSL文件的文件路径。
期望输出： - 最好是XPathDocument/IXPathNavigable格式，表示已应用所有转换的XML，一个接一个。
示例场景：
输入的xml：<doc></doc>
xsl-1: .xsl文件，在doc元素下添加<one />子元素。
xsl-2: .xsl文件，在doc元素下添加<two />子元素。
期望结果
<doc><one /><two /></doc>
目标
利用XPathDocument/IXPathNavigable的向前只读特性或更好的特性。避免将整个文档加载到内存中。
XslCompiledTransform xsl1 = new XslCompiledTransform();
xsl1.Load("xsl1.xsl");
XslCompiledTransform xsl2 = new XslCompiledTransform();
xsl1.Load("xsl2.xsl");
using (Stream stream = new MemoryStream())
{
using (XmlReader xmlReader1 = XmlReader.Create("source.xml"))
{
xsl1.Transform(xmlReader1, stream);
}
stream1.Position = 0;
using (XmlReader xmlReader2 = XmlReader.Create(stream))
{
xsl2.Transform(xmlReader2, "output.xml");
}
}
通过使用xmlreader，您将获得所需的单向前进。我刚刚将第一个结果输出到了MemoryStream，但是您也可以将其输出到临时文件中。
为了获得额外的性能提升，您可能需要考虑预编译xslt。
I. 这演示了如何使用支持 exslt node-set() 扩展函数的任何 XSLT 1.0 处理器（包括 .NET XslCompiledTransform）执行多遍 XSLT 1.0 转换。
对于其他 XSLT 1.0 处理器，需要将 ext:node-set() 替换为它们支持的内容，例如 MSXML 的 msxsl:node-set()（与正确的命名空间关联的 msxsl）。
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common"
exclude-result-prefixes="ext xsl">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="node()|@*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/">
<xsl:variable name="vrtfPass1">
<xsl:apply-templates select="node()"/>
</xsl:variable>
<xsl:apply-templates mode="pass2"
select="ext:node-set($vrtfPass1)/node()"/>
</xsl:template>
<xsl:template match="/*">
<xsl:copy>
<xsl:copy-of select="@*"/>
<one/>
<xsl:apply-templates/>
</xsl:copy>
</xsl:template>
<xsl:template match="node()|@*" mode="pass2">
<xsl:copy>
<xsl:apply-templates select="node()|@*" mode="pass2"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/*/one" mode="pass2" >
<xsl:call-template name="identity"/>
<two/>
</xsl:template>
</xsl:stylesheet>
当这个转换应用于此XML文档时：
<doc/>
期望的结果已经生成：
<doc>
<one/>
<two/>
</doc>
二、目前XSLT 1.0和XSLT 2.0使用XPath，这需要整个XML文档（表示）在RAM中。
XSLT 2.1的工作草案（最近更名为3.0）提出了一个新的流式处理特性，如果此工作草案成为官方建议，那么符合XSLT 3.0处理器的要求可以实现流式处理。
三、XPathDocument的仍将整个XML文档表示保留在内存中。 XPathDocument提供的只是单向迭代，并不意味着XslCompiledTransform执行任何XML文档的流式处理。
如果你想避免将整个文档树加载到内存中，你可能需要考虑一种不同于XSLT的技术。
有一种称为XML流式转换（STX）的方法，它不需要构建内存树。您可以在SourceForge上查看STX项目。
关于流式转换的概述，我推荐阅读以下文章：
//somenode）将搜索整个文档树，因此需要加载整个文档。 - Dirk Vollmar<xsl:value-of select='count(//*)'/>的操作。 - Robert Rossney