由于zsh中的日期命令，多行提示格式错误

Question

由于zsh中的日期命令，多行提示格式错误

3

以下是我.zshrc文件的内容：

setopt PROMPT_SUBST
precmd(){
  echo""
  LEFT="$fg[cyan]$USERNAME@$HOST $fg[green]$PWD"
  RIGHT="$fg[yellow]$(date +%I:%M\ %P)"
  RIGHTWIDTH=$(($COLUMNS-${#LEFT}))
  echo $LEFT${(l:$RIGHTWIDTH:)RIGHT}
}
PROMPT="$ "

这给我带来了以下截图

右侧的时间部分总是不会延伸到终端的边缘，即使调整大小也是如此。我认为这是由于$(date +%I:%M\ %P)引起的。有人知道如何解决吗？

编辑：放大截图

- Lord_Zane 55

1

请将您的屏幕截图裁剪到仅包含终端（现在如果不放大很难看到问题），无论您的背景有多漂亮... - 4ae1e1

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- 4ae1e1 · Accepted Answer

虽然您的想法值得赞扬，但您遇到的问题是您的LEFT和RIGHT包含ANSI转义序列（用于颜色），这些序列应该是零宽字符，但如果您天真地使用$#name或${（l:expr:)name}，它们仍然会被计算为字符串的长度。

此外，从风格上讲，最好使用Zsh的内置提示扩展，它将许多人们可能想在其提示中看到的常见内容包装在短百分号转义序列中。特别是，有内置的颜色序列，因此您不需要依赖非标准的$fg[blah]。

下面是一个近似于您的提示符的示例，以我喜欢的编码风格编写... 不完全一样，我使每个部分都非常详细，以便更易理解（希望如此）。在剥离颜色转义序列并执行提示扩展后，左侧和右侧预提示的长度被计算出来，这给出了正确的显示长度（我不可能在几分钟内完成；我从pure中复制了表达式）。

precmd(){
    local preprompt_left="%F{cyan}%n@%m %F{green}%~"
    local preprompt_right="%F{yellow}%D{%I:%M %p}%f"
    local preprompt_left_length=${#${(S%%)preprompt_left//(\%([KF1]|)\{*\}|\%[Bbkf])}}
    local preprompt_right_length=${#${(S%%)preprompt_right//(\%([KF1]|)\{*\}|\%[Bbkf])}}
    local num_filler_spaces=$((COLUMNS - preprompt_left_length - preprompt_right_length))
    print -Pr $'\n'"$preprompt_left${(l:$num_filler_spaces:)}$preprompt_right"
}

PROMPT="$ "

编辑: 在某些终端仿真器中，打印恰好$COLUMN个字符可能会换行。在这种情况下，请使用以下内容替换相应的行:

local num_filler_spaces=$((COLUMNS - preprompt_left_length - preprompt_right_length - 1))

编辑结束。

这个非常可定制，因为你几乎可以在preprompt_left和preprompt_right中放入任何东西，仍然可以得到正确的长度 - 只需记住使用提示转义序列用于零宽度序列，例如，%F{}%f表示颜色，%B%b表示粗体等。再次阅读有关提示扩展的文档：http://zsh.sourceforge.net/Doc/Release/Prompt-Expansion.html。

注意：您可能会注意到%D{%I:%M %p}扩展为像11:35 PM这样的内容。那是因为我想使用%P来获取pm，但并不是每个strftime实现都支持%P。最坏的情况是：如果您真的想要小写但不支持%P，请使用原始命令替换$(date +'%I:%M %P')。

此外，我使用%~而不是%/，这样你会得到~/Desktop而不是/c/Users/johndoe/Desktop。有些人喜欢，有些人不喜欢。然而，正如我所说，这很容易自定义。