如何获取USB设备的驱动器字母？

Question

我正在使用WMI获取所有插入的USB磁盘制造商名称。代码运行良好，但我有一个问题，如何确定某个磁盘所对应的驱动器号码...我只能获取设备名称，例如

(\\.\PhysicalDrive1) ... 我该如何将其转换为普通的驱动器号码？

- opc0de

---

RRUZ 很快就会到这里。 - Andreas Rejbrand

Answer 1

如果您得到像 \\.\PHYSICALDRIVE1 这样的值，这意味着您正在使用 Win32_DiskDrive wmi 类和 DeviceID 属性，因此为了获取驱动器字母，您必须使用一个 ASSOCIATORS 类，它会在包含您要查找信息的 wmi 类之间创建链接（Win32_LogicalDisk）和您正在使用的类 (Win32_DiskDrive)。

所以您必须做类似于以下操作:

Win32_DiskDrive-> Win32_DiskDriveToDiskPartition -> Win32_DiskPartition -> Win32_LogicalDiskToPartition -> Win32_LogicalDisk

请查看此示例函数：

{$APPTYPE CONSOLE}

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;


function DeviceIDToDrive(const ADeviceID : string) : string;
var
  FSWbemLocator  : OLEVariant;
  objWMIService  : OLEVariant;
  colLogicalDisks: OLEVariant;
  colPartitions  : OLEVariant;
  objPartition   : OLEVariant;
  objLogicalDisk : OLEVariant;
  oEnumPartition : IEnumvariant;
  oEnumLogical   : IEnumvariant;
  iValue         : LongWord;
  DeviceID       : string;
begin;
  Result:='';
  FSWbemLocator   := CreateOleObject('WbemScripting.SWbemLocator');
  objWMIService   := FSWbemLocator.ConnectServer('localhost', 'root\CIMV2', '', '');
  DeviceID        := StringReplace(ADeviceID,'\','\\',[rfReplaceAll]); //Escape the `\` chars in the DeviceID value because the '\' is a reserved character in WMI.
  colPartitions   := objWMIService.ExecQuery(Format('ASSOCIATORS OF {Win32_DiskDrive.DeviceID="%s"} WHERE AssocClass = Win32_DiskDriveToDiskPartition',[DeviceID]));//link the Win32_DiskDrive class with the Win32_DiskDriveToDiskPartition class
  oEnumPartition  := IUnknown(colPartitions._NewEnum) as IEnumVariant;
  while oEnumPartition.Next(1, objPartition, iValue) = 0 do
   begin
       if not VarIsNull(objPartition.DeviceID) then
       begin
        colLogicalDisks := objWMIService.ExecQuery('ASSOCIATORS OF {Win32_DiskPartition.DeviceID="'+VarToStr(objPartition.DeviceID)+'"} WHERE AssocClass = Win32_LogicalDiskToPartition'); //link the Win32_DiskPartition class with theWin32_LogicalDiskToPartition class.
        oEnumLogical  := IUnknown(colLogicalDisks._NewEnum) as IEnumVariant;
          if oEnumLogical.Next(1, objLogicalDisk, iValue) = 0 then
          begin
              Result:=objLogicalDisk.DeviceID;
              objLogicalDisk:=Unassigned;
          end;
       end;
       objPartition:=Unassigned;
   end;
end;

begin
 try
    CoInitialize(nil);
    try
      Writeln(DeviceIDToDrive('\\.\PHYSICALDRIVE2'));
    finally
      CoUninitialize;
    end;
 except
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
  end;
  Readln;
end.

- RRUZ

---

非常感谢，伙计。你应该写一本关于使用WMI实现酷炫功能的书 :D。 - opc0de

@opc0de - 我想到整个Windows内部；例如预览处理程序将需要我几个月时间来开发 :) (+1) - user532231