如何在开始菜单中为我的程序创建一个菜单？

Question

这可能是一个简单的问题，但我甚至不确定要搜索哪个术语，所以必须询问。当程序被固定到开始菜单时，我希望它在悬停时有一个菜单。 我附上一个Windows PowerShell演示此功能并呈现任务列表的截图。

其他程序有时使用此功能列出最近打开的文件等等。我相信这是标准化的，有教程可以学习。请问有人可以指向一下教程，或者解释如何做到这一点吗？我希望使用的编程语言不太重要，但我精通Delphi、C++和C#。

- Joe

Answer 1

在Windows 7中，您必须使用ICustomDestinationList.AddUserTasks方法，它是任务栏扩展的一部分。

更新

尝试此示例控制台应用程序，运行代码并将应用程序的快捷方式移动到开始菜单。（这只是一个示例代码片段，请记得添加返回HResult值的所有方法的检查）

program ProjectTasks;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils,
  ActiveX,
  windows,
  ComObj,
  ShlObj,
  PropSys,
  ObjectArray;

const
  PKEY_TITLE : TPropertyKey = ( fmtID : '{F29F85E0-4FF9-1068-AB91-08002B27B3D9}'; pID : 2);

procedure CreateTaskList;
var
  LCustomDestinationList : ICustomDestinationList;
  pcMaxSlots : Cardinal;
  ppv : IObjectArray;
  poa : IObjectCollection;
  LTask : IShellLink;
  LPropertyStore : IPropertyStore;
  LTitle : TPropVariant;
  LTaskBarList : ITaskBarList;
  LTaskBarList3 : ITaskBarList3;
  hr : HRESULT;
begin
    LTaskBarList := CreateComObject(CLSID_TaskBarList) as ITaskBarList;
    hr := LTaskBarList.QueryInterface(IID_ITaskBarList3, LTaskBarList3);
    if hr <> S_OK then exit;


    LCustomDestinationList := CreateComObject(CLSID_DestinationList) as ICustomDestinationList;
    LCustomDestinationList.BeginList(pcMaxSlots, IID_IObjectArray, ppv);
    poa := CreateComObject(CLSID_EnumerableObjectCollection) as IObjectCollection;


    LTask := CreateComObject(CLSID_ShellLink) as IShellLink;
    LTask.SetPath(pChar(ParamStr(0))); //set the  path to the exe
    LTask.SetDescription('This is a description sample');
    LTask.SetArguments(PChar('Bar'));
    LTask.SetIconLocation(PChar('Shell32.dll'),1);
    LPropertyStore := LTask as IPropertyStore;
    LTitle.vt := VT_LPWSTR;
    LTitle.pwszVal := PChar('This is the Task 1');
    LPropertyStore.SetValue(PKEY_Title,LTitle);
    LPropertyStore.Commit;
    poa.AddObject(LTask);

    LTask := CreateComObject(CLSID_ShellLink) as IShellLink;
    LTask.SetPath(PChar(ParamStr(0))); //set the  path to the exe
    LTask.SetDescription('This is a description sample');
    LTask.SetArguments(PChar('Foo'));
    LTask.SetIconLocation(pChar('Shell32.dll'),1);
    LPropertyStore := LTask as IPropertyStore;
    LTitle.vt := VT_LPWSTR;
    LTitle.pwszVal := pChar('This is the Task 2');
    LPropertyStore.SetValue(PKEY_Title,LTitle);
    LPropertyStore.Commit;
    poa.AddObject(LTask);


    LCustomDestinationList.AddUserTasks(poa as IObjectArray);
    LCustomDestinationList.CommitList;
end;

begin
 try
    CoInitialize(nil);
    try
       CreateTaskList;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

- RRUZ

---

这里有一个很好的C#示例，展示如何实现此功能：http://www.canofcode.co.uk/software/how-to-add-jumplists-to-a-c-application/。 - nateirvin