MS Excel - 使用分隔符连接(concatenate)函数

Question

我有一个包含数字的长表格。

我需要将它们放在一个字符串中，用分号分隔； 例如：4364453;24332432;2342432

我知道可以这样做：

=concat(A1:A2000)

但是这将把它合并成一个字符串，没有分隔符 - 当你指定范围时，我似乎找不到有关分隔符的选项。

谢谢

- Wasteland

---

你使用的是哪个版本的Excel？ - CallumDA

最新的Office365教育版 - 我认为是2016版本。 - Wasteland

Answer 1

请使用TEXTJOIN()代替：

=TEXTJOIN(";",TRUE,A1:A2000)

对于没有OFFICE 365 Excel的人，可以使用这个UDF来模仿TEXTJOIN函数。将其放置在附加到工作簿的模块中，并使用上述公式进行调用。

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function

- Scott Craner

---

倒数第二行应该写成 TEXTJOIN = Left... 而不是 TEXTJOIN2，如果你不想在文本末尾添加分隔符。 - Rotsiser Mho

Answer 2

如果你和我一样，使用的工作电脑上装有旧版本的Excel，没有TEXTJOIN函数，你可以使用宏来代替。这是一个我快速设计的示例，适用于单列或单行。只需点击要放置结果字符串的位置，然后运行宏。

请注意，此方法仅处理一行或一列的情况，与你提供的示例数据类似。如果你想要拼接A1:C3这样的范围，就需要不同的逻辑。

Sub ConcatenateRange()

Dim resultCell As Range
    Set resultCell = Selection

Dim concatRange As Range
    Set concatRange = Application.InputBox("Select a range", "Obtain Range Object", Type:=8)

Dim optionalSeparator As String
    optionalSeparator = Chr(34) & InputBox("Any Separator?") & Chr(34)

Dim outputString As String
    outputString = "=TRIM(CONCATENATE("

Dim rangeSize As Integer
    rangeSize = concatRange.Columns.count + concatRange.Rows.count

For Each item In concatRange
    outputString = outputString & item.Address(RowAbsolute:=False, ColumnAbsolute:=False)

    rangeSize = rangeSize - 1

    If (rangeSize > 1) Then
        outputString = outputString & ", " & optionalSeparator & ", "
    Else
        outputString = outputString & "))"
    End If
Next

resultCell.formula = outputString

End Sub

- Joe

---

如果OP有CONCAT()，那么他们也有TEXTJOIN()，因为它们同时推出。 - Scott Craner

你确定吗？我正在使用我的工作电脑，我肯定在Excel 2010上有CONCATENATE函数，但是我没有TEXTJOIN。 - Joe

CONCAT和CONCATENATE是两个不同的函数。 - Scott Craner

哦，噗。好发现，我甚至没有在OP中注意到那个。我从来没有用过带有CONCAT的Excel版本，所以我的大脑只是在心理上替换了Concatenate。你认为我应该删除这个还是保留它？ - Joe

留下它作为一个很好的选择，供那些以后可能会遇到这个页面的人使用。我正在更新我的内容，加入一个模拟TEXTJOIN函数的用户定义函数（UDF）。 - Scott Craner

谢谢 - 我已经拥有最新的（O365的一部分）。 - Wasteland

Answer 3

给答案Scott Craner，我想添加一个小的改进，当我们要连接一系列单元格时，如果什么也不做并且必须跳过空值，可以使用以下行代替分配结果的行：

  TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))

我添加了一个检查，如果结果为空，则返回它而不会出现错误。

    If TEXTJOIN <> "" Then
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
        Else
        TEXTJOIN = ""
    End If

- Nidhogg

Answer 4

使用转置函数：

=TRANSPOSE(A1:A200)

选择公式并按下F2，您将获得一个带有默认分隔符','的长字符串，该分隔符可以替换为您所需的分隔符。

- santhosha

---

这个函数可能不会做它原本应该做的事情。现在，它创建的行/列是指定范围的倒数（从行到列或从列到行）。没有连接符，也没有分隔符。 - chill389cc

Answer 5

一个适当的搜索会为你们节省很多麻烦...有一个"MyConCat()"函数，是我从2012年开始编写的这里，更简单但非常有效...

- Apostolos55