TEmbeddedWB和背景色

Question

TEmbeddedWB和背景色

delphiwebbrowser-controldelphi-xe

3

如何在没有显示任何页面的情况下更改TEmbeddedWB组件的默认背景颜色（clWhite）？

enter image description here

- Salvador

2个回答

6

通过将 IHTMLDocument2.bgColor 属性设置为来自 color table 的某个值，可以轻松地实现此目标。以下代码将导航到“空”页面并将其背景色更改为红色。请注意，您需要在每次使用此解决方案导航到该“空”页面后设置背景颜色。

uses
  GraphUtil, MSHTML;

procedure TForm1.Button1Click(Sender: TObject);
begin
  EmbeddedWB1.AssignEmptyDocument(True);
  (EmbeddedWB1.Document as IHTMLDocument2).bgColor := ColorToWebColorStr(clRed);
end;

- TLama

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- kobik · Accepted Answer

可以通过在创建表单时加载默认页面来实现（快速方式）:

function ColorToHTML(const Color: TColor): string;
var
  ColorRGB: Integer;
begin
  ColorRGB := ColorToRGB(Color);
  Result := Format('#%0.2X%0.2X%0.2X',
    [GetRValue(ColorRGB), GetGValue(ColorRGB), GetBValue(ColorRGB)]);
end;

WebBrowser1.Navigate(Format('about:<body bgcolor="%s" style="overflow:hidden"/>', [ColorToHTML(clRed)]));

或者更常见的方法（TWebBrowser/TEmbeddedWB）：

uses ActiveX, MSHTML;
procedure LoadDocFromString(ABrowser: TWebBrowser; const HTMLString: WideString);
var
  v: OleVariant;
  HTMLDocument: IHTMLDocument2;
begin
  if not Assigned(ABrowser.Document) then
  begin
    ABrowser.Navigate('about:blank');
    while ABrowser.ReadyState <> READYSTATE_COMPLETE do
      Application.ProcessMessages;
  end;
  HTMLDocument := ABrowser.Document as IHTMLDocument2;
  v := VarArrayCreate([0, 0], varVariant);
  v[0] := HTMLString;
  HTMLDocument.Write(PSafeArray(TVarData(v).VArray));
  HTMLDocument.Close;
end;

LoadDocFromString(WebBrowser1, Format('<body style="background-color:%s; scrollbar-base-color:%s;"/>',
  [ColorToHTML(clGray), ColorToHTML(clBlack)]));

TEmbeddedWB 特定内容：

EmbeddedWB1.LoadFromString(Format('<body style="background-color:%s; scrollbar-base-color:%s;"/>',
    [ColorToHTML(clGray), ColorToHTML(clBlack)]));

编辑：请查看这个教程：如何自定义TWebBrowser用户界面。
该教程解释了如何使用IOleClientSite和IDocHostUIHandler自定义WB，这也为浏览器对象本身提供了默认的CSS。

我们可以动态创建一个样式表，了解表单的颜色和字体，并告诉浏览器使用它（请看第5部分的结果）。

由于TEmbeddedWB实现了IDocHostUIHandler，因此您可以使用它的HostCSS属性（但仍需要加载一个空白文档）：

procedure TForm1.Button1Click(Sender: TObject);
const
  // Template for default CSS style
  cCSSTplt = 'body {background-color: %0:s}';
var
  FmtCSS: string;  // Stores default CSS
begin
  FmtCSS := Format(cCSSTplt, [ColorToHTML(clYellow)]);
  EmbeddedWB1.HostCSS := FmtCSS;
  EmbeddedWB1.AssignEmptyDocument;
end;

请注意，使用CSS样式模板的HostCSS属性将在没有CSS样式的页面上使用此模板。