如何使用printf调试Linux内核汇编代码

Question

如何使用printf调试Linux内核汇编代码

3

这个文件是我正在尝试通过使用printf/printk语句进行调试的文件。

这段代码是汇编语言。

 79         __HEAD
 80 ENTRY(stext)
 81  ARM_BE8(setend be )                    @ ensure we are in BE8 mode
 82 
 83  THUMB( adr     r9, BSYM(1f)    )       @ Kernel is always entered in ARM.
 84  THUMB( bx      r9              )       @ If this is a Thumb-2 kernel,
 85  THUMB( .thumb                  )       @ switch to Thumb now.
 86  THUMB(1:                       )
 87 
 88 #ifdef CONFIG_ARM_VIRT_EXT
 89         bl      __hyp_stub_install
 90 #endif
 91         @ ensure svc mode and all interrupts masked
 92         safe_svcmode_maskall r9
 93 
 94         mrc     p15, 0, r9, c0, c0              @ get processor id
 95         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
 96         movs    r10, r5                         @ invalid processor (r5=0)?
 97  THUMB( it      eq )            @ force fixup-able long branch encoding
 98         beq     __error_p                       @ yes, error 'p'
 99 
100 #ifdef CONFIG_ARM_LPAE
101         mrc     p15, 0, r3, c0, c1, 4           @ read ID_MMFR0
102         and     r3, r3, #0xf                    @ extract VMSA support
103         cmp     r3, #5                          @ long-descriptor translation table format?
104  THUMB( it      lo )                            @ force fixup-able long branch encoding
105         blo     __error_lpae                    @ only classic page table format
106 #endif
107 
108 #ifndef CONFIG_XIP_KERNEL
109         adr     r3,

我只是想从这个文件向控制台输出一些消息。这段代码是为ARM编写的。

我尝试在这样的代码块中使用printk，但它无法编译。

有什么建议吗？

- Uzair

1

这是内核入口点的最顶端 - 你甚至还没有一个 _栈_。你可能可以借用一些备用寄存器将字节转储到硬编码的 UART 地址，但在达到 start_kernel 之前，printk 几乎是不可能的。然而，如果你的引导加载程序有一个 printf 实现，并留下了一个可用的 SP，如果你能找出正确的地址进行调用，你可能可以在这个时候使用它。 - Notlikethat

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- artless noise · Accepted Answer

答案在ARM启动FAQ中。您需要启用配置菜单项Kernel Hacking | Kernel低级调试功能。例如，代码__error_p将在您的控制台UART上显示一些内容。例如，elinux.org的打印调试在内核无法匹配您的机器ID时显示错误消息。^{请参见：ARM启动文档}

DEBUG_LL创建extern void printascii(char *);函数，您也可以使用它来检测vprintk_emit()。

--- a/kernel/printk/printk.c
+++ b/kernel/printk/printk.c
@@ -1483,6 +1483,8 @@ static size_t cont_print_text(char *text, size_t size)
        return textlen;
 }

+extern void printascii(char*);
+
 asmlinkage int vprintk_emit(int facility, int level,
                            const char *dict, size_t dictlen,
                            const char *fmt, va_list args)
@@ -1541,6 +1543,7 @@ asmlinkage int vprintk_emit(int facility, int level,
         * prefix which might be passed-in as a parameter.
         */
        text_len = vscnprintf(text, sizeof(textbuf), fmt, args);
+       printascii(text);

        /* mark and strip a trailing newline */
        if (text_len && text[text_len-1] == '\n') {

这个和内核命令行initcall_debug对于诊断引导问题非常有用。

如果您的平台不支持DEBUG_LL，则相当容易实现所需的轮询UART例程以支持它。

通常，在早期引导期间printk()被缓冲，并且直到控制台驱动程序激活后才真正打印输出。因此，在UART驱动程序运行之前任何地方崩溃/停止都看不到任何东西，除非修补vprintk_emit()，并使用正常配置。

对于head.S等的调试，需要使用汇编语言。 error_p实现提供了一些示例代码，这里还有另一个。

 #ifdef CONFIG_DEBUG_LL
         /* Save some registers? */
         adr     r0, prefix
         bl      printascii
         mov     r0, r9
         bl      printhex8
         adr     r0, tail
         bl      printascii
         b       1f
 prefix: .asciz  "\nTrace 1 gives "
 tail:   .asciz  "\n"
 1:  /* Perhaps halt here, due to register clobbers */
 #endif

您在head.S中的寄存器使用受上下文限制。这段代码的唯一问题通常是您没有执行ARM引导文档中描述的操作。

您还可以直接使用arch/arm/include/debug中定义的宏。这些宏包括：

- addruart - 获取uarts地址并将其分配给参数1（物理地址）、参数2（虚拟地址）（第3个参数是宏的临时变量）。 - senduart - 将参数1中的字符写入地址（虚拟或物理）。 - waituart - 参数1（tmp）和参数2（地址，虚拟或物理）。准备好了吗？ - busyuart - 参数1（tmp）和参数2（地址，虚拟或物理）。空闲吗？

您可以在printasii()实现中看到API的用法。

ENTRY(printascii)
        addruart_current r3, r1, r2   @ phys address to r3
        b   2f
1:      waituart r2, r3   @ ready (r2 is tmp, r3 is phys address)
        senduart r1, r3   @ transmit r1 character
        busyuart r2, r3   @ wait for character to finish tx.
        teq r1, #'\n'
        moveq   r1, #'\r' @ insert carriage return if new line.
        beq 1b
2:      teq r0, #0    @ NULL pointer?
        ldrneb  r1, [r0], #1  @ next char
        teqne   r1, #0        @ end of string?
        bne     1b            @ send another.
        mov pc, lr
ENDPROC(printascii)

在head.S等汇编代码中，你可以使用带有各种寄存器参数的宏，以避免使用中的寄存器（如r0-r3）被覆盖。它们通常可用于使用，并且可以直接调用printascii()。