如何保存带透明度的png文件？

Question

如何保存带透明度的png文件？

5

我正在使用2011年版的Barcode Studio将QR码绘制到Graphics32-TImage32组件中，并且我希望以png格式保存，但是白色作为透明色，这在Graphics32的OuterColor中进行了指定。

在FormCreate事件中，我只是：

procedure TForm1.FormCreate(Sender: TObject);
begin
  psBarcodeComponent1.BarCode := 'some text here...';
end;

目前我已将绘画分配给按钮点击事件

procedure TForm1.Button8Click(Sender: TObject); // Paint the barcode
var
  bmp: TBitmap32;
  Coords: TRect;
begin
 bmp := TBitmap32.Create;
 bmp.SetSize(image.Width, image.Height);
 bmp.Canvas.Brush.Color := color;
 bmp.Canvas.Rectangle(-1, -1, image.Width+2, image.Height+2);

 bmp.DrawMode := dmTransparent;
 bmp.OuterColor := clWhite;

 // make Coords the size of image
 Coords := Rect(0,0,image.Width,image.Height);
 psBarcodeComponent1.PaintBarCode(bmp.Canvas, Coords);
 image.Bitmap.Assign(bmp);
end;

我正在使用Vampyre Imaging Library将位图转换为PNG格式，但我很乐意使用任何库、函数和建议——我已经尝试了近一个星期！我已经阅读并反复阅读了graphics32和Vampyre Imaging Library的文档，但是我尝试的所有方法都无法将白色转换为透明颜色。我已经尝试了clWhite、clWhite32，并将drawMode设置为dmBlend并应用ChromaKey函数，但都没有成功，只有沮丧、咖啡和一点啤酒；）

这是我保存它的方式...

procedure TForm1.Button7Click(Sender: TObject); // Save with Vampyre Imaging Lib
{ Try to save in PNG format with transparancy }
var
  FImage: TSingleImage;
begin
  FImage := TSingleImage.Create;
  ConvertBitmap32ToImage(image.Bitmap, FImage);
  FImage.SaveToFile('VampyreLibIMG.png');
end;

这将导致缩略图呈黑色，并且在Windows照片查看器中查看时完全透明。

希望我提供的信息足够，有人能够帮助我。

Chris

- Shambhala

当您将bmp.transparentColor := clWhite;设置为bmp.outerColor := clWhite时会发生什么？ - user497849

TBitmap32中没有这个成员 - 我也尝试从像素中选择OuterColor，但没有效果。bmp.OuterColor：= bmp.Pixel [0,1]; - Shambhala

2个回答

4

这种方法对我很有效：

uses GR32, GR32_PNG, GR32_PortableNetworkGraphic;

var
  Y: Integer;
  X: Integer;
  Png: TPortableNetworkGraphic32;

  function IsWhite(Color32: TColor32): Boolean;
  begin
    Result:= (TColor32Entry(Color32).B = 255) and
             (TColor32Entry(Color32).G = 255) and
             (TColor32Entry(Color32).R = 255);
  end;

begin
  with Image321 do
  begin
    Bitmap.ResetAlpha;
    for Y := 0 to Bitmap.Height-1 do
      for X := 0 to Bitmap.Width-1 do
      begin
        if IsWhite(Bitmap.Pixel[X, Y]) then
          Bitmap.Pixel[X,Y]:=Color32(255,255,255,0);
      end;
    Png:= TPortableNetworkGraphic32.Create;
    Png.Assign(Bitmap);
    Png.SaveToFile('C:\Temp\NowTransparent.png');
    Png.Free;
  end;
end;

这里使用了GR32 PNG库。这是一种相当直接的方法，将所有白色像素设置为透明。

PS：Image321是一个TImage32组件，包含我的TBitmap32。

- Heinrich Ulbricht

这个例子在“procedure TCustomBitmap32.Assign(Source: TPersistent)”中出现了错误，位于GR32.pas单元中。有什么帮助吗？ - XBasic3000

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- user497849 · Accepted Answer

你没有指定Delphi版本，但是如果你的Delphi版本有“PngImage”（我相信它随D2009+一起发布），下面的代码可以完美地工作（在Gimp和Windows照片查看器中加载，它会绘制一个带有透明背景的框架和一些文本，请随意玩耍：

uses
  PngImage;

procedure TForm1.OnBtnClick(Sender: TObject);
var
  bmp: TBitmap;
  png: TPngImage;
begin
  bmp := TBitmap.Create;
  bmp.Width := 200;
  bmp.Height := 200;

  bmp.Canvas.Brush.Color := clBlack;
  bmp.Canvas.Rectangle( 20, 20, 160, 160 );

  bmp.Canvas.Brush.Style := bsClear;
  bmp.Canvas.Rectangle(1, 1, 199, 199);

  bmp.Canvas.Brush.Color := clWhite;
  bmp.Canvas.Pen.Color := clRed;
  bmp.Canvas.TextOut( 35, 20, 'Hello transparent world');

  bmp.TransparentColor := clWhite;
  bmp.Transparent := True;

  png := TPngImage.Create;
  png.Assign( bmp );
  png.SaveToFile( 'C:\test.png' );

  bmp.Free;
  png.Free;
end;