如何检查多个单元格的值是否相等？

Question

假设我有6个不在同一行的单元格。我想检查这些单元格中的值是否相等。如何使用函数实现这一目标？我希望该函数仅显示“EQUAL”或“NOT EQUAL”（或可能更改单元格背景颜色）。

- d3pd

---

A1 = B1 = C1 = D1 = E1 等等……如果全部匹配，则结果为TRUE；如果有不匹配的，则结果为FALSE。（根据需要更改范围） - Vasim

@Vasim - 你不能像这样使用多个 = 符号。即使这些单元格中的值相等，=A1=B1=C1也会返回 FALSE。 - ZygD

为什么这是关于公式的问题？ - user894319twitter

Answer 1

6个电池的选择之一是这个：

=IF(AND(A1=B2,B2=C3,C3=D4,D4=E5,E5=F6),"EQUAL","NOT EQUAL")

另一种选择-这样你就不需要引用同一个单元格两次：

=IF(AND(ARRAYFORMULA(A1={B2,C3,D4,E5,F6})),"EQUAL","NOT EQUAL")

如果您想根据单元格的值来设置颜色，您需要创建一个类似的条件格式规则：

1. 选择您要设置颜色的单元格
2. 格式 > 条件格式
3. 选择“自定义公式为”
4. 使用上述公式之一（不包括公式中的 IF 部分）填写公式，例如：
   =AND(ARRAYFORMULA(A1={B2,C3,D4,E5,F6}))
5. 选择格式样式（颜色）
6. 完成

- ZygD

---

对我来说，这个不起作用，A1={B2,C3,D4,E5,F6}会出现语法错误，但是A1={B2;C3;D4;E5;F6}不会。 - YakovL

@YakovL - 这可能是你的本地化问题。对于你来说，所有基本公式都需要使用 ; 而不是 ,，这并不会使答案无效。 - ZygD

哦，我的，公式语法取决于区域设置...无论如何还是谢谢！ - YakovL

Answer 2

作为条件格式的公式：

=countunique({A1,B2,C3,D4,E5,F6})=1

作为函数，它将类似于：=if([公式],"相等","不相等")：

更新：请求澄清：

• 将所需单元格放入自定义数组{A1,B2,C3,D4,E5,F6}
  (分隔符：, = 新列，; = 新行；对于countunique，两者都可以)
• 获取唯一值countunique(...)
• 如果结果为1，则所有值都相同

更新2：原始答案使用=count(unique(...))而不是组合函数=countunique(...)

- wivku

---

如果您的范围中有空单元格，而您不想将其视为“不相等”，那么这是最佳答案。 - mang

Answer 3

这里提供一种不使用数组的选项，对于大量单元格来说更易实现：

=IF(MIN(A1,B2,C3,D4,E5,F6)=MAX(A1,B2,C3,D4,E5,F6),"Equal", "Not Equal")

- jfursedon

---

如果你需要忽略 #N/A：=MINIFS(A1:F1,A1:F1,"<>#N/A")=MAXIFS(A1:F1,A1:F1,"<>#N/A") - charles-allen