打印一个TDBGrid

Question

如何在不安装或下载组件的情况下打印DBGrid？

或者

如何将DBGrid的数据导入RichEdit中，以便从那里打印？

- Arno

Answer 1

数据感知控件从DataSource属性获取它们的数据，使用该属性即可。但是您需要手动遍历它，没有即时的方法可用（除非使用第三方库/组件）。

- LeleDumbo

Answer 2

您需要能够为每个字段确定适当的打印宽度，类似于以下内容：

function PrintFieldWidth(Field: TField): Integer;
var
  CharWidth: Integer;  // an average character width
  TitleWidth: Integer; // the width of the field title
  FieldWidth: Integer; // the width of the field content
begin
  CharWidth := Printer.Canvas.TextWidth('0');                
  TitleWidth := Printer.Canvas.TextWidth(Field.DisplayName);
  FieldWidth := Field.DisplayWidth*CharWidth;               
  if TitleWidth > FieldWidth then
    Result := TitleWidth+CharWidth
  else
    Result := FieldWidth+CharWidth;
end;

然后循环遍历所有记录，并循环遍历每个字段进行打印。

procedure PrintText(S: String; X, Y, W, H: Integer);
begin
  Printer.Canvas.TextRect(Rect(X,Y,X+W,Y+H),S);
end;

procedure PrintHeader(DataSet: TDataSet; X, Y, H: Integer);
var
  I: Integer; // record loop
  W: Integer; // field width
begin
  for I := 0 to DataSet.FieldCount-1 do
  begin
    if DataSet.Fields[I].Visible then
    begin
      W := PrintFieldWidth(DataSet.Fields[I]);
      PrintText(DataSet.Fields[I].FieldName, X, Y, W, H);
      X := X + W;
    end;
  end;
end;

procedure PrintRecord(DataSet: TDataSet; X, Y, H: Integer);
var
  I: Integer; // record loop
  W: Integer; // field width
begin
  for I := 0 to DataSet.FieldCount-1 do
  begin
    if DataSet.Fields[I].Visible then
    begin
      W := PrintFieldWidth(DataSet.Fields[I]);
      PrintText(DataSet.Fields[I].AsString, X, Y, W, H);
      X := X + W;
    end;
  end;
end;

procedure PrintDataSet(DataSet: TDataSet; X, Y: Integer);
var
  OldPos: TBookmark;
  H: Integer; // line height
begin
  if DataSet <> nil then
  begin
    H := Printer.Canvas.TextHeight('0');
    SaveAfterScroll := DataSet.AfterScroll;
    DataSet.AfterScroll := nil;
    try
      DataSet.DisableControls;
      OldPos := DataSet.GetBookmark;
      DataSet.First;
      PrintHeader(DataSet, X, Y, H);
      Y := Y + H * 2;
      while not DataSet.Eof do
      begin
        PrintRecord(DataSet, X, Y, H);
        Y := Y + H;
        DataSet.Next;
      end;
      DataSet.GotoBookmark(OldPos);
      DataSet.FreeBookmark(OldPos);
    finally
      DataSet.AfterScroll := SaveAfterScroll;
      DataSet.EnableControls;
    end; // try
  end;
end;

你需要添加一些代码来处理分页。

- Rob McDonell

Answer 3

你可以手动循环遍历网格并将其全部放入富文本编辑器中。 但为什么要重复造轮子呢？只需使用报表组件即可。 在Delphi 7 - Delphi2010中，您已安装了Rave组件。

- Ravaut123

---

这是一个在课堂上完成的学校项目，我们不能下载或安装新组件，因为有人在安装组件时搞砸了系统。您能给我一个如何使用Rave组件的示例吗？ - Arno

我自己不使用Rave，我使用ReportBuilder。但是Rave报告通常在Delphi7-Delphi2010上使用。例如：http://componentace.com/reports-rave-report-delphi.htm 但是如果您的IDE上没有这些组件，则必须循环访问您的数据。 - Ravaut123