正如其他人所提到的,控制台应用程序没有消息泵。
这里有一个
TConsoleTimer
线程类,它模拟了一个
TTimer
类。主要区别在于事件中的代码在
TConsoleTimer
线程中执行。
更新
在本文末尾有一种方法可以在主线程中调用此事件。
unit ConsoleTimer;
interface
uses
Windows, Classes, SyncObjs, Diagnostics;
type
TConsoleTimer = Class(TThread)
private
FCancelFlag: TSimpleEvent;
FTimerEnabledFlag: TSimpleEvent;
FTimerProc: TNotifyEvent;
FInterval: integer;
procedure SetEnabled(doEnable: boolean);
function GetEnabled: boolean;
procedure SetInterval(interval: integer);
protected
procedure Execute; override;
public
Constructor Create;
Destructor Destroy; override;
property Enabled : boolean read GetEnabled write SetEnabled;
property Interval: integer read FInterval write SetInterval;
property OnTimerEvent: TNotifyEvent read FTimerProc write FTimerProc;
end;
implementation
constructor TConsoleTimer.Create;
begin
inherited Create(false);
FTimerEnabledFlag := TSimpleEvent.Create;
FCancelFlag := TSimpleEvent.Create;
FTimerProc := nil;
FInterval := 1000;
Self.FreeOnTerminate := false;
end;
destructor TConsoleTimer.Destroy;
begin
Terminate;
FTimerEnabledFlag.ResetEvent;
FCancelFlag.SetEvent;
Waitfor;
FCancelFlag.Free;
FTimerEnabledFlag.Free;
inherited;
end;
procedure TConsoleTimer.SetEnabled(doEnable: boolean);
begin
if doEnable then
FTimerEnabledFlag.SetEvent
else
FTimerEnabledFlag.ResetEvent;
end;
procedure TConsoleTimer.SetInterval(interval: integer);
begin
FInterval := interval;
end;
procedure TConsoleTimer.Execute;
var
waitList: array [0 .. 1] of THandle;
waitInterval,lastProcTime: Int64;
sw: TStopWatch;
begin
sw.Create;
waitList[0] := FTimerEnabledFlag.Handle;
waitList[1] := FCancelFlag.Handle;
lastProcTime := 0;
while not Terminated do
begin
if (WaitForMultipleObjects(2, @waitList[0], false, INFINITE) <>
WAIT_OBJECT_0) then
break;
if Assigned(FTimerProc) then
begin
waitInterval := FInterval - lastProcTime;
if (waitInterval < 0) then
waitInterval := 0;
if WaitForSingleObject(FCancelFlag.Handle,waitInterval) <> WAIT_TIMEOUT then
break;
if WaitForSingleObject(FTimerEnabledFlag.Handle, 0) = WAIT_OBJECT_0 then
begin
sw.Start;
FTimerProc(Self);
sw.Stop;
lastProcTime := sw.ElapsedMilliSeconds;
end;
end;
end;
end;
function TConsoleTimer.GetEnabled: boolean;
begin
Result := (FTimerEnabledFlag.Waitfor(0) = wrSignaled);
end;
end.
还有一个测试:
program TestConsoleTimer;
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils,ConsoleTimer;
type
TMyTest = class
procedure MyTimerProc(Sender: TObject);
end;
procedure TMyTest.MyTimerProc(Sender: TObject);
begin
WriteLn('Timer event');
end;
var
MyTest: TMyTest;
MyTimer: TConsoleTimer;
begin
MyTest := TMyTest.Create;
try
MyTimer := TConsoleTimer.Create;
MyTimer.Interval := 1000;
MyTimer.OnTimerEvent := MyTest.MyTimerProc;
WriteLn('Press [Enter] key to end.');
MyTimer.Enabled := true;
ReadLn;
MyTimer.Free;
finally
MyTest.Free;
WriteLn('End.');
end;
end.
如上所述,我该如何使事件在主线程中执行?
阅读
Delphi 7:处理控制台应用程序中的事件(TidIRC)即可得到答案。
在
TConsoleTimer
中添加一个方法:
procedure TConsoleTimer.SwapToMainThread;
begin
FTimerProc(Self);
end;
并将 Execute
方法中的调用更改为:
Synchronize(SwapToMainThread);
为了进行同步调用,请在Classes单元中使用
CheckSynchronize()
函数:
while not KeyPressed do CheckSynchronize(); // Pump the synchronize queue
注意:控制台
KeyPressed
函数可以在这里找到:
如何在Delphi控制台应用程序中实现IsKeyPressed函数?。